Matrice en argument d'une subroutine

Bonjour à tous,

Ma question est relativement simple. Existe-t-il une façon de passer une matrice à une subroutine, sans avoir besoin de passer pour autant ses dimensions ? Un exemple de l'idée est donnée dans le code ci-dessous :
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 PROGRAM INTEGER :: I,J DOUBLE PRECISION :: A(2,2) ! Initialisation de la matrice DO I=1,2 DO J= 1,2 A(i,j)=0.D0 ENDDO ENDDO CALL SHAPEMATRIX(A) END PROGRAM SUBROUTINE SHAPEMATRIX(A) DOUBLE PRECISION, INTENT(IN) :: A(:,:) ! SHAPE donne la dimension d'une matrice A:M*N sous la forme (M,N) Print *,SHAPE(A) END SUBROUTINE
Evidemment ce code ne fonctionne pas, mais je ne trouve pas d'écriture correcte (s'il en existe une) de la ligne en rouge.

Merci d'avance à tous ceux qui prendront le temps de m'apporter leur aide.

Bonjour,
A ma connaissance tu as deux manières de faire au moins :

- Soit tu déclares tes subroutines dans le corps du programme principal dans un "contains". Ca me semble peu élégant et limité en application mais ca marche :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 
PROGRAM 
 
   INTEGER :: I,J
   DOUBLE PRECISION :: A(2,2)
 
   ! Initialisation de la matrice
   A = 0.0D00   ! initialisation récursive au passage (plus rapide que 2 boucles imbriquées)
 
   CALL SHAPEMATRIX(A)
 
CONTAINS
 
 
SUBROUTINE SHAPEMATRIX(A)
   DOUBLE PRECISION, INTENT(IN) :: A(:,:)
 
   ! SHAPE donne la dimension d'une matrice A:M*N sous la forme (M,N)
   Print *,SHAPE(A)
END SUBROUTINE 
 
 
END PROGRAM

- Soit tu dois déclarer l'interface des subroutines concernées dans le main. Cette solution est un peu lourde mais rigoureuse et élégante car tu peux définir tes interfaces dans un module puis simplement "use module" dans le programme. Pour ton exemple voici ce que ca donnerai sans module :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
 
PROGRAM 
 
   INTERFACE
   ! Place ici toutes les interfaces des subroutines concernées
 
   SUBROUTINE SHAPEMATRIX(A)
      DOUBLE PRECISION, INTENT(IN) :: A(:,:)
   END SUBROUTINE SHAPEMATRIX
 
   END INTERFACE
 
 
   INTEGER :: I,J
   DOUBLE PRECISION :: A(2,2)
 
   ! Initialisation de la matrice
   A = 0.0D00   
   CALL SHAPEMATRIX(A)
 
END PROGRAM
 
 
SUBROUTINE SHAPEMATRIX(A)
   DOUBLE PRECISION, INTENT(IN) :: A(:,:)
 
   ! SHAPE donne la dimension d'une matrice A:M*N sous la forme (M,N)
   Print *,SHAPE(A)
END SUBROUTINE

et avec module (assez pratique car ne surcharge pas le programme principal) :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
MODULE MES_INTERFACES
 
   INTERFACE
   ! Place ici toutes les interfaces des subroutines concernées
 
   SUBROUTINE SHAPEMATRIX(A)
      DOUBLE PRECISION, INTENT(IN) :: A(:,:)
   END SUBROUTINE SHAPEMATRIX
 
   END INTERFACE
 
END MODULE
 
 
PROGRAM 
   USE MES_INTERFACES
 
   INTEGER :: I,J
   DOUBLE PRECISION :: A(2,2)
 
   ! Initialisation de la matrice
   A = 0.0D00
   CALL SHAPEMATRIX(A)
 
END PROGRAM
 
SUBROUTINE SHAPEMATRIX(A)
   DOUBLE PRECISION, INTENT(IN) :: A(:,:)
 
   ! SHAPE donne la dimension d'une matrice A:M*N sous la forme (M,N)
   Print *,SHAPE(A)
END SUBROUTINE

Problème résolu !!

Merci énormément pour votre aide. Après vérification la solution marche parfaitement.

Merci pour tout