Discussion :

[zandru]

Bonjour,

j'ai une erreur sur mon code :

"la methode select de la classe range a échoué"

sur la première ligne du code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
client.Range("A3:L" & ligneclient).Select
Selection.Sort Key1:=Range("A3"), Order1:=xlAscending, Header:=xlGuess, OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom

et je ne comprend pas pourquoi

client est une feuille xls et ligneclient contient 78.

[aalex_38]

Bonjour,

dans ton code pas besoin de select :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

client.Range("A3:L" & ligneclient).Sort Key1:=Range("A3"), Order1:=xlAscending, Header:=xlGuess, OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom

client est une feuille xls

client est le codename de la feuille c'est bien ça ? (nom de la feuille dans le projet)

[Jean-Philippe André]

salut,
peut-on avoir les lignes juste au dessus (attribution de la variable client) ?

voir si fusionner les lignes ne fait pas sauter l'erreur :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

client.Range("A3:L" & ligneclient).Sort Key1:=Range("A3"), Order1:=xlAscending, Header:=xlGuess, OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom

[LeForestier]

Bonjour tous,
Ca serait pas plutôt..

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("client").Range("A3:L" & ligneclient).....

Voir aussi si pas d'erreur dans la transcription du nom de la feuille, l'erreur la plus fréquente c'est un espace "invisible".
A+

[ouskel'n'or]

"la methode select de la classe range a échoué"

Tu ne dis pas si Client est le nom de la feuille ou l'instance de la feuille.
Dans le premier cas ce sera
Sheets("client").Range("Gnagna... 'dixit l'homme des bois
et dans le second client devra être déclaré "as worksheet", instancié "set client = Worksheets("nomde la feuille") et utilisé tel que tu l'as fait

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

client.Range("Gnagna...'dixit les autres

Bonne journée

[Bigalo]

Bonjour à tous,

La suggestion d’aalex_38 me paraît la meilleure approche. En effet les Select sont une source de ralentissement : à la main, on est obligé de sélectionner un objet (classeur, feuille, cellue, …) pour interagir avec lui. Mais il n’y a aucune raison de le faire en VBA si une méthode peut être appliquée directement ou s’il s’agit de modifier une propriété.

En ce qui concerne ton plantage, es-tu sûr que "Client" est la feuille active au moment où l’instruction doit être exécutée ? Outre ralentir les traitements, les Select (et Activate) sont une fréquente source de bugs, liée au fait que Select plante si l’objet n’est pas au premier plan ;-(

[aalex_38]

Bonjour à tous,

Effectivement je viens de faire le test ci-dessous, et j'ai le même message si le classeur n'est pas actif, s'il est actif ça fonctionne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub testx()
Dim client As Worksheet, LigneClient As Long
 
Set client = ThisWorkbook.Worksheets("client")
LigneClient = 78
 
client.Range("A3:L" & LigneClient).Select ' => fonctionne seulement si le classeur est actif
client.Range("A3:L" & LigneClient).Sort Key1:=Range("A3"), Order1:=xlAscending, Header:=xlGuess, OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom
' MsgBox Err.Number & Err.Description
 
End Sub

edit : c'est aussi un plantage sur la ligne de tri, au début j'ai essayé, ThisWorkbook.Activate mais il y a aussi un problème si on est pas sur la feuille active

edit2 : au final un code qui semble fonctionner :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
Sub Tri_Client()
Dim client As Worksheet, LigneClient As Long
 
LigneClient = 78
Set client = ThisWorkbook.Worksheets("client")
client.Activate
client.Range("A3:L" & LigneClient).Sort Key1:=Range("A3"), Order1:=xlAscending, Header:=xlGuess, OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom
 
End Sub

[CodeFacile]

A mon avis , si tu veux utiliser le select , fait d'abord un client.activate pour selectionner le fichier actif.

J'ai aussi 2 autres pistes .

Regardes sur la zone A3:L78 , si il y a des cellules fusionnées , ça fait planter le tri.

Regardes aussi si le classeur est partagé. J'ai rencontré le cas , ça empêche le tri ?

[Bigalo]

@ aalex_38

Il n’est absolument pas nécessaire que le classeur soit actif. Toutefois, pour que cela marche si la feuille à trier n’est pas la feuille active du classeur actif, il faut modifier 1 des arguments de Sort.

En effet, Range fait référence par défaut à la feuille active. par conséquent Key1:=Range("A3") n’est valable que si la feuille à trier est active. Il faut donc utiliser Key1:=client.Range("A3"), ce qui donne à partir de ton code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub testx()
Dim client As Worksheet, LigneClient As Long
   ' ThisWorkbook.Activate
    LigneClient = 78
    Set client = ThisWorkbook.Worksheets("client")
    client.Range("A3:L" & LigneClient).Sort Key1:=client.Range("A3"), Order1:=xlAscending, Header:=xlGuess, OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom
End Sub

@ codefacile

Il NE FAUT PAS utiliser le Select. Ce n’est qu’une source de ralentissements et de bugs potentiels !

[aalex_38]

Merci Bigalo, en effet j'évite souvent les activate et toujours les select (sauf cas exceptionnels) dans le code, eventuellement en utilisant des with.
Avec le code donné ça ne m'a pas sauté aux yeux, merci pour ces précisions, bonne journée

[Bigalo]

De rien aalex_38.

Bonne journée également !

[zandru]

Merci à tous !

effectivement le problème ( les problèmes en fait ) venait d'une part du select inutile, et surtout du fait que la feuille active n'était pas obligatoirement Client.

Ce qui fait que le Range("A3") ne faisait pas toujours partie de la zone à ranger.

ce qui donne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

client.Range("A3:L" & ligneclient).Sort Key1:=client.Range("A3"), Order1:=xlAscending, Header:=xlGuess, OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom

Avec client l'instance de la feuille.

Merci encore