Discussion :

[panpulilu]

Bonjour,

voilà ma question: j'ai une première feuille excel qui comporte 5 colonnes: nom, prénom, ville de résidence, pays de résidence, numéro de téléphone. Je voudrais, à partir de cette première feuille créer d'autres feuilles excel dans le même classeur où chaque onglet correspondrait à un pays de résidence déjà répertorié dans la première feuille.

Par exemple, dans ma première feuille, j'ai 4 personnes: 2 habitent en France, 2 en Italie. A partir de ces données, comment faire pour créer automatiquement 2 nouvelles feuilles dont les onglets se nommeraient France et Italie et qui ne contiendrait pour l'une que les lignes des personnes habitant en France et pour l'autre que les lignes des personnes habitant en Italie?

Merci d'avance pour votre réponse.

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub CommandButton1_Click()
Dim LastLig As Long, i As Long
Dim Pay As New Collection
 
Application.ScreenUpdating = False
With Sheets("BASE")      'à adapter
   .Range("A1").AutoFilter
   LastLig = .Cells(Rows.Count, "A").End(xlUp).Row
   For i = 2 To LastLig
      On Error Resume Next
      Pay.Add .Range("D" & i).Value, .Range("D" & i).Value
      On Error GoTo 0
   Next i
   For i = 1 To Pay.Count
      On Error Resume Next
      If IsError(Sheets(Pay.Item(i)).Select) Then
         On Error GoTo 0
         Worksheets.Add after:=Sheets(Sheets.Count)
         ActiveSheet.Name = Pay.Item(i)
      End If
      .Range("A1:D" & LastLig).AutoFilter field:=4, Criteria1:=Pay.Item(i)
      .Rows(1 & ":" & LastLig).SpecialCells(xlCellTypeVisible).Copy Sheets(Pay.Item(i)).Range("A1")
      .Range("A1").AutoFilter
   Next i
   .Activate
End With
End Sub

[le_dilem]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Sub AJ()
'Important il faut avant lancer cette macro faire un trie sur le pays
Dim i, j, X
i = 2
j = 2
X = 0
Dim val, rg
 
Sheets("Feuil1").Select  ' la feuille principale
While Range("A" & i) <> ""
 
X = 0
pays = Sheets("Feuil1").Range("D" & i)
 
  For Z = 1 To Sheets.Count
       If (pays) = Sheets(Z).Name Then
      X = 1
      End If
  Next Z
 
If X <> 1 Then                   ' ajouter une feuille si elle n'existe pas
Set NewSheet = Sheets.Add(Type:=xlWorksheet)
    NewSheet.Name = (pays)
End If
Sheets("Feuil1").Select
val = Range("D" & i)
If Range("D" & i) = val Then
  rg = Range("d" & i).Value
  Rows(i).Copy
 
 Sheets(rg).Select
 Rows(j).Select
 ActiveSheet.Paste
j = j + 1
End If
Sheets("Feuil1").Select
If Range("D" & i) <> Range("D" & i + 1) Then
j = 2
End If
i = i + 1
 
Wend
End Sub

[mercatog]

Oh là là, Je ne me peux pas m'empêcher de critiquer le code proposé vu ses nombreuses manières à éviter
1. déclaration incorrecte des variable ou non déclaration
2. utilisation de noms de variables qui peuvent donner à confusion (val)
3. Indentation archaïque du code, lisibilité moindre
4. Utilisation sans utilité des Select et Activate
5. Ce passage est étrange

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
   val = Range("D" & i)
   If Range("D" & i) = val Then
      rg = Range("D" & i).Value

Améliore ton code

[panpulilu]

Merci beaucoup pour ces codes!!! Ca marche!