Macro qui ne fonctionne qu'avec F5 !

Version imprimable

Bonjour à tous,

J'ai écris une macro dans ThisWorkbook: Private Sub Workbook_Open() qui ne fonctionne que dans l'éditeur lorsque je tape la touche F5.
En revanche, si je ferme mon classeur et que je l'ouvre, la macro ne fonctionne pas...
Je ne comprend pas pourquoi et ne trouve aucun forum avec ce sujet sur le net.
Une idée pour résoudre mon problème peut-être ?

Ci-joint mon code qui me pose problèmes:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Private Sub Workbook_Open()
'Affiche l'userform Acceuil (plein écran)
UsfAcceuil.Show
'Cache les textebox et listbox
UsfAcceuil.TxtAnniv.Visible = False
UsfAcceuil.ListNomsAnniv.Visible = False
UsfAcceuil.ListDatesAnniv.Visible = False
UsfAcceuil.LabelRDV.Visible = False
UsfAcceuil.ListRDV.Visible = False
Dim i As Long
For i = 5000 To 2 Step -1
'Affiche les textbox et listbox si la date est reconnue et les remplis
If Worksheets("CLIENTS").Cells(i, 10) = Date - 7 Then
UsfAcceuil.TxtAnniv.Visible = True
UsfAcceuil.ListNomsAnniv.Visible = True
UsfAcceuil.ListDatesAnniv.Visible = True
UsfAcceuil.ListNomsAnniv.AddItem Worksheets("CLIENTS").Cells(i, 5).Value
UsfAcceuil.ListDatesAnniv.AddItem Worksheets("CLIENTS").Cells(i, 10).Value
End If
Next
 
'idem pour d'autre textbox et listbox
For i = 5000 To 2 Step -1
If Worksheets("RDV").Cells(i, 1) = Date Then
UsfAcceuil.LabelRDV.Visible = True
UsfAcceuil.ListRDV.Visible = True
UsfAcceuil.ListRDV.AddItem Worksheets("RDV").Cells(i, 2).Value
End If
Next
End Sub

Merci d'avance pour votre aide !

Ocin2

Bonsoir
Essaies d'ouvrir simplement l'userform à l'ouverture de ton classeur

Code:

1
2
3
4
Private Sub Workbook_Open()
 
UsfAcceuil.Show
End Sub

Ensuite dans l'initialize de ton userform mettre

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Private Sub UserForm_Initialize()
Dim i As Long
Dim bClient As Boolean, bRdv As Boolean
 
Me.TxtAnniv.Visible = False
Me.ListNomsAnniv.Visible = False
Me.ListDatesAnniv.Visible = False
Me.LabelRDV.Visible = False
Me.ListRDV.Visible = False
For i = 5000 To 2 Step -1
    If Worksheets("CLIENTS").Cells(i, 10) = Date - 7 Then
        Me.ListNomsAnniv.AddItem Worksheets("CLIENTS").Cells(i, 5).Value
        Me.ListDatesAnniv.AddItem Worksheets("CLIENTS").Cells(i, 10).Value
    End If
    If Worksheets("RDV").Cells(i, 1) = Date Then Me.ListRDV.AddItem Worksheets("RDV").Cells(i, 2).Value
Next i
'Affiche les textbox et listbox si la date est reconnue et les remplis
If Me.ListNomsAnniv.ListCount > 0 Then
    Me.TxtAnniv.Visible = True
    Me.ListNomsAnniv.Visible = True
    Me.ListDatesAnniv.Visible = True
End If
If ListRDV.ListCount > 0 Then
    Me.LabelRDV.Visible = True
    Me.ListRDV.Visible = True
End If
End Sub

PS: pourquoi 2 boucles alors qu'une seule fera l'affaire
Peut être un filtre automatique serait plus rapide

28/03/2011, 00h22
pgz
Bonsoir

Citation:

Envoyé par Ocin2

J'ai écris une macro dans ThisWorkbook: ... si je ferme mon classeur et que je l'ouvre, la macro ne fonctionne pas...
Je ne comprend pas pourquoi et ne trouve aucun forum avec ce sujet sur le net.

Et pourtant il y en a, notamment sur les forums US.
Mais sur DVP aussi :
- ici
- et là
Le pb qui a été identifié survient avec l'utilisation de mise en forme conditionnelle appelant une fonction personnalisée.

SI tu es dans ce cas, tu pourras facilement le vérifier en supprimant ces MFC.

Mais le pb n'est toujours pas élucidé. Peut-être cette fois-ci?

Cordialement,

PGZ