imprime une virgule au lieu d'un point

Version imprimable

Bonjour tout le monde !

J'ai créé un programme qui copie la colonne P3 d'un fichier texte en une colonne -P3 dans ce même fichier texte. Le soucis est qu'il me renvoie un nombre avec virgule alors que tous les nombres étaient avec des points.
Comment faire pour qu'il me renvoie des nombres avec des points ?

Merci d'avance pour votre aide :)
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 Sub Lissage() Dim Nv, P1, P2, P3 As Variant Dim X(10000000), Y(10000000), Z(10000000) As Variant Open ActiveWorkbook.Sheets("bathy").Cells(7, 6) For Input As #1 ' Fichier bathy Brut 'Mise en tableau dynamique des bathy i = 0 Do While Not EOF(1) i = i + 1 Input #1, P1, P2, P3 ' lecture fichier X(i) = P1 Y(i) = P2 Z(i) = P3 Loop Close #1 Nv = i Close #1 i = 0 Open ActiveWorkbook.Sheets("bathy").Cells(7, 6) For Output As #2 For i = 1 To Nv Print #2, X(i), Y(i), -Z(i) Next i Close #2 End Sub

11/04/2011, 16h32
casefayere

Bonjour,
essayes avec :

Code:

X(i) = Replace(P1, ",", ".")

Bonjour,

Il te faut utiliser Replace(). J'ai, je pense, simplifié un peu ton code :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
 
Sub Lissage()
 
    Dim X()
    Dim I As Long
    Dim Fichier As String
 
    Fichier = ActiveWorkbook.Sheets("bathy").Cells(7, 6)
 
    Open Fichier For Input As #1
 
    Do While Not EOF(1)
 
       I = I + 1
 
       'redimensionne le tableau (3 colonnes et x lignes)
       ReDim Preserve X(1 To 3, 1 To I)
 
       'récup directe dans le tableau
       Input #1, X(1, I), X(2, I), X(3, I)
 
    Loop
 
    Close #1
 
    Open Fichier For Output As #1
 
    For I = 1 To UBound(X, 2)
 
        'remplace la virgule par le point
        Print #1, Replace(X(1, I), ",", "."), _
                  Replace(X(2, I), ",", "."), _
                  Replace(-X(3, I), ",", ".")
 
    Next I
 
    Close #1
 
End Sub

Hervé.

12/04/2011, 08h49
Titened

:ccool: ca marche ! (mais c'est un peu plus lent)

Merci beaucoup pour votre aide :)

Bonjour,

C'est normal que ce soit un peu plus lent puisqu'on passe par la fonction Replace pour modifier les trois valeurs de chaque ligne. Maintenant, tu pourrais essayer de récupérer la ligne entière et Spliter dans un tableau et comme ça, pas besoin de remplacer les virgules par des points (à voir pour le plus rapide des deux ?) :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
 
Sub Lissage()
 
    Dim X()
    Dim Tbl
    Dim I As Long
    Dim Fichier As String
    Dim Ligne As String
 
    Fichier = ActiveWorkbook.Sheets("bathy").Cells(7, 6)
 
    Open Fichier For Input As #1
 
    Do While Not EOF(1)
 
        'récup par ligne entière
        Line Input #1, Ligne
 
        'splite la ligne dans un tableau transitoire
        'adapter le délimiteur (ici, 11 espaces)
        Tbl = Split(Ligne, Space(11))
 
        I = I + 1
        ReDim Preserve X(1 To 3, 1 To I)
 
        'distribu le tableau
        'trim supprime les espaces éventuels avant et après
         X(1, I) = Trim(Tbl(0))
         X(2, I) = Trim(Tbl(1))
         X(3, I) = Trim(Tbl(2))
 
    Loop
 
    Close #1
 
    Open Fichier For Output As #1
 
    For I = 1 To UBound(X, 2)
 
        Print #1, X(1, I), X(2, I), -X(3, I)
 
    Next I
 
    Close #1
 
End Sub

Hervé.