Problème sur filtre combobox et userform

Version imprimable

27/01/2011, 14h49
Esak59

1 pièce(s) jointe(s)

Problème sur filtre combobox et userform

Bonjour à toutes et à tous,

J'ai créer l'Userform sans problème et j'ai bidouiller un code VBA:
Mais voila j'ai un problème:

Quand je choisis un paramètre dans une liste déroulante de ma userform et que je clique sur le bouton " rechercher ", il me filtre toute ma base de données( toutes les colonnes, mais j'aimerais qu'il me filtre juste la colonne sélectionnée.

Je pense qu'il faut séparer le code sur chaque combobox, mais mes compétences en programmation sont très limitées.

Je joins un fichier excel pour exemple

Merci d'avance.
27/01/2011, 15h06
zazaraignée

Salut

Bienvenue sur le Forum DVB

Un titre plus explicite s'il vous plaît

Et personnellement, je préfèrerais un bout de code qui fait défaut à tout un fichier, pour commencer. Comme ça si l'un de nous voit une bidouille pas trop nette juste à vue, ça nous éviterait de fouiller tout le fichier.

Merci de me prêter de l'attention. Voici tout le code de mon userform :
Je veux juste dire que j'ai un niveau de débutant en ce qui concerne la programmation vba. :oops:

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Private Sub CommandButton1_Click()
 
ActiveSheet.Range("$A$3:$e$200").AutoFilter Field:=1, Criteria1:=ComboBox1.Value
ActiveSheet.Range("$A$3:$e$200").AutoFilter Field:=2, Criteria1:=ComboBox2.Value
ActiveSheet.Range("$A$3:$e$200").AutoFilter Field:=3, Criteria1:=ComboBox3.Value
ActiveSheet.Range("$A$3:$e$200").AutoFilter Field:=4, Criteria1:=ComboBox4.Value
ActiveSheet.Range("$A$3:$e$200").AutoFilter Field:=5, Criteria1:=ComboBox5.Value
 
Unload Me
 
End Sub
 
Private Sub UserForm_Initialize()
 
ActiveSheet.Range("$A$3:$e$200").AutoFilter
    Set dico = CreateObject("Scripting.dictionary")
    Set dico1 = CreateObject("Scripting.dictionary")
    Set dico2 = CreateObject("Scripting.dictionary")
    Set dico3 = CreateObject("Scripting.dictionary")
    Set dico4 = CreateObject("Scripting.dictionary")
 
For n = 2 To Range("e65536").End(xlUp).Row
 
a = Range("a" & n)
b = Range("b" & n)
c = Range("c" & n)
d = Range("d" & n)
e = Range("e" & n)
 
dico(a) = 1
dico1(b) = 1
dico2(c) = 1
dico3(d) = 1
dico4(e) = 1
 
Next
ComboBox1.List = dico.keys
ComboBox2.List = dico1.keys
ComboBox3.List = dico2.keys
ComboBox4.List = dico3.keys
ComboBox5.List = dico4.keys
 
End Sub

27/01/2011, 15h26
zazaraignée

Bien, heu... déjà que le filtre automatique filtre tout le tableau puisque c'est son mode de fonctionnement... Un filtre élaboré serait plus indiqué, et le résultat exporté sur une autre feuille, si mes souvenirs sont bons.

C'est tout ce que je peux te donner comme aide puisque je ne l'ai jamais fait en VBA (seulement directement dans Excel).

T'as essayé d'enregistrer une macro et de voir ce que ça donne et d'utiliser le code comme base de travail ?
27/01/2011, 15h40
Esak59

Tout à fait, j'ai déjà essayer le filtre élaboré mais j'ai besoin d'un interface avec des combobox pour sélectionner mes critères et filtrer mes données.

Le souci comme tu peux le voir c'est que dès que je sélectionne un paramètre et que je clique sur rechercher, il me filtre tout mon tableau (par exemple, je cherche que les personnes du sexe masculin).

En tout cas merci de prendre le temps de me répondre :ccool:

Edit: j'ai relu ton sujet
Sur le fichier joint, remplace ton code par ceci

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
Private Sub UserForm_Initialize()
Dim LastLig As Long, n As Long
 
With Sheets("bras")
    .AutoFilterMode = False
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
    Set dico = CreateObject("Scripting.dictionary")
    Set dico1 = CreateObject("Scripting.dictionary")
    Set dico2 = CreateObject("Scripting.dictionary")
    Set dico3 = CreateObject("Scripting.dictionary")
    Set dico4 = CreateObject("Scripting.dictionary")
    For n = 2 To LastLig
        dico(.Range("A" & n).Value) = 1
        dico1(.Range("B" & n).Value) = 1
        dico2(.Range("C" & n).Value) = 1
        dico3(.Range("D" & n).Value) = 1
        dico4(.Range("E" & n).Value) = 1
    Next n
End With
ComboBox1.List = dico.keys
ComboBox2.List = dico1.keys
ComboBox3.List = dico2.keys
ComboBox4.List = dico3.keys
ComboBox5.List = dico4.keys
 
End Sub
 
Private Sub CommandButton1_Click()
Dim LastLig As Long
Dim Cr(1 To 5)
Dim i As Byte
 
With Sheets("bras")
    .AutoFilterMode = False
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
    For i = 1 To 5
        Cr(i) = IIf(Me.Controls("ComboBox" & i).ListIndex = -1, "<>", Me.Controls("ComboBox" & i).Value)
    Next i
    With .Range("A1:E" & LastLig)
        .AutoFilter Field:=1, Criteria1:=Cr(1)
        .AutoFilter Field:=2, Criteria1:=Cr(2)
        .AutoFilter Field:=3, Criteria1:=Cr(3)
        .AutoFilter Field:=4, Criteria1:=Cr(4)
        .AutoFilter Field:=5, Criteria1:=Cr(5)
    End With
End With
Unload Me
End Sub

27/01/2011, 16h34
Esak59

Merci pour votre rapidité.

Le code qui tu m'as donné ne change rien. Peut-être que je m'exprime mal.

Quand je choisis même un seul paramètre et que je clique sur rechercher, il me filtre tout le tableau, je n'ai même pas une seule proposition ce qui est impossible car les filtres normaux, fonctionne très bien. J'aimerais juste simplifier au maximum la recherche sur la base de données grâce à une interface intuitive.
27/01/2011, 16h43
mercatog

J'avais édité ma réponse en relisant ta question
essaie le nouveau code

Un membre d'un autre forum m'as trouvé la solution, je vous remercie tout de même pour le temps que vous avez passer pour moi. Je poste la solution à mon problème au cas ou si quelqu'un d'autre rencontre ce genre de galères.

Merci mille fois encore.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
Private Sub ComboBox1_Change()
 
End Sub
 
Private Sub CommandButton1_Click()
If ComboBox1.ListIndex > -1 Then ActiveSheet.Range("$A$2:$e$200").AutoFilter Field:=1, Criteria1:=ComboBox1.Value
If ComboBox2.ListIndex > -1 Then ActiveSheet.Range("$A$2:$e$200").AutoFilter Field:=2, Criteria1:=ComboBox2.Value
If ComboBox3.ListIndex > -1 Then ActiveSheet.Range("$A$2:$e$200").AutoFilter Field:=3, Criteria1:=ComboBox3.Value
If ComboBox4.ListIndex > -1 Then ActiveSheet.Range("$A$2:$e$200").AutoFilter Field:=4, Criteria1:=ComboBox4.Value
If ComboBox5.ListIndex > -1 Then ActiveSheet.Range("$A$2:$e$200").AutoFilter Field:=5, Criteria1:=ComboBox5.Value
 
'Unload Me
 
End Sub
 
Private Sub CommandButton2_Click()
Dim I As Byte
  For I = 1 To 5
    Me.Controls("ComboBox" & I).ListIndex = -1
  Next I
  On Error Resume Next
  Sheets("bras").ShowAllData
 
End Sub
 
Private Sub UserForm_Initialize()
Dim Lg As Long
Dim I As Long
Dim J As Integer
 
    ActiveSheet.Range("$A$2:$e$200").AutoFilter
'    Set dico = CreateObject("Scripting.dictionary")
'    Set dico1 = CreateObject("Scripting.dictionary")
'    Set dico2 = CreateObject("Scripting.dictionary")
'    Set dico3 = CreateObject("Scripting.dictionary")
'    Set dico4 = CreateObject("Scripting.dictionary")
  Lg = Range("e65536").End(xlUp).Row
  For J = 1 To 5
    For I = 4 To Lg             'Range("e65536").End(xlUp).Row
      Me.Controls("ComboBox" & J) = Cells(I, J)
      If Me.Controls("ComboBox" & J).ListIndex = -1 Then
        Me.Controls("ComboBox" & J).AddItem Cells(I, J)
      End If
    Next I
    Me.Controls("ComboBox" & J).ListIndex = -1
  Next J
 
'a = Range("a" & n)
'b = Range("b" & n)
'c = Range("c" & n)
'd = Range("d" & n)
'e = Range("e" & n)
'
'dico(a) = 1
'dico1(b) = 1
'dico2(c) = 1
'dico3(d) = 1
'dico4(e) = 1
'
'Next
'ComboBox1.List = dico.keys
'ComboBox2.List = dico1.keys
'ComboBox3.List = dico2.keys
'ComboBox4.List = dico3.keys
'ComboBox5.List = dico4.keys
 
End Sub

ou bien

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
Private Sub UserForm_Initialize()
Dim LastLig As Long, n As Long
 
With Sheets("bras")
    .AutoFilterMode = False
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
    Set dico = CreateObject("Scripting.dictionary")
    Set dico1 = CreateObject("Scripting.dictionary")
    Set dico2 = CreateObject("Scripting.dictionary")
    Set dico3 = CreateObject("Scripting.dictionary")
    Set dico4 = CreateObject("Scripting.dictionary")
    For n = 2 To LastLig
        dico(.Range("A" & n).Value) = 1
        dico1(.Range("B" & n).Value) = 1
        dico2(.Range("C" & n).Value) = 1
        dico3(.Range("D" & n).Value) = 1
        dico4(.Range("E" & n).Value) = 1
    Next n
End With
ComboBox1.List = dico.keys
ComboBox2.List = dico1.keys
ComboBox3.List = dico2.keys
ComboBox4.List = dico3.keys
ComboBox5.List = dico4.keys
 
End Sub
 
Private Sub CommandButton1_Click()
Dim LastLig As Long
Dim i As Byte
 
With Sheets("bras")
    .AutoFilterMode = False
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
    With .Range("A1:E" & LastLig)
        For i = 1 To 5
            If Me.Controls("ComboBox" & i).ListIndex > -1 Then .AutoFilter Field:=i, Criteria1:=Me.Controls("ComboBox" & i).Value
        Next i
    End With
End With
Unload Me
End Sub

27/01/2011, 17h13
zazaraignée

Citation:

Envoyé par Esak59

Un membre d'un autre forum m'as trouvé la solution, je vous remercie tout de même pour le temps que vous avez passer pour moi. Je poste la solution à mon problème au cas ou si quelqu'un d'autre rencontre ce genre de galères.

Important :
SVP montrer la solution à ton problème tel que tu l'as résolu et cliquer sur :resolu:
27/01/2011, 17h27
Esak59

C'est bon c'est résolu :D j'ai indiqué la solution un peu plus haut.

Merci encore :lol:

Edit: Quelques erreurs dans le code, mais beaucoup de questions...
28/01/2011, 11h01
Esak59

Bonjour à toutes et à tous, j'ai une question pour vous:

Si j'ai besoin de rajouter des colonnes (imaginons que j'ai 50 colonnes à filtrer avec 50 combobox dans l'userbox), comment puis-je modifier le code VBA.

J'aimerais également ne pas prendre en compte la 1ère et 3ème colonne. C'est à dire qu'elles ne seront pas présentées dans l'userform (avec des combobox). En espérant que c'est possible...

Et juste pour ne plus poser de questions, pourriez-vous m'expliquer comment ça fonctionne tout ça (genre des commentaires à coté des lignes de code), parce que c'est génial que ça fonctionne, mais j'aimerais surtout comprendre et apprendre le VB pour ne plus avoir à vous embêter pour une question bête. :mouarf:

Je vous remercie par avance. :)

Esak

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Private Sub CommandButton1_Click()
Dim LastLig As Long
Dim i As Byte
 
With Sheets("bras")
    .AutoFilterMode = False                             'on enlève le filtre automatique de la page
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row      'dernière ligne remplie de la colonne 1
    With .Range("A1:E" & LastLig)
        For i = 1 To 5                                  'on parcourt les 5 combobox nommées ComboBox1, ComboBox2...ComboBox5
            'Me.Controls("ComboBox" & i) signifie ComboBox1 pour i=1, Combobob2 pour i=2....
            'si on choisit un item de la combobox "Combobox1" ou "Combobox2"..., sa Listindex est > -1
            'alors on filtre sur la colonne 1 (pour ComboBox1), 2 (pour ComboBox2)... avec comme critère la valeur choisie dans la combo correspondante
            If Me.Controls("ComboBox" & i).ListIndex > -1 Then .AutoFilter Field:=i, Criteria1:=Me.Controls("ComboBox" & i).Value
        Next i
        'la boucle précédente est équivalente à:
        '-------------------------------------------------------------------------------------
        'If Me.ComboBox1.Listindex>-1 then .AutoFilter Field:=1, Criteria1:=Me.ComboBox1.Value
        'If Me.ComboBox2.Listindex>-1 then .AutoFilter Field:=2, Criteria1:=Me.ComboBox2.Value
        'If Me.ComboBox3.Listindex>-1 then .AutoFilter Field:=3, Criteria1:=Me.ComboBox3.Value
        'If Me.ComboBox4.Listindex>-1 then .AutoFilter Field:=4, Criteria1:=Me.ComboBox4.Value
        'If Me.ComboBox5.Listindex>-1 then .AutoFilter Field:=5, Criteria1:=Me.ComboBox5.Value
        '-------------------------------------------------------------------------------------
    End With
End With
Unload Me
End Sub

Ok merci pour toutes ces précisions je comprends un peu mieux déjà, mais juste deux truc, quand tu dis i = 1 to 5 :
Il prend compte du filtrage de la colonne 1 à 5 mais si je veux qui prend compte jusqu’à, par exemple, la colonne 15.
Parce que j'ai entré cette valeur et il me met une erreur. Peut-etre parce qu'il ne trouve les combobox.

Ensuite, autre question, tu m'as aidé pour code le commandbutton1, mais je dois également, modifier UserForm_initialize, pour remplir mes combobox. Userform n'est pas fait pour filtrer, mais juste pour rechercher les informations dans la feuille ? Car le code me filtre tout mème avec un seul parametre
Code:

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 Private Sub UserForm_Initialize() Dim Lg As Long Dim i As Long Dim J As Integer ActiveSheet.Range("$A$3:$e$200").AutoFilter Lg = Range("e65536").End(xlUp).Row For J = 1 To 5 For i = 4 To Lg Me.Controls("ComboBox" & J) = Cells(i, J) If Me.Controls("ComboBox" & J).ListIndex = -1 Then Me.Controls("ComboBox" & J).AddItem Cells(i, J) End If Next i Me.Controls("ComboBox" & J).ListIndex = -1 Next J
En gros la marche à suivre dans le code c'est:

Remplisage combobox avec plusieurs critères (userform_initialize), puis ensuite, quand j'ai choisi tous mes paramètres, c'est le commandbutton1 qui filtre.

Merci d'avance. :ccool::lol:

Oui, tu es sur la bonne voie
pour l'exemple tu as 15 ComboBox, nommées ComboBox1...Combobox15
Chaque Combobox_i permet de filtrer la colonne i
Maintenant, si tes colonnes à filtrer ne se suivent pas, tu pourrais par exemple utiliser un tableau comportant les colonnes
exemple

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Option Base 1
Private Sub UserForm_Initialize()
Dim LastLig As Long, j As Long
Dim i As Byte
Dim ColCrit
 
ColCrit = Array(2, 3, 4, 6, 7, 8, 9, 13, 15, 18, 19, 20, 23, 26, 27)
With Sheets("bras")
    .AutoFilterMode = False                             'on enlève le filtre automatique de la page
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row      'dernière ligne remplie de la colonne 1
    For i = 1 To UBound(ColCrit)                                      'on parcourt les 15 combobox nommées ComboBox1, ComboBox2...ComboBox5
        For j = 2 To LastLig
            Me.Controls("ComboBox" & i).Value = .Cells(j, ColCrit(i)).Value
            If Me.Controls("ComboBox" & i).ListIndex = -1 Then Me.Controls("ComboBox" & i).AddItem .Cells(j, ColCrit(i)).Value
            Me.Controls("ComboBox" & i).ListIndex = -1
        Next j
    Next i
End With
End Sub
 
Private Sub CommandButton1_Click()
Dim LastLig As Long
Dim i As Byte
Dim ColCrit
 
 
ColCrit = Array(2, 3, 4, 6, 7, 8, 9, 13, 15, 18, 19, 20, 23, 26, 27)
With Sheets("bras")
    .AutoFilterMode = False                             'on enlève le filtre automatique de la page
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row      'dernière ligne remplie de la colonne 1
    With .Range("A1:AA" & LastLig)
        For i = 1 To UBound(ColCrit)                                  'on parcourt les 5 combobox nommées ComboBox1, ComboBox2...ComboBox5
            If Me.Controls("ComboBox" & i).ListIndex > -1 Then .AutoFilter Field:=ColCrit(i), Criteria1:=Me.Controls("ComboBox" & i).Value
        Next i
    End With
End With
Unload Me
End Sub

Dans l'exemple ci-dessus
ComboBox1 -> Colonne 2, ComboBox2 -> Colonne 3, ComboBox3 -> Colonne 4, ComboBox4 -> Colonne 6 ...etc

28/01/2011, 16h18
Esak59

Ca fonctionne du feu de dieu, c'est génial. J'ai finis la 1ère phase de mon projet.
Merci, si j'avais d'autres questions, je n'hésiterais pas à revenir vous demander quelques conseils. Merci encore, surtout à toi mercatog :ccool::ccool::ccool:

Bon continuation et HAVE FUN !