[Tableaux Structurés] Suppression des lignes

Bonjour,

Je souhaite supprimer les lignes d'un tableau structuré, merci de votre aide pour corriger ce code, car actuellement ce dernier fait juste l'effacement des données (Clear).

Code:

---

1 2 3 4 5 6 7 8

Sub OuvrirOngletGL() Sheets("GL").Visible = True Sheets("GL").Activate Range("Tableau_GL").Clear ' Efface seulement les données.   MsgBox "Le tableau GL a été vidé" Range("A2").Activate End Sub

---

:fleche: L'idée c'est de supprimer les lignes afin de pouvoir faire une nouvelle importation de données.

Citation:

---

Envoyé par Malick

---

Bonjour Malick,

Code:

---

Sheets("GL").ListObjects("Tableau_GL").DataBodyRange.Delete

---

Bonjour Eric,

Merci :ccool: la suppression se fait bien à l'ouverture.
Cependant, lorsque le tableau est vide et que j'ouvre l'onglet en question à nouveau, j'ai ce message :

Pièce jointe 558317

Code:

---

1 2 3 4 5 6 7 8

Sub OuvrirOngletGL() Sheets("GL").Visible = True Sheets("GL").Activate ' Suppression des données à l'activation de la feuille Sheets("GL").ListObjects("Tableau_GL").DataBodyRange.Delete MsgBox "Le tableau GL a été vidé" Range("A2").Activate End Sub

---

Débogage : en jaune la ligne Sheets("GL").ListObjects("Tableau_GL").DataBodyRange.Delete
J'imagine que c'est parce qu'il ne trouve plus de données à supprimer. :koi:

Citation:

---

Envoyé par Malick

---

Essaye :

Code:

---

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17

Sub OuvrirOngletGL()   With Sheets("GL") .Visible = True .Activate ' Suppression des données à l'activation de la feuille With .ListObjects("Tableau_GL") If .ListRows.Count > 0 Then .DataBodyRange.Delete MsgBox "Le tableau GL a été vidé" End If End With .Range("A2").Activate End With   End Sub

---

Bonjour,

Code:

---

1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21

Sub SuppressionLigneTableau2() nomtableau = "tableau1" n = 1 If Range(nomtableau).Item(n, 1) <> "" Then Range(nomtableau).Rows(n).delete End Sub   Sub InsèreLigneTableau2() nomtableau = "tableau1" Range(nomtableau).Rows(1).Insert End Sub   Sub AjoutFinTableau2() nomtableau = "tableau1" If Range(nomtableau).Item(1, 1) <> "" Then n = Range(nomtableau).Rows.Count + 1 Else n = 1 Range(nomtableau & "[nom]").Item(n, 1) = "xxxx" End Sub   Sub VideTableau2() nomtableau = "tableau1" If Range(nomtableau).Item(1, 1) <> "" Then Range(nomtableau).delete End Sub

---

Boisgontier

Salut,

Citation:

---

Envoyé par Eric KERGRESSE

Essaye :

---

:fleche: Merci Eric, ça marche nickel. :king:

Citation:

---

Envoyé par boisgontierjacques

Bonjour,

Boisgontier

---

:fleche: Merci Boisgontierjacques :ccool:

Bonne journée à vous

:merci:

Salut Malick,

Depuis longtemps, j'ai mis ces fonctions génériques dans mon xlTools... Et perso, je préfère ne pas passer par la feuille mais par la plage, ce qui permet au code de continuer à fonctionner en cas de déplacement sur une autre feuille ou si on la renomme. Ca rend le code très générique ;)

Code:

---

1 2 3

Sub Table_Clear(Tablename As String) If Not Range(Tablename).ListObject.DataBodyRange Is Nothing Then Range(Tablename).ListObject.DataBodyRange.Delete End Sub

---

Bien que tu ne l'aies pas demandé, mais comme un code t'a été donné...

Pour insérer, je préfère utiliser le listobject et le listrow, qui permettent de travailler avec la plage du listrow

Code:

---

1 2 3 4 5

Sub test() Dim lr As ListRow   Set lr = Range("tableau1").ListObject.ListRows.Add() End Sub

---

Ca peut alors être utilisé de façon générique, avec un code lui aussi placé dans le xlTools, comme je le montre dans cette contribution

Code:

---

1 2 3 4 5 6 7 8 9 10 11 12

Sub Table_Insert(Tablename As String, Values, Optional Before As Long = 0) Dim lr As ListRow Dim lo As ListObject Dim Counter As Long   Set lo = Range(Tablename).ListObject If Before < 1 Or Before > lo.ListRows.Count Then Before = lo.ListRows.Count + 1 Set lr = lo.ListRows.Add(Before) For Counter = 0 To UBound(Values) Step 2 lr.Range(lo.ListColumns(Values(Counter)).Index).Value = Values(Counter + 1) Next End Sub

---

Dès lors, pour insérer des données dans le tableau après l'avoir vidé, on peut utiliser ceci

Code:

---

1 2 3 4 5 6

Sub Test() xlTools.Table_Clear "tableau1" xlTools.Table_Insert "tableau1", Array("Nom", "Térieur", "Prénom", "Alain", "DN", DateSerial(1985, 12, 14)) xlTools.Table_Insert "tableau1", Array("Prénom", "Jean", "Nom", "Aymar") xlTools.Table_Insert "tableau1", Array("DN", DateSerial(1970, 9, 14), "Nom", "Hénas", "Prénom", "Julie"), 1 End Sub

---

On remarque alors que l'on peut insérer une ligne où on veut (les deux premières sont poussées à la suite alors que la troisième est placée en première ligne) et tu peux pousser tes données dans le tableau sans avoir à te soucier de l'ordre des colonnes (chaque ligne d'insertion possède un ordre différent pour les données). Si tu les permutes, ton code continue à fonctionner.

Pièce jointe 558875



Tu peux aussi pousser un array entier dans le tableau, par exemple pour récupérer un recordset d'Access ou de SQL dans un tableau structuré (ici, j'ai créé le tableau par code, mais le principe est là). Tu n'auras plus le choix de l'ordre des colonnes dans ce cas, mais tu passeras les données en 1 bloc (C'est une tuerie quand tu ramènes un recordset SQL server de 100000 lignes dans un tableau => quasi instantané)

Code:

---

1 2 3 4 5 6 7 8 9 10 11 12

Sub Test1() Dim t(1, 2)   xlTools.Table_Clear "Tableau1" t(0, 0) = "Alain" t(0, 1) = "Térieur" t(0, 2) = DateSerial(1985, 12, 14) t(1, 0) = "Jean" t(1, 1) = "Aymar" t(1, 2) = DateSerial(1970, 9, 14) Range("tableau1").Resize(2, 3).Value = t End Sub

---

En espérant t'avoir aidé ;)

Salut Pierre,

Excellente démonstration :ccool:

Effectivement avec ta proposition,on ne se soucie plus du nom de la feuille.

Clairement ta contribution m'a aidé aussi, mais en aidera plus d'un autre sûrement.

:merci:

Bonjour,

Pour vider un tableau (#3):

Code:

---

1 2 3 4

Sub VideTableau2() nomtableau = "tableau1" If Range(nomtableau).Item(1, 1) <> "" Then Range(nomtableau).delete End Sub

---

Boisgontier

La solution pour l'ajout d'une ligne proposée au message #5 est erronée (outre la non déclaration des variables, le nom paramétrage de la fonction qui fait qu'on ne peut l'utiliser qu'avec le tableau1,...), car elle ne tient pas compte de la présence éventuelle d'une ligne de total en bas de la table de données. En effet, elle pousse la nouvelle donnée dans la ligne de total, ce qui est du plus mauvais effet :weird::aie::calim2:

Pièce jointe 559021

L'utilisation de ListRows.Add se fout de la présence de la ligne de total et délègue au ListObject la responsabilité de tenir compte de la présence éventuelle de cette ligne.

Pour revenir au sujet de la demande qui est de supprimer les lignes d'un tableau (de le vider, en fait, sans tenir compte d'une quelconque condition), la solution proposée au #9 est assez étonnante. Elle laisse supposer que le tableau est vide si la première cellule de la plage structurée est vide, puisqu'elle ne videra le tableau que si cette cellule n'est pas vide. Dès lors, le tableau suivant ne sera pas vidé... :weird::calim2::aie: Passer par le ListObject ( Listobject.ListRows.Count> 0 ou Not ListObject.DataBodyRange Is Nothing) supprime les lignes si le tableau n'est pas vide, sans tenir compte d'une condition qui n'est pas exprimée dans la demande, et qui s'avère ne pas être judicieuse pour déterminer qu'un tableau doit être vidé ou pas :roll:

Pièce jointe 559023


En résumé: Pour coder de façon propre et professionnelle, il faut utiliser les bons outils. Lorsque l'on travaille sur la structure d'un tableau structuré (ajouter ou supprimer des lignes, c'est toucher à la structure), il est de loin préférable de travailler avec le listobject plutôt que d'essayer des fantaisies caduques ou franchement erronées qui ne travaillent qu'avec la plage ;)

Citation:

---

Envoyé par Pierre Fauconnier

La solution pour l'ajout d'une ligne proposée au message #5 est erronée (outre la non déclaration des variables, le nom paramétrage de la fonction qui fait qu'on ne peut l'utiliser qu'avec le tableau1,...), car elle ne tient pas compte de la présence éventuelle d'une ligne de total en bas de la table de données. En effet, elle pousse la nouvelle donnée dans la ligne de total, ce qui est du plus mauvais effet :weird::aie::calim2:

Pièce jointe 559021

L'utilisation de ListRows.Add se fout de la présence de la ligne de total et délègue au ListObject la responsabilité de tenir compte de la présence éventuelle de cette ligne.

Pour revenir au sujet de la demande qui est de supprimer les lignes d'un tableau (de le vider, en fait, sans tenir compte d'une quelconque condition), la solution proposée au #9 est assez étonnante. Elle laisse supposer que le tableau est vide si la première cellule de la plage structurée est vide, puisqu'elle ne videra le tableau que si cette cellule n'est pas vide. Dès lors, le tableau suivant ne sera pas vidé... :weird::calim2::aie: Passer par le ListObject ( Listobject.ListRows.Count> 0 ou Not ListObject.DataBodyRange Is Nothing) supprime les lignes si le tableau n'est pas vide, sans tenir compte d'une condition qui n'est pas exprimée dans la demande, et qui s'avère ne pas être judicieuse pour déterminer qu'un tableau doit être vidé ou pas :roll:

Pièce jointe 559023

Pierre, comment ajouter un total en fin de tableau à la suite de l'ajout des lignes ?

Merci


En résumé: Pour coder de façon propre et professionnelle, il faut utiliser les bons outils. Lorsque l'on travaille sur la structure d'un tableau structuré (ajouter ou supprimer des lignes, c'est toucher à la structure), il est de loin préférable de travailler avec le listobject plutôt que d'essayer des fantaisies caduques ou franchement erronées qui ne travaillent qu'avec la plage ;)

---

Bonjour

Ta question noyée au milieu de la citation...

Un tableau a intrinsèquement une ligne de total, affichable/masquable à volonté

Code:

---

Range("Tableau1").ListObject.ShowTotals=True

---

ou False

"Tableau1" à remplacer par la référence à l'objet qui est manipulé

Mais sans code le bouton existe déjà dans l'interface Excel...