Discussion :

[JonesKCD]

Bonjour,

Je suis novice en programmation vba.

Je pilote un fichier Word via une macro VBA Excel.
Dans mon fichier Word, j'ai en en-tête de page un tableau de 1 ligne 3 colonnes dans lequel je souhaiterais insérer en :
- colonne 1 : une image
- colonne 2 : un titre (donc du texte)
- colonne 3 : le texte "Edition 00-01 / Page " suivi du numéro de page et du nombre de pages du document Word.

Quelqu'un pourrait-il m'aider à solutionner ce problème ?

Merci par avance

[SilkyRoad]

Bonjour,

Tu peux utiliser :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
'Nécessite d'activer la référence Microsoft Word xx.x Object Library
Dim WordApp As Word.Application
Dim WordDoc As Word.Document
Dim Cible As Word.Range
Dim Fichier As String
 
'adapter le chemin
Fichier = "C:\Essai.doc"
 
Set WordApp = CreateObject("Word.Application")
WordApp.Visible = True
Set WordDoc = WordApp.Documents.Open(Fichier)
 
'Insère image dans la 1ere cellule de l'entête
Set Cible = WordDoc.Sections(1).Headers(wdHeaderFooterPrimary). _
    Range.Tables(1).Cell(1, 1).Range
Cible.InlineShapes.AddPicture Filename:= _
    "C:\Documents and Settings\mimi\image.JPG", _
    LinkToFile:=False, SaveWithDocument:=True
 
'le champ va etre inséré dans la 2eme celule de l'entete
Set Cible = WordDoc.Sections(1).Headers(wdHeaderFooterPrimary). _
    Range.Tables(1).Cell(1, 2).Range
Cible.Text = ""
Cible.Collapse wdCollapseStart
'insertion du champ  "Numero de page"
WordDoc.Fields.Add Range:=Cible, _
    Type:=wdFieldPage, PreserveFormatting:=True
 
'Insère le titre dans la 3eme cellule de l'entête
Set Cible = WordDoc.Sections(1).Headers(wdHeaderFooterPrimary). _
    Range.Tables(1).Cell(1, 3).Range
Cible.Text = "Le titre"

bonne soirée
michel

[JonesKCD]

Bonjour SilkyRoad,

Merci pour ta réponse.
J'ai testé ton code et il fonctionne parfaitement, avec quelques adaptations pour que le numéro de page apparaisse à la fin de mon champ et non au début comme c'est le cas avec ton programme.

Juste pour satisfaire ma curiosité, pourrais-tu me dire s'il existe une commande pour ajouter le numéro de page à la fin du champ et non au début ?
J'ai identifié que c'est la ligne "Cible.Collapse wdCollapseStart" qui te permet d'insérer ce numéro de page en début de champ sans effacer le contenu existant.
J'ai testé la commande wdCollapseEnd mais le numéro de page est alors insérer au début de la colonne suivante.

Encore merci pour ton code et ta réactivité.