Discussion :

[Muetdhiver]

Bonjour, je dispose de cette cellule qui contient le texte :

/STD/DATA_ENGINE/TARGET_PC_HARD_ELIOS/A429 DATA

Quelle formule faire pour écrire dans la cellule voisine A429 DATA, c'est a dire extraire tout ce qui se trouve après "/" ?

J'ai bien essayé avec "DROITE()" mais il faudrait que j'arrive à retrouver le numéro du dernier "/" dans la chaine.

Merci pour l'aide.

[EmmanuelleC]

pour trouver le dernier emplacement d'un caractere, tu peux passer par une formule matricielle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MAX(IF(MID(A1;ROW(INDIRECT("z1:z"&LEN(A1)));1)="/";ROW(INDIRECT("z1:z"&LEN(A1)));""))

(attentin, la formule est en anglais, si ton excel est en francais, il faututiliser les nom de fonction fr)
a valider par Ctrl + maj + enter

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ROW(INDIRECT("z1:z"&LEN(A1)))

permet de generer une "variable" qui va aller de 1 la fin de ta chaine.

Ensuite, grace au matriciel, on va regarder chaque lettre de la chaine (de la 1 a la derniere, en utilisant la "variable") et si c'est égal a "/"; alors on affiche l'emplacement (la "variable") et sinon on met le vide. Ensuite on prend le maximum et on a le dernier emplacement de "/"

si tu veux des explications plus détaillées n'hésite pas a demander

[Muetdhiver]

Merci beaucoup pour la réponse

Imaginons que ma chaine /STD/DATA_ENGINE/TARGET_PC_HARD_ELIOS/A429 DATA soit dans la cellule C66, j'ai essayé avec cette formule (excel français) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MAX(SI(STEXT(C66;LIGNE(INDIRECT("z1:z"&NBCAR(C66)));1)="/";LIGNE(INDIRECT("z1:z"&NBCAR(C66)));""))

Et ca me renvoie #NOM?

Par ailleurs je ne comprends pas trop le sens de "z1:z" ??

Merci pour l'aide.

[EmmanuelleC]

ligne() doit fonctionner avec soit une cellule, soit une plage de cellule (et ca restituer un nombre entier, correspondant au numéro de ligne)
Comme moi je cherche une facon de parcourir ta chaine, ca va aller de la ligne 1 a la ligne NBCAR(C66)
Et apres, j'ai mis une colonne pour faire la plage. J'ai pris Z mais tu peux prendre n'importe la quelle

indirect permet de recomposer une plage a partir d'un texte. Supposons que nbcar(c66) vale 57, INDIRECT("z1:z"&NBCAR(C66)) ca donc valoir la plage Z1:Z57
Et donc LIGNE(INDIRECT("z1:z"&NBCAR(C66))) validé en matriciel va donner de 1 a 57

pour le #nom, c'est peut-etre qu'il y a un probleme de traduction,
Sur le site que j'utilise pour la conversion fr/en pour les fonctions, il a l'air de penser que Mid c'est STXT et pas STEXT, tu es sur de la traduction? http://www.docmemo.com/office/excelfonctionsanfr.php

Et bien valider la formule par ctrl + maj + enter (sinon tu auras #valeur comme résultat)

Le truc c'est que je ne peux pas tester la formule en francais, mon excel ne la prendra pas
J'ai testé la version anglaise avant de la poster, donc je suis sure du principe mais pas de la traduction

[alsimbad]

si je peux me permettre, ce que n'a pas compris muetdhiver, c'est que la formule ne lui renvoie pas la réponse qu'il attend (A429DATA) mais la position du dernier / c'est a dire 38, il faut rajouter la fonction droite

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
=DROITE(A1;NBCAR(A1)-MAX(SI(STXT(A1;LIGNE(INDIRECT("z1:z"&NBCAR(A1)));1)="/";LIGNE(INDIRECT("z1:z"&NBCAR(A1)));"")))

Bon week end

[EmmanuelleC]

ah oui, effectivement
J'aurai du préciser, désolée

[Muetdhiver]

Merci bcp pour toutes vos explications qui m'ont permis de faire ce que je voulais !
Vous etes des pro des formules d'excel !

Encore merci.