Discussion :

[osoursou]

Bonjour je cherche à créer une fonction personnelle et non une macro.

J'ai une feuille de données
Libellé S1 S2 S3 S4
Pomme 18 20 14 105
Poire 12 10 96
Cerise 13 14 9 105

Le but de la fonction serait de remonter dans une autre feuille de synthèse si j'écris par exemple en A1 "Pomme" et en B1" S3" je veux dans la cellule active le résultat de l'intersection de la ligne et de la colonne soit ici 14

Merci d'avance pour votre aide

[mercatog]

En complément de ton sujet précédent
si tu insiste pour passer par une fonction
et vu que tu cherche la somme des quantité d'un produit P pendant une semaine S (que tu n'as pas précisé ici), ci joint une proposition

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Public Function Rech(ByVal Prod As String, ByVal Sem As String) As Double
Dim LastCol As Integer
Dim LastLig As Long
Dim P As Range, S As Range
Application.Volatile
With Sheets("BD")  'à adpater
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
    LastCol = .Cells(1, Columns.Count).End(xlToLeft).Column
        Set S = .Range(.Cells(1, 2), .Cells(1, LastCol)).Find(Sem, LookIn:=xlValues, LookAt:=xlWhole)
            If Not S Is Nothing Then
                For Each P In .Range("A2:A" & LastLig)
                    If P.Value = Prod And IsNumeric(.Cells(P.Row, S.Column).Value) Then Rech = Rech + .Cells(P.Row, S.Column).Value
                Next P
            End If
        Set S = Nothing
End With
End Function

[osoursou]

Encore merci, c'est la formule de mes rêves, tu ne sais pas combien d'heures de travail tu viens de me faire gagner......J'espère pouvoir te rendre service à mon tour un jour.
Cordialement