[XSL]Fonction pour Path

Version imprimable

15/02/2006, 14h13
Zep3k!GnO

[XSL]Fonction pour Path
Bonjour à tous :D

Bin comme l'explique à moitier mon titre, je voudrai savoir si quelqu'un sait s'il existe une fonction qui retourne le Path de l'élément courant...

Par exemple : (le xml)
Code:

1 2 3 4 5 6 7 8 9 10 11 12 <test> <oui> OK </oui> <oui> DAC </oui> <oui> Biensur </oui> </test>
Si je suis dans le 2ème <oui>, je cherche une fonction qui me retournerai /test/oui[2]
Je suis à l'écoute.
Merci :D
--
Zep3k!GnO

On est des rangers mec, des rangers...

Bonjour,

la fonction, il faut l'écrire en XSLT :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 
	<xsl:output method="text"/>
 
	<xsl:template match="/">
		<xsl:call-template name="affiche-xpath">
			<xsl:with-param name="element" select="test/oui[2]"/>
		</xsl:call-template>
	</xsl:template>
 
	<xsl:template name="affiche-xpath">
		<xsl:param name="element"/>
		<xsl:param name="xpath"/>
		<xsl:choose>
			<xsl:when test="$element/parent::node()">
				<!-- Détermination du rang -->
				<xsl:variable name="rang" select="count($element/preceding-sibling::*[name() = name($element)]) + 1"/>
				<xsl:call-template name="affiche-xpath">
					<xsl:with-param name="element" select="$element/parent::*"/>
					<xsl:with-param name="xpath">
						<xsl:value-of select="concat('/', name($element))"/>
						<xsl:if test="$rang &gt; 1">
							<xsl:value-of select="concat('[', $rang, ']')"/>
						</xsl:if>
						<xsl:value-of select="$xpath"/>
					</xsl:with-param> 
				</xsl:call-template>
			</xsl:when>
			<xsl:otherwise>
				<xsl:value-of select="$xpath"/>
			</xsl:otherwise>
		</xsl:choose>
	</xsl:template>
 
</xsl:stylesheet>

Cette fonction n'est pas assez générique pour afficher un chemin pour n'importe quel type de noeud, elle ne fonctionne que pour les éléments.

16/02/2006, 11h24
Zep3k!GnO

Yep, SUPER, MERCI :D
Je teste ca dès que j'ai terminé mon xsl en cours...
En tous cas c'est sympa de ta part d'avoir pris du temps pour me faire partager ta fonction...
J'avais vraiment pas pensé à le faire en xsl, je pensai au pire le faire avec un javascript grace à DOM, mais ta fonction à l'air tout à fait de ce que je cherche.
Si j'ai un soucis j'te dirai..
Encore merci ;)

Zep3k!GnO
On est des rangers mec, des rangers...
16/02/2006, 16h09
Zep3k!GnO

Je viens de tester ta fonction et...<sound_effect>roulement de tambour</sound_effect>
Ca fonctionne carrément top moumoute ! :P
J'ai réadapté un ou 2 trucs pour mes besoins mais ca marche nickel !
alors encore MERCI.

Zep3k!GnO
On est de srangers mec, des rangers....

P.s: sans vouloir faire de trop, mais c'est vachement bien écrit, j'comprend pourquoi t'es modo :P

++