Discussion :

[smailhop]

Bonjour,

Pour un planing j'ai besoin d'avoir la liste des dates début et fin pour chaque semaine d'un mois.
Exemple pour le mois 12/2009 je dois avoir

01/12/2009 06/12/2009
07/12/2009 13/12/2009
14/12/2009 20/12/2009
21/12/2009 27/12/2009
28/12/2009 31/12/2009

Mon analyse me guide vers definir la date debut et fin du mois
avec :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
FisrtDate = DateSerial(Year(Now), Month(Now), 1)
        LasteDate = DateAdd("d", -1, DateSerial(Year(Now), Month(Now) + 1, 1))
 
For i As Integer = 1 To LasteDate.Day '31 pour le mois déc
 
 
 
 
        Next

Je sais pas si quelu'un a une idee

Merci d'avance

[tomlev]

Essaie ce code là :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Public Sub ShowWeeks(ByVal year As Integer, ByVal month As Integer)
    Dim d As New DateTime(year, month, 1)
    Dim nDays As Integer = DateTime.DaysInMonth(year, month)
    While d.Month = month
        Dim nextSunday As DateTime = NextDay(d, DayOfWeek.Sunday)
        Dim lastDay As DateTime = nextSunday
        If lastDay.Month <> month Then
            lastDay = New DateTime(year, month, nDays)
        End If
        Console.WriteLine("{0} - {1}", d, lastDay)
        d = nextSunday.AddDays(1)
    End While
End Sub
 
Public Function NextDay(ByVal fromDate As DateTime, ByVal day As DayOfWeek) As DateTime
    Dim start As Integer = CType(fromDate.DayOfWeek, Integer)
    Dim wanted As Integer = CType(day, Integer)
    If wanted < start Then
        wanted = wanted + 7
    End If
    Return fromDate.AddDays(wanted - start)
End Function

Ca s'utilise comme ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ShowWeeks(2009, 12)

La fonction NextDay renvoie le prochain jour de la semaine demandé à partir d'une date donnée. Donc par exemple, NextDay(DateTime.Today, DayOfWeek.Sunday) renvoie la date du prochain dimanche (le jour actuel inclus)

[smailhop]

merci c'est gentil man

[tomlev]

pense au bouton si c'est bon
(en bas de la page)