Discussion :

[debdev]

Bonjour,

Je cherche à sortir un rapport qui me surligne les cellules qui m'intéressent.
Je ne connais pas à l'avance les noms des colonnes de mon dataset ni leur nombre donc je les afficherai toutes.
Je voudrais utiliser un array dans une proc report, j'ai vu que c'était possible dans un bloc compute mais je n'y arrive pas.
Dans mon éditeur, le mot array reste en rouge comme s'il nétait pas reconnu, que je le mette dans le bloc compute ou en dehors.
Quand il est dans le bloc compute, le message est le suivant: The width of STEARLCM is not between 1 and 93. Adjust the column width or linesize.
Quand il n'y a pas de bloc compute, le message est le suivant: Statement is not valid or it is used out of proper order. (et il me souligne array)


Voici mon code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
proc report data=MyDataset nofs split = "$" headskip missing;
	compute /* */; /* je ne sais pas quoi mettre comme variable */
		array MyVariables{*} _NUMERIC_;
		do i=1 to dim(MyVariables);
			if MyVariables[i]=1
			then call define (_COL_,"style","STYLE=[BACKGROUND=ALICEBLUE]");
		end;
	endcomp;
run;

Merci de votre aide.

[olivier.decourt]

Salut.
Je pense que cette histoire est mal embarquée, parce que l'utilisation des Array dans une proc Report est toujours compliquée. Et dans ton cas, après quelques petits essais, je n'y arrive pas.
Si j'ai bien suivi, tu veux colorier toutes les cases qui contiennent un 1. Je te propose une solution sans Array, sans proc Report et sans macro. Mais avec une macro ça marche aussi.
L'idée est de collecter les noms de variables et leurs types auprès d'une proc Contents : on peut ainsi automatiser le traitement sans savoir les noms des variables ou leur ordre, ou encore leur nombre. Attention, en sortie de Contents, les variables sont par ordre alphabétique : il faut donc trier par position dans la table (info VARNUM).
Puis on crée un format pour les variables numériques qui, quand on rencontre la valeur 1, renvoie ta couleur de surlignement. Le seul souci, c'est qu'on ne doit l'appliquer qu'aux colonnes numériques : d'où l'utilité d'avoir collecté qui fait quoi auprès de la proc Contents.
Et ensuite, pour écrire automatiquement la proc Print, j'ai fait un CALL EXECUTE, juste pour faire plaisir au camarade Bruno. C'est là où on peut préférer passer par un macro-programme, mais ça me semble inutilement surcharger le code. Question de point de vue.
Voilà une solution, donc :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
PROC CONTENTS DATA=sashelp.prdsale OUT=work.dico (KEEP=name type varnum) NOPRINT ;
RUN ;
PROC FORMAT ;
	VALUE numSurl
		1 = "ALICEBLUE"
		OTHER = ""
	;
RUN ;
PROC SORT DATA=work.dico ;
	BY varnum ;
RUN ;
ODS HTML ;
DATA _NULL_ ;
	SET work.dico END=fin ;
	IF _N_=1 THEN CALL EXECUTE("PROC PRINT DATA=sashelp.prdsale NOOBS LABEL ;") ;
	CALL EXECUTE ("VAR "!!name) ;
	IF type=1 THEN CALL EXECUTE ("/STYLE(DATA)=[BACKGROUND=numSurl.]") ;
	CALL EXECUTE (";") ;
	IF fin THEN CALL EXECUTE("RUN ;") ;
RUN ;
ODS HTML CLOSE ;

Bon courage.
Olivier

[debdev]

Pour changer, merci olivier

Ta solution marche parfaitement. Pas de proc report, pas d'array, perso, ça ne me dérange pas . En plus, ton code me permet d'utiliser call execute dont m'avait déjà parlé Bruno (quand j'avais demandé si on pouvait imbriquer une étape data dans une étape data).

Juste pour info, voici le lien sur lequel je suis tombée quand j'ai cherché dans google proc report array. C'est un extrait du livre "SAS guide to report writing" (Michele Burlew). http://books.google.fr/books?id=k1Zr...esult&resnum=3

C'est à la page 130. Il met un array dans une proc report. Je sais que ce n'est pas comme mon cas, mais bon, je pensais y arriver ...

Merci à toi pour ta solution.

Bonne après midi et bon week end

[olivier.decourt]

J'avais effectivement déjà fait des Array dans ces conditions, avec une variable ACROSS et donc un nombre de colonnes un peu imprévisible. Mais pour que ça fonctionne, il faut énumérer toutes les colonnes temporaires, _C1_, _C2_, etc. Quant à lui parler d'autres variables, je suis encore un peu dans le flou : est-ce qu'on doit lui parler de ACTUAL, par exemple, ou de ACTUAL.SUM (les variables numériques, en l'absence de DEFINE, font l'objet de sommes par défaut) ? L'habitude dans COMPUTE est de parler de ACTUAL.SUM ; mais dans mes essais, c'est un échec. Et pourquoi le _NUMERIC_ ne fonctionne-t-il pas ? Ah, la proc Report, quel mystère !
Restons à Print et Tabulate, captain.
Bon week-end.