InputBox masquer pour password

Bonjour,

Vous l'avait sûrement comprit d’après le titre, mon but et de masquer un mdp à la saisie de l'utilisateur.

Je sais que ce sujet est plutôt compliqué... :p

Contexte :
Le point d'entré est un script vbs, qui demande un mdp à l'user. Je veut que ce mdp n'apparaisse pas. A l'heure actuelle j'utilise une inputBox (qui ne marche po :D )

Comme tout les posts que je trouve sont anciens je me permet de vous demander les solutions existantes... Je doit le déployer sur plusieurs terminaux en xp Sp3

J'ai vu : post de omen999 mais il n'est plus à jour ... :(

Je voudrait éviter de passer par un script IE à cause des politique de sécurité appliquée dans mon entreprise.

Quelles sont les moyens/techniques qui me permettent de faire cela ?

Merci d'avance ;)

bonjour,
ici (le script d'YMP)

Nikel, merci bien, je regarde ça demain ;)

-----------------------

C'est exactement ce que je voulait, je me permet de re-poster le code

Code de VSVLAD sur forum.script-coding.info

Citation:

---

Dim Wrap, pAddr
Dim CaptionText, InputData

Const NV_INPUTBOX = &H5000&
Const EM_SETPASSWORDCHAR = &HCC

Set Wrap = CreateObject("DynamicWrapperX")
Set pRef = GetRef("TimerProc")

Wrap.Register "user32.dll", "FindWindowA", "i=ls", "r=l"
Wrap.Register "user32.dll", "FindWindowExA", "i=llsl", "r=l"
Wrap.Register "user32.dll", "SetTimer", "i=llll", "r=l"
Wrap.Register "user32.dll", "KillTimer", "i=ll", "r=l"
Wrap.Register "user32.dll", "SendMessageA", "i=llll", "r=l"

pAddr = Wrap.RegisterCallback(pRef, "i=llll", "r=l")

Function InputBoxEx(strPromt, strCaption)
CaptionText = strCaption
Call Wrap.SetTimer (0, 0, 10, pAddr)
InputData = InputBox(strPromt, strCaption)
InputBoxEx = InputData
End Function

Sub TimerProc(hWnd, uMsg, idEvent, dwTime)
Dim myHwnd
myHwnd = Wrap.FindWindowExA(Wrap.FindWindowA(0, CaptionText), 0, "Edit", 0)
Call Wrap.SendMessageA(myHwnd, EM_SETPASSWORDCHAR, 42, 0)
Call Wrap.KillTimer (0, idEvent)
End Sub

AA = InputBoxEx ("Введите ваш пароль =)", "Ввод данных")
MsgBox AA

---

Je passe en resolut, merci bien