Discussion :

[Ph4rell]

bonjour, jai créer un script qui demande à l'utilisateur de saisir une adresse IP et je voudrais controler que ce qu'il rentre est bien du format d'une adresse IP, soit X.X.X.X !! je ne vois pas comment faire si ca reste possible


:manuel
set /p ip="Saisir une adresse IP pour votre PC : " //saisir de l'adresse IP dans la variable ip
if "%ip%"=="" GOTO manuel //si rien n'est rentré on redemande


si vous avez une idée de comment faire ca merci

[Ph4rell]

j'ai peut etre une piste, il faudrai que je compare le premier octet pour savoir si il est compris en 1 et 255 et ainsi de suite !!
par contre en code je ne sais pas encore comment le traduire

[minnesota]

Bon voilà, juste avant le diner

le script moteur : NTIsValideIP.cmd

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
@echo off
set isValidIPv4=false
set ipv4ToTest=%~1
set regExPattern=\^<[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\^>
echo.%ipv4ToTest% | findstr /i /r "%regExPattern%" > NUL
if %errorlevel% equ 0 goto continue
goto fin
:continue
for /f "tokens=1,2,3,4,* delims=." %%i in ("%ipv4ToTest%") do if "%%m"=="" if %%i leq 255 if %%j leq 255 if %%k leq 255 if %%l leq 255 set isValidIPv4=true
:fin
::echo %isValidIPv4%
if "%isValidIPv4%"=="true" exit /b 0
exit /b 1

le code exemple pour l'utilisation : testIPv4.cmd

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
@echo off
:debut
cls
echo.
echo Veuillez entrer une adresse ip version 4 valide :
set /p IPv4=
call NTIsValideIP.cmd %IPv4%
if %errorlevel% equ 0 goto ipvalide
echo La chaine "%IPv4%" n'est pas une adresse ip valide
echo Appuyez sur une touche pour recommencer.
pause>NUL
goto debut
:ipvalide
echo merci ;)
pause

Allez, bon amusement !

[Ph4rell]

merci à toi et bon diner !
j'ai exécuté le code qui marche niquel ! je le regarderai plus en profondeur
pour comprendre, je te poserais surement des questions !

merci bien en tout cas