VBA Excel, chargement des donn�es de la feuille de calcul dans un contr�le ListView

tototiti2008 — Fri, 13 Feb 2026 17:48:50 GMT

Bonjour,

Je vous propose un nouvel �l�ment � utiliser : VBA Excel, chargement des donn�es de la feuille de calcul dans un contr�le ListView

Exemple de code qui charge les donn�es d'une plage de cellules dans un contr�le ListView

Le code tente d'analyser le type de donn�es de chaque colonne, les affiche dans le ListView en les formattant pour faciliter les tris

possibilit� de trier les donn�es du Listview en cliquant sur les titres de colonnes

Liste d�roulante permettant de charger les donn�es de 2 listes exemples � titre de d�monstration

Qu'en pensez-vous ?

[Toutes versions] Quicksort en VBA, recursif et non r�cursif

tototiti2008 — Mon, 10 Nov 2025 12:55:52 GMT

Bonjour,

Je me suis pos� la question des tris en VBA et des m�thodes les plus fiables pour le faire

�videment, je suis retomb� sur la solution Quicksort qui est une possibilit� r�put�e rapide
Voici le code fonctionnel que j'ai fait, pas forc�ment mieux que les autres versions qui existent mais j'avais besoin de me remettre dans la logique de Quicksort

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub QuickSortRec(ByRef Liste, ByVal iBas As Long, ByVal iHaut As Long)
'Quicksort recursif
'Liste est supposé être un tableau VBA (Array) à 2 dimensions (1 colonne)
Dim Pivot, Ech
Dim iMin As Long, iMax As Long
    If iHaut <= iBas Then Exit Sub
    iMin = iBas
    iMax = iHaut
    Pivot = Liste(iMax, 1)
    iBas = iMin - 1
    iHaut = iMin
    Do Until iHaut >= iMax
        If Liste(iHaut, 1) < Pivot Then
            iBas = iBas + 1
            If iHaut > iBas Then
                Ech = Liste(iHaut, 1)
                Liste(iHaut, 1) = Liste(iBas, 1)
                Liste(iBas, 1) = Ech
            End If
        End If
        iHaut = iHaut + 1
    Loop
    Liste(iMax, 1) = Liste(iBas + 1, 1)
    Liste(iBas + 1, 1) = Pivot
    If iBas > iMin Then QuickSortRec Liste, iMin, iBas
    If iBas + 2 < iMax Then QuickSortRec Liste, iBas + 2, iMax
End Sub

Probl�me : QuickSort est r�cursif
En essayent de trier un tableau de plus de 36000 valeurs, j'ai le message 'Espace pile insuffisant

Alors j'ai fait un Quicksort non r�cursif pour �viter les soucis de pile d'appel limit�s

Code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Sub QuickSortNonRec(ByRef Liste)
'Quicksort non recursif
'Liste est supposé être un tableau VBA (Array) à 2 dimensions (1 colonne)
Dim Pivot, Ech, ListeLimites() As Long, Lim As Long
Dim iHaut As Long, iBas As Long, iMin As Long, iMax As Long
    ReDim ListeLimites(1 To 2, 1 To 1)
    Lim = 1
    ListeLimites(1, Lim) = LBound(Liste, 1)
    ListeLimites(2, Lim) = UBound(Liste, 1)
    Do Until Lim > UBound(ListeLimites, 2)
        iMin = ListeLimites(1, Lim)
        iMax = ListeLimites(2, Lim)
        Pivot = Liste(iMax, 1)
        iBas = iMin - 1
        iHaut = iMin
        Do Until iHaut >= iMax
            If Liste(iHaut, 1) < Pivot Then
                iBas = iBas + 1
                If iHaut > iBas Then
                    Ech = Liste(iHaut, 1)
                    Liste(iHaut, 1) = Liste(iBas, 1)
                    Liste(iBas, 1) = Ech
                End If
            End If
            iHaut = iHaut + 1
        Loop
        Liste(iMax, 1) = Liste(iBas + 1, 1)
        Liste(iBas + 1, 1) = Pivot
        If iBas > iMin Then
            ReDim Preserve ListeLimites(1 To 2, 1 To UBound(ListeLimites, 2) + 1)
            ListeLimites(1, UBound(ListeLimites, 2)) = iMin
            ListeLimites(2, UBound(ListeLimites, 2)) = iBas
        End If
        If iBas + 2 < iMax Then
            ReDim Preserve ListeLimites(1 To 2, 1 To UBound(ListeLimites, 2) + 1)
            ListeLimites(1, UBound(ListeLimites, 2)) = iBas + 2
            ListeLimites(2, UBound(ListeLimites, 2)) = iMax
        End If
        Lim = Lim + 1
    Loop
End Sub

Au cas o� �a servirait � certains

Forum du club des d�veloppeurs et IT Pro - Contribuez

VBA Excel, chargement des donn�es de la feuille de calcul dans un contr�le ListView

[Toutes versions] Quicksort en VBA, recursif et non r�cursif