utilisation des combobox ppt2010

Version imprimable

24/07/2017, 15h52
Redame

utilisation des combobox ppt2010

Bonjour à tous,

j'aurais besoin de l'aide d'une personne sachant développer sous VBA pour powerpoint.
je sais pas si c'est juste une impression mais ça me parait plus compliqué que VBA pour Excel...
bref, voila mon problème:
je souhaiterais qu'une combobox s'alimente en fonction d'une autre combobox et j'ai beau tout essayer je n'arrive pas à bien faire fonctionner le truc.
j'ai une combobox (combo1) dans laquelle l'utilisateur doit choisir le service auquel il appartient. il y a 5 choix (conditionnement, fabrication, magasin energie, infrastructure). En fonction de ce choix, j'ai des tableaux qui sont préremplis dans le dernier slide avec les noms du personnel de chaque service. ex: pour le service energie, j'ai un tableau qui s'appelle "energie", qui a 4 lignes avec les noms des 4 personnes.
et enfin j'ai un autre combobox (combo2) qui, en fonction du service qu'on a choisi au début, va permettre de choisir une personne de ce service. donc si j'ai choisi sur combo1 le service energie, sur combo2 je dois pouvoir selectionner une des 4 personnes de ce service...
j'ai essayé un tas de truc hyper mal programmé car je ne suis pas familier avec VBA pour ppt mais il y a toujours des choses qui ne fonctionnent pas, un coup il m'additionne dans le combo2 les noms de tous les services, un coup je ne peux pas selectionner la personne...bref besoin d'aide.

en fouillant un peu j'ai écrit un truc qui ressemble à ça, c'est très mal codé, les noms de variables sont nuls mais c'est une ébauche pour trouver comment ça marche ensuite je réécrirai au propre

je récupère le secteur puis j'ai un "select case" en fonction du secteur puis:

Case "Secteur administratif - magasin"

compt = objSld.Shapes("magasin").Table.Rows.Count
r = ComboBox6.ListCount

If ComboBox6.ListCount = 0 Then

For j = 1 To compt

r = objSld.Shapes("magasin").Table.Cell(j, 1).Shape.TextFrame.TextRange.Text
ComboBox6.AddItem r

Next
Else
If ComboBox6.ListIndex > -1 Then ComboBox6.Text = ComboBox6.List(ComboBox6.ListIndex)

End If

merci pour votre aide

Citation:

Envoyé par Redame

Bonjour,

A tester et à adapter :

Dans un module standard :

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
 
Option Explicit
 
Public MatriceShape() As Variant
 
Sub Essai()
 
Dim PresentationEncours As Presentation
Dim MaComboBox1 As Object, MaComboBox2 As Object
Dim ContenuCombo1 As Variant
 
    Set PresentationEncours = ActivePresentation
    With PresentationEncours
 
         Set MaComboBox1 = .Slides(1).Shapes("ComboBox1").OLEFormat.Object
         ContenuCombo1 = Array("Conditionnement", "Fabrication", "Magasin", "Energie", "Infrastructure")
 
         Set MaComboBox2 = .Slides(1).Shapes("ComboBox2").OLEFormat.Object
 
         With MaComboBox1
              .Clear
              .List = ContenuCombo1
         End With
         MaComboBox2.Clear
 
         Set MaComboBox1 = Nothing
         Set MaComboBox2 = Nothing
 
     End With
     Set PresentationEncours = Nothing
 
 
End Sub
 
 
Sub ChargerLaComboBox2(ByVal NumeroSlide As Integer, ByVal TitreShape As String)
 
Dim I As Integer
Dim Matable As Table
Dim Continuer As Boolean
Dim IndiceTable As Integer
 
 
    With ActivePresentation.Slides(NumeroSlide).Shapes
         Continuer = False
         For I = 1 To .Count
             If .Item(I).HasTable Then
              Set Matable = ActivePresentation.Slides(NumeroSlide).Shapes(I).Table
                If Matable.Cell(1, 1).Shape.TextFrame.TextRange = TitreShape Then
                   IndiceTable = I
                   Continuer = True
                End If
            Set Matable = Nothing
             End If
         Next I
         If Continuer = True Then
            Set Matable = ActivePresentation.Slides(NumeroSlide).Shapes(IndiceTable).Table
            With Matable
                 ReDim MatriceShape(Matable.Columns(1).Cells.Count - 2)
                 For I = 2 To Matable.Columns(1).Cells.Count
                     MatriceShape(I - 2) = Matable.Cell(I, 1).Shape.TextFrame.TextRange
                 Next I
            End With
            Set Matable = Nothing
         End If
    End With
 
End Sub

Dans le module du Slide 1

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Option Explicit
 
Private Sub ComboBox1_Change()
 
Dim J As Integer
 
    ChargerLaComboBox2 4, ComboBox1
 
    ComboBox2.Clear
 
    If UBound(MatriceShape, 1) > 0 Then
       For J = LBound(MatriceShape, 1) To UBound(MatriceShape, 1)
           With ComboBox2
                .AddItem MatriceShape(J)
                .ListIndex = 0
           End With
       Next J
    End If
 
End Sub

Le slide 1

Pièce jointe 297238

Le slide 4

Important : Le premier enregistrement de chaque table correspond à un item de la Combobox1. C'est par cette valeur que la table correspondante est trouvée.

Pièce jointe 297233

04/08/2017, 18h51
Redame

Bonjour, jai testé et ça marche nickel!
C'est quand même plus simple sous Excel
Merci beaucoup !!!