Discussion :

[pscmoye]

Bonjour à tous,

Je connais bien le VBA Excel mais je débute en access.
Je souhaiterais créer une table pour récupérer la liste des tables de ma base ainsi que leur date de création.
(donc deux champs dans la nouvelle table, le "nom table" et "date création")

Merci de votre aide, car je tourne en rond depuis un moment.

[LedZeppII]

Bonsoir,

regardes ici :
Lister les tables d'une base de données

La propriété DateCreated de l'objet TableDef renvoie la date de création.

A+

[LedZeppII]

Bonjour,

Voici un exemple de code pour lister les tables de la base de données en cours.
Le résultat est stocké dans une table tblTables (Nom, DateCreation)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Sub ListeDesTables()
Dim db As DAO.Database, rs As DAO.Recordset
Dim TDef As DAO.TableDef
Dim bSys As Boolean
 
Set db = CurrentDb
' Vide la table tblTables
db.Execute "DELETE FROM tblTables"
' Ouvre un recordset sur la table tblTables
Set rs = db.OpenRecordset("tblTables")
 
For Each TDef In db.TableDefs
    ' Teste l'attribut Système
    bSys = (TDef.Attributes And dbSystemObject) <> 0
    ' Si ce n'est pas une table système et si le nom de la
    ' table ne commence pas par ~ (objet supprimé)
    If (bSys = False) And Not (TDef.Name Like "~*") Then
        rs.AddNew
        rs.Fields("Nom") = TDef.Name
        rs.Fields("DateCreation") = TDef.DateCreated
        rs.Update
    End If
Next
rs.Close
End Sub

A+

[pscmoye]

Merci c'est super, ça marche nickel.

Au plaisir.