macro, variable et boucle

Version imprimable

Bonjour à tous,

Je débute un peu dans le maniement des variables et des boucles en VBA, je comprend la logique, car je développe en PHP.

Voici ce que je souhaite faire.

- J'ai des données dans une feuille de calcul qui doivent mettre à jour les données d'un autre onglet (base source) via une macro.
- J'ai une cellule qui me sert de pivot (clé unique) entre les deux onglets.

Voici mon script vba qui fonctionne pour une ligne.
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 Dim maVariable As String maVariable = Range("B19") Sheets("bdd_suivi").Select Range("A1").Select Cells.Find(What:=maVariable, After:=ActiveCell, LookIn:=xlFormulas, LookAt:= _ xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False) _ .Activate Sheets("ecran_modif").Select Range("b19:G19").Select Application.CutCopyMode = False Selection.Copy Sheets("bdd_suivi").Select Selection.PasteSpecial Paste:=xlValues, Operation:=xlNone, SkipBlanks:= _ False, Transpose:=False
dans le script ci-dessus, j'ai deux besoins.

1°) comment passer d'une ligne à l'autre pour les lignes suivantes :

Code:

maVariable = Range("B19")

Code:

Range("b19:G19").Select

ps : j'ai besoin de mettre le chiffre "19" en variable et je ne sais pas comment faire.

Pour être plus clair, mon B19 pour la première ligne devient B20 pour la suivante et ainsi de suite sur environ 60 lignes.

2°) comment créer une boucle pour que l'incrémentation des 60 lignes génère automatiquement la variable (B19,B20...B60,B61...)

Avec une condition supplémentaire : Si il n'y a pas de valeur identique dans la recherche "Cells.Find" alors on stop la macro.

Merci de votre soutient.

Bonjour,
Voici un code pour écrire dans les cellules B19 à B29 de la feuille "Feuil1" du classeur où se trouve le code VBA
Code:

1 2 3 4 5 6 7 8 9 10 Option Explicit Sub Ecriture() Dim maLigne As Long, r As Long maLigne = 19 With ThisWorkbook.Worksheets("Feuil1") For r = maLigne To 29 .Range("B" & r) = "Ecriture sur ligne " & r Next r End With End Sub

Re,
voici comment j'ai compris le code (sans avoir testé), je suis peut-être à coté de la plaque :
En reprenant le code original

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Dim maVariable As String, i As Long, ch As Range
 
For i = 19 To 79
    maVariable = Range("B" & i)
    With Sheets("bdd_suivi")
        Set ch = .Cells.Find(What:=maVariable, After:=.Range("A1"), LookIn:=xlFormulas, LookAt:= _
            xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False)
        If Not ch Is Nothing Then
            .Range(ch.Address) = Sheets("ecran_modif").Range("b" & i, "G" & i)
        Else
            Exit Sub
        End If
    End With
Next i

Bonsoir à tous
une autre proposition

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Dim v As Range, c As Range
 
Application.ScreenUpdating = False
With Sheets("bdd_suivi")
    For Each v In Sheets("ecran_modif").Range("B19:B79")
        Set c = .UsedRange.Find(v.Value, LookIn:=xlValues, LookAt:=xlPart)
        If Not c Is Nothing Then
            c.Resize(1, 6).Value = v.Resize(1, 6).Value
            Set c = Nothing
        Else
            Exit Sub
        End If
    Next v
End With

05/04/2011, 02h57
Giantrick

Bonjour,

Merci Dom, je pense que je ne suis pas loin avec ton code.

Juste que ce qu'il donne comme résultat n'est pas totalement ce que j'attends.

En effet, dans mon onglet : "bdd_suivi" il trouve bien les bonnes cellules, mais il vide chacune de celles-ci.

A la place, je voudrais qu'il me recopie l'intégralité de la ligne de la cellule (B19 à G19) de l'onglet "ecran_modif" dans l'onglet "bdd_suivi" dès qu'il trouve le pivot via la recherche précédente de la fonction.

Merci de la suite.... ;)
12/04/2011, 10h16
casefayere

Bonjour Giantrick, re le forum,

Je pense que je n'ai pas compris ce que tu veux faire, peux-tu joindre un fichier exemple (avec explications) et on travaillera sur celui-ci.
12/04/2011, 21h53
Giantrick

1 pièce(s) jointe(s)

Re-Bonjour,

Voici le fichier exemple.

Ma macro (non inclus dans ce fichier exemple) a pour objectif de recopier chaque ligne de l'onglet "ecran_modif" sur la bonne ligne de l'onglet "bdd_suivi".

Sachant que dans "bdd_suivi" il pourra y avoir des centaines de lignes toutes unique via le pivot de la première colonne.

Ce pivot sera le point de cohérence avec la première colonne de l'onglet "ecran_modif"

J'espère que j'ai été un peu plus clair...

Merci encore à vous ;)

Plutôt comme ceci

test sur ton fichier

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Dim LastLig As Long
Dim v As Range, c As Range
 
Application.ScreenUpdating = False
With Sheets("bdd_suivi")
    LastLig = .Cells(.Rows.Count, "A").End(xlUp).Row
    For Each v In Sheets("ecran_modif").Range("A1:A" & LastLig)
        If v.Value <> "" Then
            Set c = .UsedRange.Range("A:A").Find(v.Value, LookIn:=xlValues, LookAt:=xlPart)
            If Not c Is Nothing Then
                v.Resize(1, 6).Copy c
                Set c = Nothing
            End If
        End If
    Next v
End With

12/04/2011, 23h44
Giantrick

super ca fonctionne très bien...

J'ai du adapté certaines variables car les données dans mon fichier final n'étaient pas disposé dans les mêmes colonnes, mais tout fonctionne très très bien.

Merci encore.
12/04/2011, 23h49
mercatog

Et voilà, tu as perdu une semaine, la réponse identique était proposée la 4 avril. Comme quoi, il fallait tester, étudier et comprendre toutes les propositions.