Liste de macro

Version imprimable

Liste de macro

Bonjour.
Je voulais trouver une macro qui me liste la totalité des macros située dans les 120 feuilles de mon classeur. J'ai trouvé le code suivant, mais qui ne fonctionne pas. Il affiche une erreur au sujet de ByRef que je ne sais pas résoudre.
Si quelqu'un a la solution, merci.

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
Sub ListAllSheetMacros()
    Dim ws As Worksheet
    Dim vbComp As Object
    Dim vbMod As Object
    Dim macroNames() As String
    Dim wsMacroList As Worksheet
    Dim rowIndex As Long
    Dim i As Long
    Dim macroListIndex As Long
 
    ' Créer une nouvelle feuille ou utiliser une feuille existante pour lister les macros
    On Error Resume Next
    Set wsMacroList = ThisWorkbook.Sheets("Liste des Macros")
    On Error GoTo 0
 
    If wsMacroList Is Nothing Then
        Set wsMacroList = ThisWorkbook.Sheets.Add(After:=ThisWorkbook.Sheets(ThisWorkbook.Sheets.Count))
        wsMacroList.Name = "Liste des Macros"
    Else
        ' Effacer le contenu de la feuille existante si elle existe déjà
        wsMacroList.Cells.Clear
    End If
 
    ReDim macroNames(1 To 1000) ' Ajuster la taille du tableau si nécessaire
 
    ' Parcourir toutes les feuilles du classeur
    For Each ws In ThisWorkbook.Worksheets
        If ws.CodeName <> "" Then ' Vérifier si la feuille a un nom de code VBA
            Set vbMod = ThisWorkbook.VBProject.VBComponents(ws.CodeName).CodeModule
            For i = 1 To vbMod.CountOfLines
                macroName = vbMod.ProcOfLine(i, vbext_pk_Proc)
                If macroName <> "" Then
                    If Not IsMacroSheetInList(macroNames, macroName) Then
                        macroListIndex = macroListIndex + 1
                        macroNames(macroListIndex) = macroName
                    End If
                End If
            Next i
        End If
    Next ws
 
    ' Afficher les noms des macros dans la feuille "Liste des Macros"
    rowIndex = 1
    For i = 1 To macroListIndex
        wsMacroList.Cells(rowIndex, 1).Value = macroNames(i)
        rowIndex = rowIndex + 1
    Next i
End Sub
 
Function IsMacroSheetInList(arr() As String, macroName As String) As Boolean
    Dim i As Long
 
    For i = LBound(arr) To UBound(arr)
        If arr(i) = macroName Then
            IsMacroSheetInList = True
            Exit Function
        End If
    Next i
 
    IsMacroSheetInList = False
End Function

06/04/2024, 17h00
User

Bonjour,

Le type de l'argument d'une fonction ou d'une procédure ne semble pas convenir :

Vous passer peut être un argument en variant à une procédure ou une fonction alors qu'il attend un argument avec un type précis (integer, string, etc.).

Peut-être mettre :

Code:

Option Explicit

en haut du module vous voir s'il y a des variables non déclarées ..

https://learn.microsoft.com/fr-fr/of...icit-statement
06/04/2024, 19h50
TitiPointCom67

Bonjour.
La seule variable non déclarée au regard d'Option Explicit, c'est macroName et même lorsque je la déclare (sans spécifier As ... ne sachant pas quoi mettre) l'erreur reste la même : Erreur de compilation : Type d'argument ByRef incompatible.

Je suis très loin d'être calé en VBA et je ne sais absolument pas ce que cette erreur signifie ni comment y remédier.
06/04/2024, 19h54
User

Essayez voir avec :

Code:

Dim macroName As String

Après indiquer la ligne de l'erreur serait bien ;)

Hello,

Premièrement, il faut ajouter la référence Microsoft Visual Basic for Application Extensibility, ou déclarer la constante vbext_pk_Proc.
Deuxièmement, une déclaration de variable est manquante comme l'a souligné User.

Enfin, lorsqu'il est fonctionnel, ce code ne liste que les fonctions membre des feuilles, j'espère que c'est ce que tu recherches.

Voici le code corrigé par mes soins (sans référence supplémentaire):

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
Option Explicit
 
Sub ListAllSheetMacros()
    Const vbext_pk_Proc = 0     '// Declaration de constante manquante
    Dim ws As Worksheet
    Dim vbComp As Object
    Dim vbMod As Object
    Dim macroNames() As String
    Dim wsMacroList As Worksheet
    Dim rowIndex As Long
    Dim i As Long
    Dim macroListIndex As Long
 
    ' Créer une nouvelle feuille ou utiliser une feuille existante pour lister les macros
    On Error Resume Next
    Set wsMacroList = ThisWorkbook.Sheets("Liste des Macros")
    On Error GoTo 0
 
    If wsMacroList Is Nothing Then
        Set wsMacroList = ThisWorkbook.Sheets.Add(After:=ThisWorkbook.Sheets(ThisWorkbook.Sheets.Count))
        wsMacroList.Name = "Liste des Macros"
    Else
        ' Effacer le contenu de la feuille existante si elle existe déjà
        wsMacroList.Cells.Clear
    End If
 
    ReDim macroNames(1 To 1000) ' Ajuster la taille du tableau si nécessaire
 
    ' Parcourir toutes les feuilles du classeur
    For Each ws In ThisWorkbook.Worksheets
        If ws.CodeName <> "" Then ' Vérifier si la feuille a un nom de code VBA
            Set vbMod = ThisWorkbook.VBProject.VBComponents(ws.CodeName).CodeModule
            For i = 1 To vbMod.CountOfLines
                Dim macroName As String     '// Declaration de variable manquante
                macroName = vbMod.ProcOfLine(i, vbext_pk_Proc)
                If macroName <> "" Then
                    If Not IsMacroSheetInList(macroNames, macroName) Then
                        macroListIndex = macroListIndex + 1
                        macroNames(macroListIndex) = macroName
                    End If
                End If
            Next i
        End If
    Next ws
 
    ' Afficher les noms des macros dans la feuille "Liste des Macros"
    rowIndex = 1
    For i = 1 To macroListIndex
        wsMacroList.Cells(rowIndex, 1).Value = macroNames(i)
        rowIndex = rowIndex + 1
    Next i
End Sub
 
Function IsMacroSheetInList(arr() As String, macroName As String) As Boolean
    Dim i As Long
 
    For i = LBound(arr) To UBound(arr)
        If arr(i) = macroName Then
            IsMacroSheetInList = True
            Exit Function
        End If
    Next i
 
    IsMacroSheetInList = False
End Function

Bonjour, je peux avoir l'usage de cette macro dans certains cas. J'ai donc repris la macro de deedolith (que je salue), et apporté une petite modification pour mon usage personnel, à savoir l'affichage du nom de la feuille contenant la macro, si ça t'intéresse modifie cette portion de code:

Code:

1
2
3
4
5
6
7
8
                If macroName <> "" Then
                    If vbMod.ProcStartLine(macroName, vbext_pk_Proc) = i Then
                        If Not IsMacroSheetInList(macroNames, macroName) Then
                            macroListIndex = macroListIndex + 1
                            macroNames(macroListIndex) = ws.Name & "!" & macroName
                        End If
                    End If
                End If

Bonjour,
Voici une autre solution pour lister tous les composants du projet :
- Modules standards
- Modules de feuilles et de classeur
- Modules de classe
- UserForms

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Sub ListerToutesMacros()
    'Nécessite d'activer la référence Microsoft "Visual basic For Application Extensibility 5.3"
    Dim Ajout As Integer
    Dim VBCmp As VBComponent
    Dim cdMod As CodeModule
    Dim Wb As Workbook
    Dim Debut As Long
    Dim I As Integer
    Application.ScreenUpdating = True
    Application.Calculation = xlCalculationManual
    'Indiquez le nom du classeur ouvert
    Set Wb = ActiveWorkbook 'à adapter
    'Boucle sur tous les composantsdu projet :
    'Modules standards
    'Modules de feuilles et de classeur
    'Modules de classe
    'UserForms
    If Not Range("Tableau2").ListObject.DataBodyRange Is Nothing Then Range("Tableau2").ListObject.DataBodyRange.Delete
    I = 2
    For Each VBCmp In Wb.VBProject.VBComponents
        Set cdMod = VBCmp.CodeModule
        With cdMod
            Debut = .CountOfDeclarationLines + 1
            Do Until Debut >= .CountOfLines
                    'Nom de la procédure et du module
                    Cells(I, 1) = VBCmp.Name
                    Cells(I, 2) = .ProcOfLine(Debut, vbext_pk_Proc)
                    Debut = Debut + .ProcCountLines(.ProcOfLine(Debut, vbext_pk_Proc), vbext_pk_Proc)
                    I = I + 1
            Loop
        End With
    Next VBCmp
    'Range("ListeModulesProc").Sort Key1:=Range("ListeModulesProc[Nom module]"), Header:=xlYes, Order1:=xlAscending
    Application.Calculation = xlCalculationAutomatic
    Application.ScreenUpdating = False
End Sub

09/04/2024, 13h34
TitiPointCom67

Liste Macro

Bonjour,
merci beaucoup,
c'est exactement le code dont j'avais besoin:D