Batch : script PING

Peut on m'expliquer pourquoi cette commande ne fonctionne pas ?

Citation:

---

FOR /F %%I in (machines.txt) DO ping -n 1 %%I && IF NOT ERRORLEVEL 0 echo %%I >> pingNONOK.txt

---

par contre celle-ci fonctionne :

Code:

---

1 2	FOR /F %%I in (machines.txt) DO ping -n 1 %%I && IF ERRORLEVEL 0 echo %%I >> pingOK.txt

---

je débute en batch, merci de votre compréhension...

Je tiens quand même à garder une boucle FOR, et essayer de faire mon script pour trier les PC qui ping et ceux qui ne ping pas...

merci de votre aide

A priori la commande ping ne positionne pas le flag ERRORLEVEL.

Essaye plutôt ce script trouvé sur internet (j'aurais été bien incapable de le faire)

Code:

---

1 2 3 4 5 6 7 8 9 10

FOR /F %%I IN (machines.txt) DO ( set Ordi=%%I call :aa ) exit :aa ping /n 1 %Ordi% | find "TTL" > nul if %ERRORLEVEL%==1 echo %Ordi% >> pingNONOK.txt if %ERRORLEVEL%==0 echo %Ordi% >> pingOK.txt

---

Je viens de tester (XP SP3), la commande errorlevel retourne bien la bonne valeur (0 ou 1 suivant le cas).

Par contre, la gestion de errorlevel est assez particulière avec le test que tu utilises:
le test if errorlevel 0 est valable pour un code d'erreur de 0 ou... plus
ce qui veut dire que le test sera positif pour errorlevel=0 ET pour errorlevel=1 (ou plus).
Pour lever l'ambiguité, utilise le code de sevyc64:
if NOT %errorlevel%==0
ou
if %errorlevel% NEQ 0


ou fait ton test d'une autre facon:
if errorlevel 1 (si le code d'erreur est 1 ou plus)
Pour tester si le code d'erreur vaut 0, il faut utiliser une négation:
if not errorlevel 1 (si le code d'erreur n'est pas 1 ou plus, c'est qu'il vaut 0 ou moins)

Merci pour votre intéret,

Une tiers personnes à trouver cette solution qui fonctionne bien aussi :

Citation:

---

FOR /F %%I in (machines.txt) DO ping -n 1 %%I && ( echo %%I >> pingOK.txt ) || ( echo %%I >> pingNONOK.txt )

---

si ça peut aider certains....

bah bizarrement la commande que j'ai donné ci-dessus ne fonctionne plus.
Quand je lance la commande seule dans un .bat ça tourne en boucle pendant 30s à 1 min et la fenetre dos se ferme et les 2 fichiers.txt associés restent vides....
comprends pas
pk ça marchait hier et là ça ne marche plus...?

Citation:

---

Envoyé par obijes

bah bizarrement la commande que j'ai donné ci-dessus ne fonctionne plus.
Quand je lance la commande seule dans un .bat ça tourne en boucle pendant 30s à 1 min et la fenetre dos se ferme et les 2 fichiers.txt associés restent vides....

---

A tout hasard, tu as bien laissé tous les %%I en majuscule ?
(les variables des boucles FOR sont sensibles à la casse)

pour que le script fonctionne, j'ai rajouté ping.exe au lieu de ping....
:calim2:
bizarre

Citation:

---

Envoyé par obijes

pour que le script fonctionne, j'ai rajouté ping.exe au lieu de ping....
:calim2:
bizarre

---

tu dois avoir un batch qui s'appelle ping soit dans le dossier ou tu lance ton programme, soit dans le chemin de recherche (PATH)

@echo off
FOR /F %%I IN (c:\Temp\adresses_a_pinger.txt) DO (
echo Pinging %%I
ping -n 2 -w 1000 %%I >nul
if errorlevel 1 (
echo Pas de reponse au ping
) else (
echo Ping OK
)
echo.
)
pause >nul

Notes:
ping -n 2 = nombre de ping à réaliser
-w 1000 = toute les secondes
adresses_a_pinger.txt = fichier contenant les adresses IP à tester dans le dossier C:\Temp

$InputFile = "C:\Temp\adresses_a_pinger.txt"

foreach ($IP in Get-Content $InputFile) {
Write-Host "Pinging $IP"
$result = Test-Connection -ComputerName $IP -Count 1 -Quiet
if ($result) {
Write-Host "Ping OK"
} else {
Write-Host "Pas de reponse au ping"
}
Write-Host
}

Read-Host -Prompt "Appuyez sur une touche pour continuer..."