Discussion :

[bobafric]

Bonjour à tous
Je voudrai enregistrer automatiquement mon classeur dans un dossier sur c:\backup toutes les quinze minutes.
Mon problème c’est que la journée administrative commence à 15h et se termine à 3h du matin le lendemain.
J’ai déjà une macro pour enregistrer automatiquement, ci-dessous, mais celle-ci n’enregistre que jusqu’à minuit, à mon avis parce que la journée est à cheval sur deux dates.

Dans ThisWorkbook

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Option Explicit
Private Sub Workbook_Open()
debut = Timer
End Sub
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
    If (debut + 300) < Timer Then
        Application.DisplayAlerts = False
        ThisWorkbook.SaveCopyAs "C:\documents\Backup\" & _
     Format(Date, "dd-mm") & " à " & Format(Time, "hh""H""mm""mn""") & " - " & ThisWorkbook.Name
        Application.DisplayAlerts = True
        debut = Timer
    End If
End Sub

Dans module

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Option Explicit
Public debut As Single

Avec ce code je peux enregistrer ausii chaque fois je j’entre une donnée si le PC est au repos depuis plus de 15mn.
Voilà j’espère que c’est clair sinon je suis à votre disposition pour plus de renseignements.
Merci d’avance
Bob

[pgz]

Bonjour.

Tu pourrais essayer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Public Debut as date

et

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub Workbook_Open()
debut = Now
End Sub
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
    If datediff("s",Debut,Now) > 900 Then
        Application.DisplayAlerts = False
        ThisWorkbook.SaveCopyAs "C:\documents\Backup\" & _
     Format(Date, "dd-mm") & " à " & Format(Time, "hh""H""mm""mn""") & " - " & ThisWorkbook.Name
        Application.DisplayAlerts = True
        debut = Now
    End If
End Sub

A tester.

PGZ

[ucfoutu]

Bonjour,

N'utilise alors pas la fonction Timer, mais la fonction Now en conjonction avec la fonction DateDiff (et tu n'auras plus ce problème de dépendance à Minuit)

[bobafric]

Merci à tous les deux ça fonctionne impec
A plus Bob