masquer la saisie utilisateur [Trucs & Astuces]

**I'm_HERE** · 29/10/2009, 15h13

Salut,

Pour masquer la saisie utilisateur on a plusieurs possibiités chacune d'elle à ses propres avantages et inconvénients

1- outil tierce: EDITV32.EXE

utilitaire de Bill Stewart il y a une version pour les systems 32bit et une autre pour les 64bit

voici comment l'utiliser

2- outil tierce: CONST.EXE (qui est en réalité "un couteau suisse")
il permet de stocker le StdOut dans une variable un peu comme EXPORT.EXE pour ensuite l'exploiter.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
export chemin=`cd`
echo %chemin%
export echoe=`echo bonjour maitre`
echo %echoe%
export moi=`hostname`
echo je suis %moi%

et surtout il permet aussi de masquer la saisie utilisateur,

2- Avec VBS

voici un petit exemple

3- Avec VBS + HTA

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
,@echo off
,::::::::::::::::::::::::::::::::::::::::::::::::::::::::
,::  === Hide Input by WALID (I'm_HERE) ===
,::::::::::::::::::::::::::::::::::::::::::::::::::::::::
,findstr /v "^," "%~f0">{psw}.hta
,goto:suiteCode
 <html> 
   <HTA:APPLICATION 
      border="thin"
      borderStyle="normal" 
      caption="no" 
        maximizeButton="no"
      minimizeButton="no" 
        showinTaskbar="no" 
      singleInstance="yes" 
      sysmenu="yes"
        windowstate="maximize"> 
      <head> 
        <title></title> 
        <style type="text/css">
          .button {border:none}
          .arr_plan {background:#000;color:#fff;border:1px solid #ccc;}
          #mid {margin:300px 200px;}
        </style>
        <script language="VBS"> 
           Sub Submit_OnClick 
              set fso = createobject("scripting.filesystemobject") 
              set fsi = fso.opentextfile("{psw}.bat",2,true) 
              set fsa = document.fo 
              fsi.write("set input="&fsa.psw.value) 
           End Sub 
        </script> 
     </head> 
     <body scroll="no" class="arr_plan">
        <div id="mid"> 
          <form name="fo">
             Mot de passe : 
             <input type="PASSWORD" name="psw" size="30" class="arr_plan"> 
             <input type="BUTTON" name="Submit"  value="Execute" class="button"> 
             <input type="RESET" value="Clear" class="button"> 
             <input type="BUTTON" value="Close" onclick="window.close" class="button">
         </form> 
       </div>
     </body> 
   </html> 
,:SuiteCode
,{psw}.hta
,(for %%A in (call del) do %%A {psw}.bat {psw}.hta) 2>nul
,echo MOT DE PASSE: %input%
,pause

4- avec Debug

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
@echo off & goto:psw
a
db, BF 66 01 B4 03 CD 10 88 16 65 01 B8 07 0C CD 21 3C 0D 74 22
db, 3C 08 74 06 3C 20 77 14 EB 10 81 FF 67 01 72 E7 4F FE 0E 65
db, 01 E8 22 00 EB DD B0 2A AA E8 16 00 EB D5 B8 24 24 AB B4 09
db, BA 66 01 CD 21 89 F8 2D 68 01 B4 4C CD 21 FE 06 65 01 8A 16
db, 65 01 B9 01 00 B8 2A 0A CD 10 B4 02 CD 10 41 B8 20 0A CD 10
db, C3 00 6D 61 6B 65 20 62 79 20 62 65 6E 74 6F 6E 2E

r cx
75
n _.com
w
q
:psw
:::::$ By WALID (I'm_HERE)
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
debug < %0 >nul
cd|set/p=Mot de Passe: % 
for /f "delims=" %%a in ('_.com') do set PSW=%%a
echo.
echo/%PSW% 
del _.com
pause

5- Avec une boite de dialogue de "Herbert Kleebauer"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

@echo off
echo Bj@jzh`0X-`/PPPPPPa(DE(DM(DO(Dh(Ls(Lu(LX(LeZRR]EEEUYRX2Dx=>inp.com
echo 0DxFP,0Xx.t0P,=XtGsB4o@$?PIyU WwX0GwUY Wv;ovBX2Gv0ExGIuht6>>inp.com
echo T}{z}~@GwkEG@OEKcUt`}}@MqqEsy?seHE}_Phxr?@zAB`LrPEyoDt@Cj?>>inp.com
echo pky_jN@QEKpEt@ij?jySjN@REKpEt@jj?jyGjN@SEKkjtlGuNw?p@pjirz>>inp.com
echo RFvAYXV?_YLTV@@?~VCo_R~RDY@?aY?@MV_AMy1GHs?Gw`LbLK@shM`S_d>>inp.com
echo bD_nsDddlTr_sPdlnTcnaTv_xP_ngD_rhDhsrT_kkDhrtT_fmDRNCTILk?>>inp.com
echo staThg_So_rPfnqTl`qTdq_ShtpTrdqThV_Sqrm@ILm?O?cOKRDP?@@?dx>>inp.com
echo OdFYu?N?_B@J@??KD?HYE?VPsA_VO?R?XCAVO?YCR?YCE?V_F?DYA?CYB?>>inp.com
echo ORO?ROX?DYO?IYO?RO?@RY{O?ROOmYY?wdsTnVs@OVD?VEV?LYA?_R_oo~>>inp.com
echo Y_}RO_WROoiROo{ROoGRO?URP?eRP?qRP?DYP?RPc@RPq@RPAARPMAYP_A>>inp.com
echo OGDG{HYOOVO?PKRC}HY?gRP?TYO?DRTTqrQ@kcmSoRk`}RO_WROoiROo{R>>inp.com
echo OoGRO?URP?eRP?qRP?FYP?rdLTf`rTnAdTV@wD`hCTfnkTwnATcmHTdqhT>>inp.com
echo OsbT`q`TV@lDsdFTfkCTdsHTdSlT@swTdRVSkCsTsHfTSldTswdTDV@PCc>>inp.com
echo mTk`hTVfnDsdFTfkCTdsHTFXlPCsdTBfkTkqsTXCHDsdFTbnETXrtDsdRT>>inp.com
echo bnETRrtDQDJTKDMTmqr?kkcTPcRCPqRCPARGPMRGP_RGDFYOshwTnqOTrd>>inp.com
echo bTFVrPRsdTGcsTcm`TXdkDhqVTEdsTdkhTdFVSnBsT`llTKcmTdmhTFV@P>>inp.com
echo LsdTtcnTGdkTcm`T@dkTXgRCwT~B??OCgXgP?PjRXg?CQ{gHO??PCT~B??>>inp.com
echo OCOwOX??SC@1gNT~RK?OgOCJ?W=Gc?R@O?]CNgP=V?sR@O?pDo?OABcCJE>>inp.com
echo =eKCs?AO=ezDt?@OT~jN?O[O~O?sOWT?=??@tVNOOiZCcs~FT~GK?OSO~O>>inp.com
echo ?sO_T?w??`AV@o_?OOSX}E~??`iVNOVUOTcs~FT~oK?OGOE@?oLEFBdrIS>>inp.com
echo CEFFo_sPEF`\rrGSB?=_FJERO~@MOuVstEFvRIL?pO`H~O?vGcs@OT~B??>>inp.com
echo OC~djzOsT?G??Pw??HEs?C_w?A?tt\NiODcs~FT~KK?OKOBj?kGAR?X??J>>inp.com
echo I?E??I??Y?GRACYO?`?Cb?sP?g?CH?_O?m?Ct?oPYs?CO@EO?vX?w?IO?I>>inp.com
echo ??~?NoY@~J?_E?XO@C]?v??w?CO?I?~~?{EY@A@?@?wXOP?v??N?g??@??>>inp.com
echo ?~~n?N?CGYJ@XO@Cv?{??g??A?N?~~?{B??Q?`?Cb?mP?d?CEYk@ORAO?I>>inp.com
echo X?b?I??I??~?Lo?A~Jr?TP?d?Cm?qP?`?Cd?lPYy??RAC?IXO@?]??I?b?>>inp.com
echo ?M??A~~n?O?Cr?`P?r?Cn?vP?q?Cy?c@_CYOIEHm?GEoEGsPVDgB`qj1OB>>inp.com
echo O]SwaAp??@DB?B?SGPLt?C~ti=OkT?b??`?SGP?i?CSKgDi??Pwg@C??SC>>inp.com
echo T~OL?OoO?H?oi[tPxg?C??SCSxg@i??PT~?K?O?O?i?CgT~B??OCK=@Q??>>inp.com
echo SCtV@OBWWvqv?SdshTqd_SqnqTrJYO_sdDdrtTL=q@drISo_sPrr`TIL=?>>inp.com
echo Y~YKY~XM0x>>inp.com

inp.com >inp.exe
del inp.com

::Wk2/XP:
for /f "tokens=*" %%i in ('inp.exe guest') do %%i
echo username: %user%
echo password: %pass%

::Win9x:
::inp.exe guest>_.bat
::call _.bat
::del _.bat
::echo username: %user%
::echo password: %pass%

del inp.exe

**maxim_um** · 29/10/2009, 22h04

Salut I'm_HERE,

Pourquoi ne fais-tu pas un script natif ? Au pire, avec «choice».

**I'm_HERE** · 29/10/2009, 23h22

Envoyé par maxim_um

Salut I'm_HERE,

Pourquoi ne fais-tu pas un script natif ? Au pire, avec «choice».

salut maxim_um,

je ne vois pas le rapport avec choice "qui n'est pas une commande native (XP)". Dans ce petit post le but était de montrer quelques exemples variés pour cacher la saisie utilisateur..avec des commandes externes et des script hybrides (qui peuvent être considéré comme "natif" puisqu'on n'a pas besoin d'outil tierce pour les faire fonctionner)

**maxim_um** · 30/10/2009, 00h08

Choice fait du va-et-vient au grès des différentes versions Windows. Quoi qu'il en soit, il reste toujours possible de l'obtenir depuis le site de Microsoft. Le fait qu'il ne soit pas disponible d'origine dans XP ne fait pas de lui un outil non natif. Il est trop commun pour être qualifié de la sorte.

**I'm_HERE** · 30/10/2009, 02h21

Envoyé par maxim_um

Choice fait du va-et-vient au grès des différentes versions Windows. Quoi qu'il en soit, il reste toujours possible de l'obtenir depuis le site de Microsoft. Le fait qu'il ne soit pas disponible d'origine dans XP ne fait pas de lui un outil non natif. Il est trop commun pour être qualifié de la sorte.

est-que choice permet de cacher la saisie utilisateur ?..si oui alors on l'ajoutera à la liste..maintenant

**maxim_um** · 30/10/2009, 20h37

Oui, mais il ne peut pas s'auto-suffire. Il faut l'accompagner d'un script. Enfin, c'était ça l'intérêt.

**Mat_F** · 29/05/2010, 13h18

Merci I'm_HERE pour ces informations et cette synthèse des différentes méthodes pour masquer la sisie utilisateur, que j'ai lu avec beaucoup d'intérêt.

Je me pose toutefois quelques questions _

- Parmi les méthodes exposées, lesquelles n'écrivent jamais la saisie dans un fichier temporaire ? Il me semble que c'est le cas pour la méthode n°5, qui n'utilise un fichier externe que pour générer l'interface graphique, non ?

- Toujours à propos de la méthode N° 5, y a-t-il moyen justement de modifier cette interface (p.ex. pour avoir uniquement un champ texte et pouvoir changer son libellé) ?

Merci d'avance pour ce complément d'info

**john.fender** · 31/05/2010, 13h40

Pour apporter ma pierre :

Masquage partiel (personne ne le verra de loin, mais ca reste à usage réduit, et il faut avoir de bon yeux, avantage, ca fonctionne en batch simple) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

color f7

Avec ctext.exe (à télécharger), mise en noir du text & de l'arrière plan dans la console :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ctext {0,0}

Enfin, le code en VBS est un peu plus simple que celui proposé :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Set objPassword = CreateObject("ScriptPW.Password") 
WScript.StdOut.Write "Please enter your password:" 

strPassword = objPassword.GetPassword() 
Wscript.Echo
Wscript.Echo "Your password is: " & strPassword

A exécuter en console avec cscript évidement.

**Mat_F** · 31/05/2010, 18h20

Merci aussi à john.fender.

La solution VBS me plaît pas mal mais je ne vois pas trop comment l'utiliser. Pour résumer, disons qu'on crée un fichier pw.vbs qui contient le code que tu as fourni. La question c'est que devrait contenir le code d'un fichier pw.bat pour récupérer le mot de passe demandé par pw.vbs ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
@ECHO OFF
CSCRIPT pw.vbs
...
ECHO Le mot de passe saisi est :
ECHO ???

Ou sinon comment utiliser pw.vbs ?

**john.fender** · 09/06/2010, 12h35

Tout dépends de l'action que tu veux faire derrière. Tu peux tout faire en VBS ou déporter uniquement l'action sensible et renvoyer un code d'erreur pour permettre au batch de gérer.

**Mat_F** · 10/06/2010, 13h16

Je pensais plutôt la deuxième option, donc récupérer dans le batch le résultat du script VBS.

john.fender, peux-tu nous éclairer ?

**john.fender** · 10/06/2010, 17h24

Ben non je peux pas t'éclairer avec si peu d'infos.

En gros tu code dans ton VBS les actions à déporter, puis tu renvoies en fonction avec wscript.quit x ton numéro d'erreur pour continuer en batch (tu testeras %errorlevel% aprés ton appel via cscript au vbs).

**I'm_HERE** · 18/06/2010, 11h29

salut,

tu peux simplifier comme ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
@echo off & :: Tester sous XPSP3
>$ echo set o=createObject("scriptpw.password"):wsh.echo o.getpassWord():^
        set a=createobject("scripting.filesystemobject"):a.deletefile("$")
cd|set/p"=PASSWORD: " 
for /f "tokens=*" %%* in ('cscript -nologo -e:vbs $') do set "mdp=%%*"
echo=%mdp%
pause

**Mat_F** · 22/06/2010, 15h12

Envoyé par john.fender

En gros tu code dans ton VBS les actions à déporter, puis tu renvoies en fonction avec wscript.quit x ton numéro d'erreur pour continuer en batch (tu testeras %errorlevel% aprés ton appel via cscript au vbs).

@john.fender
Aurais-tu l'amabilité de développer ? Parce que là je ne comprends rien du tout. Un petit bout de code ne serait pas du luxe.

@I'm_HERE
Merci pour le code mais y aurait-il moyen à ton avis d'éviter de créer le fichier temporaire pour stocker le mot de passe ?

Merci d'avance

**I'm_HERE** · 22/06/2010, 16h35

salut,

Envoyé par Mat_F

@I'm_HERE
Merci pour le code mais y aurait-il moyen à ton avis d'éviter de créer le fichier temporaire pour stocker le mot de passe ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
@echo off & :: Tester sous XPSP3
>$ echo set o=createObject("scriptpw.password"):wsh.echo o.getpassWord():^
        set a=createobject("scripting.filesystemobject"):a.deletefile("$")
cd|set/p"=PASSWORD: " 
for /f "tokens=*" %%* in ('cscript -nologo -e:vbs $') do set "mdp=%%*"
echo=%mdp%
pause

dans le code que je t'ai donné, j'ai fais en sorte que le fichier temporaire soit fusionner au code VBS pour que le traitement de création/execution/effacement du fichier temporaire soit presque en même temps, tu peux si tu veux mettre un chemin %temp%.\fichier_de_lot_vbs au lieu de $ ainsi le fichier temporaire ne sera pas visible

voici une autre solution sans création de fichier temporaire mais cette fois avec jscript:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
@set @cmd=false; /*
@Echo oFF
cd|Set/p"=PASSWORD: "
For /f "delims=" %%_ in ('
    cscript /nologo /e:jscript %0 _MotDePasse
 ') Do Set "%%_"
echo:
::::::::::::::::::::::::::::::::::::::::::::::::::::
:// Debut Code Batch

echo %_MotDePasse%
pause


:\\ Fin Code Batch 
::::::::::::::::::::::::::::::::::::::::::::::::::::
Goto :EOF
*/
function PASSWORD() 
{
 var z;
 var o = WScript.Arguments
 var z=new ActiveXObject("ScriptPW.Password");
 var s = z.GetPassword();
 WScript.Echo(o(0) +"="+ s);
}
PASSWORD()

**Mat_F** · 20/07/2010, 15h11

Génial, ça marche !!!

Merci I'm_HERE opur cette élégante solution

Solution qui suscite tout de même quelques questions :

1) Pourquoi utiliser JScript au lieu de VB Script ? Est-ce indispensable ?
2) L'exécution de JScript peut-elle être empêchée (p.ex. via le registre comme c'est le cas opur VB Script) ?
3) Serait-il possible d'avoir une petite explication du code fourni ?

**I'm_HERE** · 20/07/2010, 16h13

Envoyé par Mat_F

1) Pourquoi utiliser JScript au lieu de VB Script ? Est-ce indispensable ?

parceque jscript a des syntaxes commune au fichier de commandes NT et ces blocs de commentaires sont plus magnable avec les fichiers de commandes

Envoyé par Mat_F

2) L'exécution de JScript peut-elle être empêchée (p.ex. via le registre comme c'est le cas opur VB Script) ?

tout peut être empêcher de s'executer par la base de registre, même les fichier batch

Envoyé par Mat_F

3) Serait-il possible d'avoir une petite explication du code fourni ?

j'essayerais:
on mets à l'en-tête du fichier Batch une expression commune à Cmd et Jscript @set @cmd=false; qui est interpréter par Jscript comme etant une intro à une condition de compilation "à mettre en commentaire", c'est comme "les conditions mis en commantaires" qu'on met dans l'en-tête des fichiers html pour verifier la version de IE et agir de suite.

les blocs mis entre /* */ sont considérés des commentaires, donc ils seront ignorés par jscript.
On gros, Cmd va appeler Jscript qui lira le fichier batch en ignorant les commentaires par la suite Cmd.exe prendra la main.

**reremoki** · 25/05/2013, 22h22

Bonjour,
pour la solution 5 que se passe-t-il quand on appui sur cancel??
Merci.
Reremoki.

**sachadee** · 26/05/2013, 04h10

Salut,

On sort du programme sans affecter de valeur au variable %user% et %pass%

Amicalement

**reremoki** · 27/05/2013, 08h59

J'ai remarqué que la solution 5 ne marche pas pour les windows 64 bits. Quelqu'un pourrait-il en fournir une version compatible 32 et 64 bits s'il vous plait.
Merci.
Reremoki.

masquer la saisie utilisateur [Trucs & Astuces]

Scripts/Batch

Discussions similaires

Partager

Partager