Discussion :

[maninwhite]

Bonjour à toutes et à tous

J'ai un formulaire (userform) rempli par plusieurs utilisateurs.
Grace à un bouton, les données sont reportées dans la feuille d'un tableau.

A l'heure actuelle, les données vont là où je leur dit d'aller, sans conditions grâçe au code ci dessous
Elles vont donc en B C et D quelque soit la date donc dans les colonnes de Novembre.
Le but est de rentrer les valeurs en fonction de la date, c'est à dire si nous sommes au moins de Décembre, les valeurs iront dans els colonnes de Décembre.

Merci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
'Transfert des valeurs des ComboBoxs dans tableau
 
'Sélectionner feuille BOS_administration
Sheets("BOS_Administration").Select
 
'Remplir colonne ok"
Range("B3") = Range("B3") + ComboBox_comportement_ok_admin1
Range("B4") = Range("B4") + ComboBox_comportement_ok_admin2
Range("B5") = Range("B5") + ComboBox_comportement_ok_admin3
Range("B6") = Range("B6") + ComboBox_comportement_ok_admin4
Range("B7") = Range("B7") + ComboBox_comportement_ok_admin5
Range("B8") = Range("B8") + ComboBox_comportement_ok_admin6
Range("B9") = Range("B9") + ComboBox_comportement_ok_admin7
Range("B10") = Range("B10") + ComboBox_comportement_ok_admin8
 
'Remplir colonne nok
Range("C3") = Range("C3") + ComboBox_comportement_nok_admin1
Range("C4") = Range("C4") + ComboBox_comportement_nok_admin2
Range("C5") = Range("C5") + ComboBox_comportement_nok_admin3
Range("C6") = Range("C6") + ComboBox_comportement_nok_admin4
Range("C7") = Range("C7") + ComboBox_comportement_nok_admin5
Range("C8") = Range("C8") + ComboBox_comportement_nok_admin6
Range("C9") = Range("C9") + ComboBox_comportement_nok_admin7
Range("C10") = Range("C10") + ComboBox_comportement_nok_admin8
 
'Remplir colonne feedback
Range("D3") = Range("D3") + ComboBox_feedback_donne_admin1
Range("D4") = Range("D4") + ComboBox_feedback_donne_admin2
Range("D5") = Range("D5") + ComboBox_feedback_donne_admin3
Range("D6") = Range("D6") + ComboBox_feedback_donne_admin4
Range("D7") = Range("D7") + ComboBox_feedback_donne_admin5
Range("D8") = Range("D8") + ComboBox_feedback_donne_admin6
Range("D9") = Range("D9") + ComboBox_feedback_donne_admin7
Range("D10") = Range("D10") + ComboBox_feedback_donne_admin8

[mercatog]

On suppose qu'une date valide est saisie dans un TextBox nommé txtDate de l'usf.
à adapter

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Private Sub CommandButton1_Click()
Dim k As Byte
Dim j As Integer
Dim LaDate As Date, Dte As Date
Dim c As Range
 
LaDate = CDate(Me.txtDate)      'On suppose qu'une date valide est saisie dans un TextBox nommé txtDate de l'usf
Dte = DateSerial(Year(LaDate), Month(LaDate), 1)
With Sheets("BOS_Administration")
    Set c = .Range("A1:IV1").Find(Dte, LookIn:=xlFormulas, lookat:=xlWhole)
    If Not c Is Nothing Then
        j = c.Column
        For k = 1 To 8
            'Remplir colonne ok"
            .Cells(k + 2, j).Value = .Cells(k + 2, j).Value + Me.Controls("ComboBox_comportement_ok_admin" & k)
            'Remplir colonne nok"
            .Cells(k + 2, j + 1).Value = .Cells(k + 2, j + 1).Value + Me.Controls("ComboBox_comportement_nok_admin" & k)
            'Remplir colonne feedback
            .Cells(k + 2, j + 2).Value = .Cells(k + 2, j + 2).Value + Me.Controls("ComboBox_feedback_donne_admin" & k)
        Next k
        Set c = Nothing
    Else
        MsgBox "date erronée"
    End If
End With
Unload Me
End Sub