IdentifiantMot de passe
Loading...
Mot de passe oublié ?Je m'inscris ! (gratuit)
Navigation

Inscrivez-vous gratuitement
pour pouvoir participer, suivre les réponses en temps réel, voter pour les messages, poser vos propres questions et recevoir la newsletter

FAQs Windows Discussion :

Brève explication sur quelques notions basiques


Sujet :

FAQs Windows

  1. #1
    Membre chevronné
    Avatar de I'm_HERE
    Homme Profil pro
    Inscrit en
    Juillet 2008
    Messages
    1 013
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : Tunisie

    Informations forums :
    Inscription : Juillet 2008
    Messages : 1 013
    Points : 1 991
    Points
    1 991
    Par défaut Brève explication sur quelques notions basiques
    salut,

    le but de ce post est de donner quelques explications sur des notions basiques.

    (j'espère que les explications seront claires)

    .BAT VS .CMD

    Quel est la différence entre un fichier de commande ayant l'extension .BAT et un autre ayant l'extension .CMD ?

    L'une des différences est l'intérprétation de la variable ERRORLEVEL, dans le cas des fichiers .BAT la variable ERRORLEVEL est limité au erreurs retournées par des commandes, par contre dans le cas des fichiers .CMD cette variable n'est plus spécifique aux retours d'erreurs seulement, mais aussi, en cas de reussite.

    Exemple

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    @Echo oFF
     
    set test=CMD
    Call :batVScmd 6
    set test=BAT
    If errorlevel 6 (echo BAT) else (echo CMD)
    goto:eof
     
    :batVScmd
    exit /b %1
    goto :eof
    essayez d'enregistrer ce code dans un fichier d'extension .bat puis dans un fichier .cmd pour voir la différence.

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    c:\RepTest> batfile.bat
    BAT
    
    c:\RepTest> cmdfile.cmd
    CMD


    TOKENS VS DELIMS

    Quelle est la différence entre TOKENS et DELIMS ?

    Supposant qu'on a un fichier "tokVSdel.txt"
    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    a b c d e f g
    1 2 3 4 5 6 7
    on veux maintenant, lire chaque ligne de ce fichier, pour ce faire on va utiliser une boucle FOR/F
    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    For /F "?" %%a In (tokVSdel.txt) Do Echo %%a
    Que choisir alors [TOKENS=*] ou bien [DELIMS=] ?

    Pour répondre à cette question il faut comprendre leurs fonctionnements : Voici un exemple qui montre les différences entre ces deux options

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    @echo off
    (set Str=          Ceci est     un test      )
    for /f "tokens=*" %%i in ("%Str%") do Set Token=%%~i
    for /f "delims=" %%i in ("%Str%") do Set Delim=%%~i
    for /f "tokens=*" %%i in ('echo\%Str%') do Set Echot=%%~i
    for /f "delims=" %%i in ('echo\%Str%') do Set Echod=%%~i
    echo Str_Origin=[%Str%]
    echo Token-Echo=[%Token%]
    echo Delim-Echo=[%Delim%]
    echo Token+Echo=[%Echot%]
    echo Delim+Echo=[%Echod%]
    pause
    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    C:\RepTest> test.cmd
    
    Str_Origin=[          Ceci est     un test      ]
    Token-Echo=[Ceci est     un test      ]
    Delim-Echo=[          Ceci est     un test      ]
    Token+Echo=[Ceci est un test ]
    Delim+Echo=[ Ceci est un test ]
    => remarquez l'interprétation des espaces dans chaque boucle.



    Echo. VS Echo[+(,=;+\/]

    dans la documentation Echo suivi d'un point "ECHO." créer une ligne vide

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    ECHO Ligne1
    ECHO Ligne2
    ECHO.
    ECHO Ligne4
    mais aussi permet de ne rien afficher si la variable n'est pas définie

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    Set NON_DEFNIE=
    ECHO %NON_DEFINIE%
    ECHO.%NON_DEFINIE%
    Mais souvent on utilise d'autres caractères à la place de "." :

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    ECHO,
    ECHO;
    ECHO+
    ECHO=
    ECHO(
    ECHO/
    ECHO\
    ECHO[
    ECHO]
    Quel est la différence entre la syntaxe de la documentation et ces variantes ?

    Voici 2 cas qui montrent que le "." peut causer des problèmes:

    1) Conflit entre les noms de fichiers en "ECHO" et la commande "ECHO."

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    @Echo oFF
     
    CD.>ECHO
     
    ECHO. ECHO.
    ECHO, ECHO,
    ECHO; ECHO;
    ECHO+ ECHO+
    ECHO= ECHO=
    ECHO( ECHO(
    ECHO/ ECHO/
    ECHO\ ECHO\
    ECHO[ ECHO[
    ECHO] ECHO]
     
    DEL ECHO
     
    Pause
    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    C:\RepTest> test.cmd
    
    'ECHO.' n'est pas reconnu en tant que commande interne
    ou externe, un programme ex‚cutable ou un fichier de commandes.
     ECHO,
     ECHO;
     ECHO+
     ECHO=
     ECHO(
     ECHO/
     ECHO\
     ECHO[
     ECHO]
    2) L'ERV (expansion retardée de variable) et les variables de substitutions:

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    @Echo oFF
     
    md __test
    pushd __test
     
    setlocal enabledelayedexpansion
     
    for /l %%a in (1 1 5) Do cd.>fichier_%%a.txt
     
    echo --------------------------- ECHO.
    for %%a in (*.*) do Set "file=%%a" & echo.!file:_=@! 
     
    echo --------------------------- ECHO+
    for %%a in (*.*) do Set "file=%%a" & echo+!file:_=@! 
     
    echo --------------------------- ECHO=
    for %%a in (*.*) do Set "file=%%a" & echo=!file:_=@! 
     
    echo --------------------------- ECHO,
    for %%a in (*.*) do Set "file=%%a" & echo,!file:_=@! 
     
    echo --------------------------- ECHO;
    for %%a in (*.*) do Set "file=%%a" & echo;!file:_=@! 
     
    echo --------------------------- ECHO[
    for %%a in (*.*) do Set "file=%%a" & echo[!file:_=@! 
     
    echo --------------------------- ECHO]
    for %%a in (*.*) do Set "file=%%a" & echo]!file:_=@! 
     
    echo --------------------------- ECHO(
    for %%a in (*.*) do Set "file=%%a" & echo(!file:_=@! 
     
    popd
    rd /s /q __test
     
    pause
    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    45
    46
    47
    48
    49
    50
    51
     C:\RepTest> test.cmd
    
    --------------------------- ECHO.
    file:_=@ 
    file:_=@ 
    file:_=@ 
    file:_=@ 
    file:_=@ 
    --------------------------- ECHO+
    file:_=@ 
    file:_=@ 
    file:_=@ 
    file:_=@ 
    file:_=@ 
    --------------------------- ECHO=
    fichier@1.txt 
    fichier@2.txt 
    fichier@3.txt 
    fichier@4.txt 
    fichier@5.txt 
    --------------------------- ECHO,
    fichier@1.txt 
    fichier@2.txt 
    fichier@3.txt 
    fichier@4.txt 
    fichier@5.txt 
    --------------------------- ECHO;
    fichier@1.txt 
    fichier@2.txt 
    fichier@3.txt 
    fichier@4.txt 
    fichier@5.txt 
    --------------------------- ECHO[
    file:_=@ 
    file:_=@ 
    file:_=@ 
    file:_=@ 
    file:_=@ 
    --------------------------- ECHO]
    file:_=@ 
    file:_=@ 
    file:_=@ 
    file:_=@ 
    file:_=@ 
    --------------------------- ECHO(
    fichier@1.txt 
    fichier@2.txt 
    fichier@3.txt 
    fichier@4.txt 
    fichier@5.txt 


    EnableExtensions VS DisableExtensions:

    voici quelques différences entre le mode d'extension activé (par défaut) et le mode d'extension désactivé.



    interprétation des variables dynamiques:


    Si on désactive les extensions de commandes les variables dynamiques ne sont plus reconnues.

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    @Echo oFF
     
    Set VAR=ERRORLEVEL RANDOM DATE CD CMDCMDLINE TIME CMDEXTVERSION
     
    echo DISABLEEXTENSIONS
    echo -----------------
    for %%a in (%VAR%) do Cmd /e:off /Ccall echo %%a %%%%a%%%
    echo.
    echo ENABLEEXTENSIONS
    echo -----------------
    for %%a in (%VAR%) do Cmd /e:on /Ccall echo %%a %%%%a%%%
     
    Pause
    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    C:\RepTest> test.cmd
    
    DISABLEEXTENSIONS
    -----------------
    ERRORLEVEL %ERRORLEVEL%
    RANDOM %RANDOM%
    DATE %DATE%
    CD %CD%
    CMDCMDLINE %CMDCMDLINE%
    TIME %TIME%
    CMDEXTVERSION %CMDEXTVERSION%
    
    ENABLEEXTENSIONS
    -----------------
    ERRORLEVEL 0
    RANDOM 25664
    DATE 14/02/2010
    CD D:\Documents and Settings\Administrateur\Bureau
    CMDCMDLINE Cmd /e:on /Ccall echo CMDCMDLINE Cmd /e:on /Ccall echo CMDCMDLINE %CMDCMDLINE%
    TIME 17:05:56,56
    CMDEXTVERSION 2


    commandes non-reconnues:



    Si les extensions de commandes sont désactivées la commande COLOR n'est plus reconnue.

    ** COLOR

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    @Echo oFF
    :: setlocal enableextensions
    setlocal disableextensions
     
    color 0e
     
    endlocal
     
    Pause



    Comportement de quelques commandes:



    Si on désactive les extensions de commandes, certaines auront un comportement différent:

    A) La commande MD:

    La création d'arborescence n'est plus reconnue.

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    Md racine\arbo1\arbo2\arbo3
    cette commande par défaut (extensions activées) va créer une arborescence dans le répertoire en cours, si on désactive
    l'extension des commandes elle retournera une erreur puisqu'elle essaiera de créer un répertoire "racine\arbo1\arbo2\arbo3" ce qui est impossible puisque le caractère "\" est un caractère réservé dans le nommage de fichiers/dossiers

    B) La commande CALL:

    si les extensions sont déactivées,la commande "CALL" ne permet plus d'appel à une étiquette :

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    @Echo oFF
    ::Setlocal EnableExtensions
    Setlocal DisableExtensions
     
    set _test=false
    call :eti
    echo %_test% 
     
    pause
    exit /b
     
    :eti
    set _test=true
    exit /b
    C) La commande GOTO:


    avec la désactivation des extensions, goto :EOF attend l'étiquette :EOF (End-Of-File)

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    @Echo oFF
    ::setlocal enableextensions
    setlocal disableextensions
     
    set eof=enableextensions
     
    echo %eof% 
    goto :eof
     
     
    :eof
    set eof=disableextensions
    echo %eof%

    D) La commande IF:

    ==> tiré du help de la commande "IF"
    Si les extensions de commandes sont désactivées vous ne pouvez pas utiliser les syntaxes suivantes :

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    if [/i] Chaîne1 OpComparaison Chaîne2 Commande [else Expression]
     
    if cmdextversion Nombre Commande [else Expression]
     
    if defined Variable Commande [else Expression]

    E) La commande FOR:

    si les extensions de commandes sont désactivées, pour la boucle FOR : Les formes d'itération (/L) , de récursivité (/R) et de formatage de fichiers (/F) ne sont plus reconnues :

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    Setlocal DisableExtensions
    For /L %%a In (1 1 5) Do Echo %%a
     
    For /R . %%a In (.) Do Echo %%a
     
    For /F %%a In (Fichier) Do Echo %%a
     
    Endlocal
    F) Il y a aussi d'autres commandes SHIFT DEL,etc.



    FOR/F VS FOR/R

    Dans une recherche récursive, Quelle est la différence entre ces deux syntaxes :

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
     
    For /r . %%a in (*) Do echo;%%a
     
    For /f "delims=" %%a in ('Dir/s/a-d/b') Do echo;%%a
    Mac LAK et Nono075 ont répondu à cette question dans ce post


    ERRORLEVEL VS %ERRORLEVEL%

    1- Fixer un ERRORLEVEL:

    tous les codes d'erreurs retournés sont des nombres connus:
    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    IF %ERRORLEVEL%==N (%ERRORLEVEL% est égale à N)
    au contraire de la variable spéciale "ERRORLEVEL"

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    IF ERRORLEVEL==N (ERRORLEVEL=N ou ERRORLEVEL>N)
    testez cet exemple:

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    echo ceci est un test | find "test">nul
    if ERRORLEVEL==0 echo ERRORLEVEL
    REM Si la commande précédente renvoie 0 ou plus grand "c'est toujours le cas !!" 
    if %ERRORLEVEL%==0 echo %%ERRORLEVEL%% 
    REM Si la commande précédente renvoie 0
    puis ceci:

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    echo ceci est un test | find "##">nul
    if ERRORLEVEL==0 echo ERRORLEVEL
    REM Si la commande précédente renvoie 0 ou plus grand "c'est toujours le cas !!" 
    if %ERRORLEVEL%==0 echo %%ERRORLEVEL%% 
    REM Si la commande précédente renvoie 0
    puis fixer un code retour avec la variable spéciale ERRORLEVEL, on doit tester le code d'erreur en deux partie.

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    IF ERROELEVEL X  IF NOT ERRORLEVEL Y (ACTION)
    ---------------  -------------------
       Partie 1         partie 2
    la première partie va tester si ERRORLEVEL est supérieur à "X" et la deuxième partie va tester si ERRORLEVEL est inférieur à "Y"

    voici un exemple pour avoir un résultat exact avec ERRORLEVEL:

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    ::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    @Echo oFF
    CALL :EXITCODE 1
    If ERRORLEVEL 0 IF NOT ERRORLEVEL 1 ECHO ERRORLEVEL=0
    If ERRORLEVEL 1 IF NOT ERRORLEVEL 2 ECHO ERRORLEVEL=1
    IF ERRORLEVEL 2 IF NOT ERRORLEVEL 3 ECHO ERRORLEVEL=2
    ECHO.
    If ERRORLEVEL 0 ECHO ERRORLEVEL=0 OR ERRORLEVEL ^> 0
    If ERRORLEVEL 1 ECHO ERRORLEVEL=1 OR ERRORLEVEL ^> 1
    IF ERRORLEVEL 2 ECHO ERRORLEVEL=2 OR ERRORLEVEL ^> 2
    Pause
    GoTo:EOF
    :EXITCODE
    EXIT /B %1
    GOTO:EOF
    :::::::::::::::::::::::::::::::::::::::::::::::::::::::::

    2- Structures de blocs :

    La variable ERRORLEVEL a l'avantage d'être utilisé dans une structure de bloc sans activer l'expansion retardé des variables, au contraire de la variable %ERRORLEVEL%

    3- Désactivation des extensions:

    quand les extensions sont désactivées on peut utiliser ERRORLEVEL à la place de %ERRORLEVEL%

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    @echo off
    :: Setlocal enableextensions
    setlocal disableextensions
     
    IF "%ERRORLEVEL%"=="0" echo %%ERRORLEVEL%%
    IF NOT ERRORLEVEL 1 echo ERRORLEVEL
     
    pause

    @suivre

  2. #2
    Rédacteur


    Profil pro
    Inscrit en
    Janvier 2003
    Messages
    7 171
    Détails du profil
    Informations personnelles :
    Localisation : France

    Informations forums :
    Inscription : Janvier 2003
    Messages : 7 171
    Points : 15 060
    Points
    15 060
    Billets dans le blog
    1
    Par défaut
    Salut,
    très bonne idée que de documenter ces différents points.

    Je me suis permis de corriger qq coquilles et d'ajouter la signification de l'acronyme ERV.

    Pour ceci
    C) La commande GOTO:

    avec la désactivation des extensions, goto :EOF attend l'étiquette :EOF (End-Of-File)
    Est-ce attend, au sens nécessite, ou atteint ?

  3. #3
    Membre chevronné
    Avatar de I'm_HERE
    Homme Profil pro
    Inscrit en
    Juillet 2008
    Messages
    1 013
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : Tunisie

    Informations forums :
    Inscription : Juillet 2008
    Messages : 1 013
    Points : 1 991
    Points
    1 991
    Par défaut
    salut Laurent et merci de ta contribution,

    Citation Envoyé par Laurent Dardenne Voir le message

    Est-ce attend, au sens nécessite, ou atteint ?
    au sens de nécessite

  4. #4
    Inactif  
    Avatar de Mac LAK
    Profil pro
    Inscrit en
    Octobre 2004
    Messages
    3 893
    Détails du profil
    Informations personnelles :
    Âge : 49
    Localisation : France, Haute Garonne (Midi Pyrénées)

    Informations forums :
    Inscription : Octobre 2004
    Messages : 3 893
    Points : 4 846
    Points
    4 846
    Par défaut
    Joli petit compendium de trucs, et au passage, merci pour la citation !

    Pour l'étiquette :EOF, sans les extensions, on peut en fait utiliser n'importe quelle étiquette (EOF n'est qu'une convention), mais effectivement, elle est requise strictement, sinon c'est une erreur.

    Par contre, une remarque à titre purement didactique : c'est dommage qu'il n'y aie pas aussi les sorties de chaque cas (ex : variante BAT / CMD). En effet, pour quelqu'un qui consulte simplement ces trucs, taper chaque script et l'essayer prends pas mal de temps s'il doit parcourir l'intégralité des trucs que tu as illustrés... Alors qu'avec les sorties, il pourrait par exemple reconnaître un cas d'erreur qu'il avait déjà rencontré.



    @Laurent : ça ne serait pas possible de séparer tout ça en trucs "unitaires" pour les ajouter à la FAQ ou autre ressource centrale liée aux batchs ? Cela éviterait que ça se perde au fond du forum et/ou de renvoyer vers ce post...

    Et au passage, une remarque sur le forum lui-même : ça manque, une fonction de masquage type "spoiler"... Presque autant que la citation à plusieurs niveaux...
    Mac LAK.
    ___________________________________________________
    Ne prenez pas la vie trop au sérieux, de toutes façons, vous n'en sortirez pas vivant.

    Sources et composants Delphi sur mon site, L'antre du Lak.
    Pas de question technique par MP : posez-la dans un nouveau sujet, sur le forum adéquat.

    Rejoignez-nous sur : Serveur de fichiers [NAS] Le Tableau de bord projets Le groupe de travail ICMO

  5. #5
    Rédacteur


    Profil pro
    Inscrit en
    Janvier 2003
    Messages
    7 171
    Détails du profil
    Informations personnelles :
    Localisation : France

    Informations forums :
    Inscription : Janvier 2003
    Messages : 7 171
    Points : 15 060
    Points
    15 060
    Billets dans le blog
    1
    Par défaut
    Citation Envoyé par Mac LAK
    Par contre, une remarque à titre purement didactique : c'est dommage qu'il n'y aie pas aussi les sorties de chaque cas
    Sur cet aspect tu as raison, mais cela prend un peu plus de temps à rédiger et à vérifier. I'm_Here a fait le plus gros, aux lecteurs de faire le reste, c'est aussi ça le partage .

    Citation Envoyé par Mac LAK
    @Laurent : ça ne serait pas possible de séparer tout ça en trucs "unitaires" pour les ajouter à la FAQ ou autre ressource centrale liée aux batchs ? Cela éviterait que ça se perde au fond du forum et/ou de renvoyer vers ce post...
    Ici aussi tu as raison, mais QUI pour le faire ? De mon coté j'ai fort à faire sur plusieurs sujets.

    Pour le moment personne ne s'occupe de la faq Batch, il me semble. C'est pour cette raison que j'ai regroupé ce type de contributions dans un post de "référencement".
    En même temps, et provisoirement, rien ne nous empêche de placer un lien dans la page cours de Windows sur ce post. J'ai pensé créer un projet communautaire basé sur un Wiki très simple à utiliser (mais lié à un projet) ou sur celui-ci plus complet et d'accès libre.
    Citation Envoyé par Mac LAK
    Et au passage, une remarque sur le forum lui-même : ça manque, une fonction de masquage type "spoiler"... Presque autant que la citation à plusieurs niveaux...
    Je n'ai pas compris la notion/fonction de "spoiler".

  6. #6
    Inactif  
    Avatar de Mac LAK
    Profil pro
    Inscrit en
    Octobre 2004
    Messages
    3 893
    Détails du profil
    Informations personnelles :
    Âge : 49
    Localisation : France, Haute Garonne (Midi Pyrénées)

    Informations forums :
    Inscription : Octobre 2004
    Messages : 3 893
    Points : 4 846
    Points
    4 846
    Par défaut
    Citation Envoyé par Laurent Dardenne Voir le message
    Sur cet aspect tu as raison, mais cela prend un peu plus de temps à rédiger et à vérifier. I'm_Here a fait le plus gros, aux lecteurs de faire le reste, c'est aussi ça le partage .
    Je sais... "Tant de choses à faire, et si peu de temps...", comme disait l'autre...
    Bon, je verrais si je trouve un moment pour commencer à en faire quelques-uns.

    Citation Envoyé par Laurent Dardenne Voir le message
    Ici aussi tu as raison, mais QUI pour le faire ? De mon coté j'ai fort à faire sur plusieurs sujets.
    Pour ma part, je n'ai pas les droits requis sur la FAQ, donc ça ne va pas beaucoup t'aider.
    Après, faudrait voir sur un autre médium plus accessible, effectivement...

    Citation Envoyé par Laurent Dardenne Voir le message
    Je n'ai pas compris la notion/fonction de "spoiler".
    Des balises BB (comme CODE, QUOTE, etc.) mais qui produisent, à l'écran, un texte masqué que l'on affiche via un clic sur une zone permettant de dévoiler le contenu.
    Très utilisé sur certains forums, notamment littéraires, où il pourrait être malvenu de dévoiler une intrigue et/ou une solution de façon trop évidente, ou sans avertissement.
    Ici, ça permettrait surtout d'alléger considérablement la taille à l'écran de ce genre de posts, et donc de les rendre beaucoup plus lisibles.
    Mac LAK.
    ___________________________________________________
    Ne prenez pas la vie trop au sérieux, de toutes façons, vous n'en sortirez pas vivant.

    Sources et composants Delphi sur mon site, L'antre du Lak.
    Pas de question technique par MP : posez-la dans un nouveau sujet, sur le forum adéquat.

    Rejoignez-nous sur : Serveur de fichiers [NAS] Le Tableau de bord projets Le groupe de travail ICMO

  7. #7
    Membre chevronné
    Avatar de I'm_HERE
    Homme Profil pro
    Inscrit en
    Juillet 2008
    Messages
    1 013
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : Tunisie

    Informations forums :
    Inscription : Juillet 2008
    Messages : 1 013
    Points : 1 991
    Points
    1 991
    Par défaut
    salut,

    Citation Envoyé par Mac LAK Voir le message
    et au passage, merci pour la citation !

    c'est ton mérite je n'ai fais que le citer

  8. #8
    Rédacteur


    Profil pro
    Inscrit en
    Janvier 2003
    Messages
    7 171
    Détails du profil
    Informations personnelles :
    Localisation : France

    Informations forums :
    Inscription : Janvier 2003
    Messages : 7 171
    Points : 15 060
    Points
    15 060
    Billets dans le blog
    1
    Par défaut
    Citation Envoyé par Mac LAK
    Pour ma part, je n'ai pas les droits requis sur la FAQ, donc ça ne va pas beaucoup t'aider.
    Oui je sais.
    Citation Envoyé par Mac LAK
    Des balises BB (comme CODE, QUOTE, etc.) mais qui produisent, à l'écran, un texte masqué que l'on affiche via un clic sur une zone permettant de dévoiler le contenu.
    Je comprends. Dans une prochaine version peut être...

Discussions similaires

  1. brêve explication sur quelques notions basiques
    Par I'm_HERE dans le forum Scripts/Batch
    Réponses: 7
    Dernier message: 15/02/2010, 21h01
  2. [Débutant] Explications sur quelques instructions en Assembleur
    Par voodka2007 dans le forum x86 32-bits / 64-bits
    Réponses: 4
    Dernier message: 01/01/2009, 22h47
  3. Réponses: 17
    Dernier message: 11/11/2008, 13h17
  4. explication sur les notions de commande et de requête !
    Par bnuitrare dans le forum Eclipse Java
    Réponses: 2
    Dernier message: 11/02/2007, 19h20
  5. explication sur quelques login sql server 2k
    Par Bba_M dans le forum MS SQL Server
    Réponses: 2
    Dernier message: 14/07/2006, 10h23

Partager

Partager
  • Envoyer la discussion sur Viadeo
  • Envoyer la discussion sur Twitter
  • Envoyer la discussion sur Google
  • Envoyer la discussion sur Facebook
  • Envoyer la discussion sur Digg
  • Envoyer la discussion sur Delicious
  • Envoyer la discussion sur MySpace
  • Envoyer la discussion sur Yahoo