Discussion :

[coco_chanel86]

Bonjour,

Voilà, j'ai une table SAS avec plusieurs variables (id, note, habitation,...).
j'aimerais faire une procédure qui me renvoie en sortie une table qui contient le nbre de valeurs manquantes pour chacune des variables de la table initiale.
J'ai essayé avec FREQ et l'option MISSPRINT. le problème c'est que je dois écrire la proc FREQ pour chacune des variables.Et en plus,j'ai les fréquences de toutes les modalités de la variable.
Quelqu'un peut-il m'aider svp? Par avance merci.

[Manoutz]

C'est possible via la proc means ou la proc univariate. il y a l'option NMISS

[RemiBousquet]

il y a aussi la fonction nmiss() pour la proc sql, pour ceux qui aiment...

[coco_chanel86]

C'est possible via la proc means ou la proc univariate. il y a l'option NMISS

Manoutz, quel doit être le format des variables pour utiliser la proc means. Mes variables sont de type "chaîne de caractères". Est-ce-que ça marche?
Merci pour ton aide.

[coco_chanel86]

il y a aussi la fonction nmiss() pour la proc sql, pour ceux qui aiment...

RemiBousquet, cmt s'utilise le nmiss dans la proc sql svp? Merci

[Manoutz]

Proc univariate et means ne fonctionnent que sur des variables de type numérique.

le code en sql:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
proc sql;
select nmiss(testvar)
from test
;
quit;

[coco_chanel86]

Quelle fonction peut-on utiliser pour connaitre le nbre de valeurs manquantes d'une variable de type "chaîne de caractères" svp? merci

[Manoutz]

Comme indiqué dans mon exemple du précédent post, la solution de Rémi via sql fonctionne pour les chaîne de caractères...

[coco_chanel86]

Ca fonctionne avec le nmiss de la proc sql.
Merci pour votre aide

[j.klein]

Je relance ce topic vieux de 4 ans car ma question est à la base la même que coco_chanel86, mais les réponses données m'ont apporté une autre interrogation !

Je souhaite utiliser la PROC SQL pour compte le nombre de valeurs manquantes d'une table tout en automatisant le processus via une macro. En effet, pour l'instant j'en suis à :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
PROC SQL ;
	select nmiss(VAR1) as VAR1_NA, ... , nmiss(VAR9) as VAR9_NA
	from tab ;
QUIT ;

ce qui est assez laborieux, qui plus est quand on a plusieurs tables !

Je cherche donc une macro avec comme unique paramètre la table des données, et qui me retourne le nombre de NA de toutes mes variables. J'espère avoir été clair

Merci à ceux qui ont lu, et à ceux qui répondront.

[s_a_m]

Hello,
En code macro tu peux faire:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
data T1;
  input var $ VAR1 $ VAR2 $ VAR3 VAR4;
DATALINES;
A . D 5 3
. F . 5 3
H T Z . 3
. . A 5 2
Z R Z . 6
Z R Z . 8
E W R 3 0
;
run;
 
proc sql;
reset noprint;
select cat( 'nmiss( ' , strip(name) , ' ) as ' ,strip(name), ' '   )into: list_var separated by ',' from dictionary.columns
where upcase(libname)='WORK' and upcase(memname)='T1';
quit;
 
 
proc sql;
create table test as select &list_var.
from t1;
quit;

La proc MEANS te permet également de calculer le nombre de valeurs manquantes par variables numérique.

[j.klein]

Waouh. Je suis très impressionné par ta réponse !! Merci beaucoup, ça marche d'enfer

Il y a cependant un petit hic ; je n'arrive pas à adapter ton exemple à mes données, et ce pour la raison que je ne comprends pas ce que fait la première PROC SQL

Ces deux lignes me font fumer le cerveau :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
SELECT cat( 'nmiss( ' , strip(name) , ' ) as ' ,strip(name), ' '   )INTO: list_var separated BY ',' FROM dictionary.COLUMNS
WHERE upcase(libname)='WORK' AND upcase(memname)='T1';

Je comprends qu'on stocke les variables et les NA correspondantes dans l'objet list_var, mais c'est à peu près tout
Peux-tu apporter quelques précisions sur la méthode s'il-te-plaît ?

[s_a_m]

- La première procédure sql permet de récupérer les variables de ta table à partir des vues dictionary de sas.
Toi tu dois remplacer la bibliothèque WORK par le nom de ta bibliothèque et la table T1 par le nom de ta table.
Tu peux aussi faire une proc contents et récupérer le nom de tes variables.

- la deuxième proc sql, je t apprends rien elle calcule le nombre de valeurs manquantes pour chaque variables.

[m.brahim]

Bonjour,


Tu peux également utiliser array

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
%macro CalculNmiss(tab_entree,tab_sortie);
data inter ;
 set &tab_entree.;
 array cha _character_;
 array num _numeric_;
do over cha;
 if missing(cha) then do;
 vnm=vname(cha);
 output;
 end;
end;
do over num;
 if missing(num) then do;
 vnm=vname(num);
 output;
 end;
end;
run;
 
 
proc sql;
create table &tab_sortie. as
select distinct vnm, count(*) as nmiss
from inter
group by vnm
;
quit;
%Mend CalculNmiss;
%CalculNmiss (entree,sortie);

Cordialement

[j.klein]

Merci beaucoup à tous les deux, cela me sera utile pour longtemps.

[tiyolx]

Bonjour,

Je trouve normal de partager ce que je fais car c'est grâce à ce site que je l'ai fait.
Merci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
 
 
data WORK.T1;
  input VAR $ VAR1 $ VAR2 $ VAR3 VAR4;
DATALINES;
A . D 5 3
. F . 5 3
H T Z . 3
. . A 5 2
Z R Z . 6
Z R Z . 8
E W R 3 0
;
run;
 
data WORK.T2;
  input VAR $ VAR1 $ VAR2 $ VAR3 VAR4;
DATALINES;
A D D 5 3
Y F W 5 3
H T Z 1 3
B U A 5 2
Z R Z 2 6
Z R Z 7 8
E W R 3 0
;
run;
 
%macro affiche_RDM(ET, TABLE1, TABLE2=F);
 
	%put *************************;
	%put ;
	%put ENVOI TABLE2 =>  &TABLE2.;
	%put ;
 
	proc sql noprint;
	select name into:list_var separated by ' ' from dictionary.columns
	where upcase(libname)="&ET." and upcase(memname)="&TABLE1.";
	quit; 
 
	proc sql noprint;
	select cat('nmiss(', strip(name), ') as ', strip(name), ' ') into:list_varnmiss separated by ',' from dictionary.columns
	where upcase(libname)="&ET." and upcase(memname)="&TABLE1.";
	quit;
 
	proc sql;
	create table WORK.VALEURSCOMPTEES as select &list_varnmiss.
	from &ET..&TABLE1.;
	quit;
 
	PROC SQL;
		CREATE VIEW WORK.VALEURSCOMPTEES2 AS
		SELECT SRC.*, "DM_&TABLE1." AS _EG_IDCOL_
			FROM WORK.VALEURSCOMPTEES AS SRC;
	QUIT;
 
	PROC TRANSPOSE DATA = WORK.VALEURSCOMPTEES2 OUT=WORK.VALEURSCOMPTEES3;
		ID _EG_IDCOL_;
		VAR &list_var.;
	RUN;
 
	proc sort data=WORK.VALEURSCOMPTEES3;
	by _name_ ;
	run;
 
	%if "&TABLE2." ~= "F" %then %do;
 
	%put ;
	%put ENTRE DANS LA CONDITION =>  OUI;
	%put ;	
 
		proc sql noprint;
		select name into:list_var separated by ' ' from dictionary.columns
		where upcase(libname)="&ET." and upcase(memname)="&TABLE2.";
		quit; 
 
		proc sql noprint;
		select cat('nmiss(', strip(name), ') as ', strip(name), ' ') into:list_varnmiss separated by ',' from dictionary.columns
		where upcase(libname)="&ET." and upcase(memname)="&TABLE2.";
		quit;
 
		proc sql;
		create table WORK.VALEURSCOMPTEESB as select &list_varnmiss.
		from &ET..&TABLE2.;
		quit;
 
		PROC SQL;
			CREATE VIEW WORK.VALEURSCOMPTEES2B AS
			SELECT SRC.*, "DM_&TABLE2." AS _EG_IDCOL_
				FROM WORK.VALEURSCOMPTEESB AS SRC;
		QUIT;
 
		PROC TRANSPOSE DATA = WORK.VALEURSCOMPTEES2B OUT=WORK.VALEURSCOMPTEES3B;
			ID _EG_IDCOL_;
			VAR &list_var.;
		RUN;
 
		proc sort data=WORK.VALEURSCOMPTEES3B;
		by _name_ ;
		run;
 
		data WORK.AFFICHE_RDM;
		merge WORK.VALEURSCOMPTEES3 WORK.VALEURSCOMPTEES3B;
		by _name_ ;
		run;
 
	%end;
	%else %do;	
 
	%put ;
	%put ENTRE DANS LA CONDITION =>  NON;
	%put ;
 
		data WORK.AFFICHE_RDM;
		set WORK.VALEURSCOMPTEES3;
		run;
 
	%end;
 
        %* table qui contient le résultat;
	data WORK.AFFICHE_RDM;
	set WORK.AFFICHE_RDM;
	rename _name_ = 'Nom_variable';
	run;
 
%mend affiche_RDM;
 
%affiche_RDM(WORK,T1);
%affiche_RDM(WORK,T1,TABLE2=T2);