MSDE et VB6 ?

Version imprimable

09/09/2005, 01h01
__fabrice

MSDE et VB6 ?

salut à tous,

Je voudrai savoir (je re-debute en VB6) comment faire pour utiliser MSDE (Sql Server gratuit) et VB6, pour gerer, entre autres, des procedures stockées.

Merci à tous,
Fabrice

par exemple

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Private Sub Command1_Click()
Dim MaConn As ADODB.Connection, MonRs As ADODB.Recordset, MaCommand As ADODB.Command
Dim paramStart As ADODB.Parameter, paramEnd As ADODB.Parameter
 
Set MaConn = New ADODB.Connection
With MaConn
    .ConnectionString = "Provider=SQLOLEDB.1;Integrated Security=SSPI;Persist Security Info=False;Initial Catalog=Northwind;Data Source=ISPCF060260"
    .CursorLocation = adUseClient
    .Mode = adModeRead
    .Open
End With
Set MaCommand = New ADODB.Command
With MaCommand
    .CommandType = adCmdStoredProc
    .CommandText = "[Employee Sales by Country]"
    .ActiveConnection = MaConn
    Set paramStart = .CreateParameter("@Beginning_Date", adDate, adParamInput)
    Set paramEnd = .CreateParameter("@Ending_Date", adDate, adParamInput)
    .Parameters.Append paramStart
    .Parameters.Append paramEnd
End With
paramStart.Value = CDbl(#1/9/1996#)
paramEnd.Value = CDbl(#9/30/1996#)
Set MonRs = New ADODB.Recordset
With MonRs
    .ActiveConnection = MaConn
    .CursorType = adOpenStatic
    .LockType = adLockReadOnly
    .Open MaCommand
End With
Set Me.DataGrid1.DataSource = MonRs
 
End Sub

09/09/2005, 09h32
__fabrice

salut,

ok merci. Je vais voir ce que je peux faire avec çà.

Fabrice
09/09/2005, 10h43
__fabrice

me revoilà. Bon, j'ai des probleme de connection. Voila ce que j'ai fait pour me connecter :

Code:

.ConnectionString = "Provider=SQLOLEDB;Data Source=ISPCF060260;Initial Catalog=bddEssai1;User ID=fabrice;Password=mot_de_passe"

J'ai plusieurs questions :

1- Data Source c'est quoi ?, le data source ADO sur la form ?. Parce que je n'ai à ma disposition que le nom de la table "bddEssai1" et celui de la procédure stockée "StorProc_bddEssai1_Classes"

2- lorsque je me connecte à MSDE via Web Data Administrator, je met comme user : localhost\fabrice, le mot de passe et le nom du serveur SQL "localhost". Et cela marche, dois-je repercuter çà dans la connexion dans VB ?

3- Ma procédure stockée c'est juste un SELECT, pour tester. Je pense que je peux virer les lignes avec les parametres ?

Dans ton exemple, a quoi serve ces parametres dans la ligne de connexion ?

Merci beaucoup.
Fabrice
09/09/2005, 13h53
bidou

1) dans ton cas, datasource c'est localhost
2) oui tu doit mettre le bon user et le bon password dans userID et password
3) En effet pas besoin des paramêtres si la requête n'en contient pas.
quels paramêtres ?
12/09/2005, 14h50
__fabrice

ok, merci, c'est bon :)

Par contre, j'ai un soucis avec MSDE maintenant :(, j'ai mis un post (pas de serveur ni de service) mais j'ai pas de réponses :? :cry:

Fabrice