Bloquer les données avec code vba

Version imprimable

28/02/2011, 18h58
demichoux

Bloquer les données avec code vba

Bonsoir,

Voila j'ai une base dans la quelle il faut avoir un login est un mot de passe pour ce connecté par l'intermédiaire d'un code vba, moi ce que je voudrais c'est que les autres utilisateur ne peuvent que consulter la base est ne pas modifier les données qui apparaissent dans les formulaires. est-ce-que c'est possible de le faire ?

Utilises-tu la sécurité de Access (ficher .mdw) ou ta propre procédure de sécurité ?

Si c'est ta propre procédure, une solution simple serait de créer un utilisateur 'Consultation' ou quelque chose de ce genre puis pour chaque formulaire mettre dans l'événement 'Sur Ouverture' un truc du genre
Code:

1 2 3 4 5 6 7 8 9 10 11 if MonUtilisateur="Consultation" 'Interdit toutes les modifications Me.AllowAdditions = False Me.AllowDeletions = False Me.AllowEdits = False else 'Autorise les modifications Me.AllowAdditions = true Me.AllowDeletions = true Me.AllowEdits = true end if
A+

01/03/2011, 09h40
demichoux

2 pièce(s) jointe(s)

Bonjour marot_r,

Il me marque un message d'erreur (Erreur d'execution '424' objet requis)

ci-joint les captures d'écran du code et de l'erreur

Je ne vois pas d'ou viens le probléme.

Bonjour,

Utilises plutôt l'argument OpenArgs auquel tu passes la valeur représentant le fait que ce soit en consultation seule ou en lecture écriture :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
Private Const CONSULTATION_SEULE As String = "Consultation"
 
Private Sub Form_Load()
Dim vntArgs As Variant
 
    vntArgs = Me.OpenArgs
    If Not IsNull(vntArgs) Then
        Me.AllowAdditions = (vntArgs = CONSULTATION_SEULE)
        Me.AllowDeletions = (vntArgs = CONSULTATION_SEULE)
        Me.AllowEdits = (vntArgs = CONSULTATION_SEULE)
    Else
        MsgBox "Paramètre manquant requis pour ouvrir ce formulaire !", vbExclamation
        DoCmd.Close acForm, Me.Name
    End If
End Sub

Argy

01/03/2011, 10h29
demichoux

Bonjour argyronet,

Merci mais peut tu être un peu plus précis STP,

Faut-il que je met le code surtout mes formulaires ?

A quoi correspond cette partie du code fait-elle appel a une table ?

Code:

Private Const CONSULTATION_SEULE As String = "Consultation"

Merci

Sur tous ceux qui sont susceptibles de recevoir des données...

Dans l'idéal, tu initialises une variables publique booléenne (par ex g_blnIsReadOnly) à l'ouverture de la base en fonction du profil.
Tu appliques alors la valeur de celle-ci à l'événement visé :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 Option Compare Database Option Explicit Private Sub Form_Load() Me.AllowAdditions = Not g_blnIsReadOnly Me.AllowDeletions = Not g_blnIsReadOnly Me.AllowEdits = Not g_blnIsReadOnly With Me.lblReadOnlyMessage .Caption = "LECTURE SEULE" .Visible = g_blnIsReadOnly End With End Sub
Argy

01/03/2011, 11h22
demichoux

Tu me parle chinois la ;)

Pour te dire mes connaissances en vba ce limite a ouvrir visual basic

Veut tu que je redéfinis clairement mon probléme ?

voila

Bon, eh bien on va faire plus simple. Procédons par ordre :
Comme tu sais si bien le faire, tu ouvre l'éditeur Visual Basic
Tu ajoutes un Module depuis le menu Insertion
Tu y recopies le bloc:

Code:

1
2
3
4
5
6
7
8
9
10
11
Option Compare Database
Option Explicit
 
Private Const CONSULTATION_SEULE As String = "Consultation"
 
Public Function LectureSeule() As Boolean
'Verifie si le login est = à Consultation et si oui, LectureSeule = True
Dim strNomUtilisateur                                  As String
    strNomUtilisateur = Environ("USERNAME")
    LectureSeule = (StrComp(strNomUtilisateur, CONSULTATION_SEULE, vbTextCompare) = 0)
End Function

Dans ton formulaire, tu modifies le code comme suit :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Option Compare Database
Option Explicit
 
Private Sub Form_Load()
    'Ajout autorisé ou non
    Me.AllowAdditions = Not LectureSeule
    'Suppression autorisée ou non
    Me.AllowDeletions = Not LectureSeule
    'Modifications autorisée ou non
    Me.AllowEdits = Not LectureSeule
    'L'étiquette est visible et affiche une mention lecture seule si LectureSeule=True
    With Me.lblReadOnlyMessage
        .Caption = "LECTURE SEULE"
        .Visible = LectureSeule
    End With
End Sub

Argy

01/03/2011, 11h58
demichoux

1 pièce(s) jointe(s)

J'ai fait ce que tu m'a dit, j'ai créer un module puis j'ai ajouter le code dans mon formulaire sur l'ouverture mais il j'ai un message d'erreur qui apparait
01/03/2011, 13h22
argyronet

Il faut que tu ajoutes un contrôle Etiquette dans ton formulaire que tu nommes lblReadOnlyMessage.
Tu lui donnes une taille d'environ 4cm en Arial Black rouge.

Argy

C'est bon c'est fait pour l'étiquette, mais je peut toujours modifier les données même en utilisant le login Consultation l'étiquette n'aparait pas non plus, mais il y a des choses qui me turlupine dans le code du module
Code:

1 2 3 4 5 6 7 8 9 10 11 Option Compare Database Option Explicit Private Const CONSULTATION_SEULE As String = "Consultation" Public Function LectureSeule() As Boolean 'Verifie si le login est = à Consultation et si oui, LectureSeule = True Dim strNomUtilisateur As String strNomUtilisateur = Environ("USERNAME") LectureSeule = (StrComp(strNomUtilisateur, CONSULTATION_SEULE, vbTextCompare) = 0) End Function
Pourquoi mettre "strNomUtilisateur " est a quoi il sert? a quoi correspond cette partie du code "Environ("USERNAME")" je suis désolé, je t'en quiquine surment avec mes question mais j'ai bien savoir est comprendre en 1 er lieu.

Pour être plus précis quand j'ouvre ma base j'ai un formulaire qui apparait dans lequel j'ai 2 champs un txt_user (Login) et l'autre txt_pass(MdP) donc lorsque je saisie le login est le mot de passe est que je click sur mon bouton connexion j'ai ce code ci-dessous
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 Private Sub connexion_Click() Dim Rs As Recordset Dim Reconnu As Boolean Reconnu = False Set Rs = CurrentDb.OpenRecordset("T_User") Do While Not Rs.EOF If Rs.Fields("Trigramme").Value = txt_user.Value Then If Rs.Fields("Paswd").Value = txt_pass.Value Then DoCmd.OpenForm "Menu Général", acNormal, , , , acWindowNormal DoCmd.Close acForm, "F_CONNEXION" Reconnu = True Exit Do Else MsgBox "Erreur de mot de passe" GoTo fin End If End If Rs.MoveNext Loop If Reconnu = False Then MsgBox "Vous n'avez pas accès a la base!!!", vbCritical, "Attention.." GoTo fin End If 'Traitement suivants fin: End Sub
qui cherche si le login correspond bien au mot de passe si oui il m'ouvre un autre formulaire qui me sert de Menu Général est dans ce formulaire j'ai 2 formulaires un qui s'appel Ouvrir Formulaire BFI est l'autre Ouvrir Formulaire PPC est se sont ces 2 formulaires que je voudrai protéger

voila je pense t'avoir donnée tout les infos que je dispose

OK, quand tu parlais de login, je pensais LOGIN Windows d'où le
Environ("USERNAME")
ce qui est recommandé en fait car tu es sûr de cibler la personne voulu.
Bref, tu as établi ton propre gestionnaire d'utilisateurs dans une table.
Il est important de te préciser qu'en moins de 10 secondes, je rentre dans ta base avec ce procédé. Je te conseille la lecture d'un article sur ce forum sur la sécurité.
Bon, pour aller dans ton sens, voici la solution :

1/ oublier ce que je t'ai écris ci-avant (en partie)

2/ mettre dans le module une variable publique et une constante comme suit :

Code:

1
2
3
 
Public g_blnIsReadOnly                                 As Boolean
Public Const CONSULTATION_SEULE                        As String = "Consultation"

3/Modifier ta procédure connexion :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
Private Sub connexion_Click()
Dim Rs                                                 As DAO.Recordset
Dim vntUserName                                        As Variant
Dim vntPassword                                        As Variant
 
    Reconnu = False
    vntUserName = txt_user.Value
    vntPassword = txt_pass.Value
    If IsNull(vntUserName) Or Len(vntUserName) < 2 Then
        MsgBox "Nom d'utilisateur invalide !", vbExclamation
        Exit Sub
    End If
    If IsNull(vntPassword) Or Len(vntPassword) < 2 Then
        MsgBox "Mot de passe invalide !", vbExclamation
        Exit Sub
    End If
 
    Set Rs = CurrentDb.OpenRecordset("SELECT * T_User WHERE Trigramme = '" & vntUserName & "' AND Paswd = '" & vntPassword & "'")
    If Rs.EOF Then
        MsgBox "Vous n'avez pas accès a la base!!!", vbCritical, "Attention.."
        Exit Sub
    Else
        g_blnIsReadOnly = (vntUserName = CONSULTATION_SEULE)
        DoCmd.Close acForm, "F_CONNEXION"
        DoCmd.OpenForm "Menu Général", acNormal, , , , acWindowNormal
    End If
    Rs.Close
    Set Rs = Nothing
End Sub

4/ et enfin l'appliquer au formulaire ciblé comme précisé précédemment :

Code:

1
2
3
4
5
6
7
8
9
10
 
Private Sub Form_Load()
    Me.AllowAdditions = Not g_blnIsReadOnly
    Me.AllowDeletions = Not g_blnIsReadOnly
    Me.AllowEdits = Not g_blnIsReadOnly
    With Me.lblReadOnlyMessage
        .Caption = "LECTURE SEULE"
        .Visible = g_blnIsReadOnly
    End With
End Sub

Argy

01/03/2011, 16h05
demichoux

C'est bon tout fonctionne correctement

Merci beaucoup