[XSLT] Comparaison 2 documents XML?

**Marian83** · 14/04/2009, 16h09

Bonjour,

J'ai un document XML composé des éléments : "Terme" et "Definition".
Il y a des termes dans ce document dont je souhaiterais exclure.

J'ai pensé alors à une liste "Stop" au format XML contenant les termes indésirables pour que via une feuille XSLT fait une comparaison entre le document XML et la liste ainsi le nouvel document XML affiche tout sauf ce qui se trouve dans la liste!

Est-ce que c'est faisable ou je me complique la vie (pour le moment j'ai l'impression que je me complique la vie car je ne trouve pas la solution

)?

Merci

**emmanuel.remy** · 14/04/2009, 17h07

J'ai un document XML composé des éléments : "Terme" et "Definition".

Je suppose que tu ne peux pas toucher à ce doc ? Si c'est le cas il va bien falloir inscrire cette liste de "Stop Words" quelque part ?

Donc ce que tu proposes a évidemment un sens.

Tu peux très bien effectuer une transformation XSLT pour supprimer les "Termes" superflus.
Et tu peux même te simplifier la vie en mettant ces termes directement dans ton doc XSL (par exemple sous la forme d'une variable).

ERE

**Marian83** · 15/04/2009, 10h17

Effectivement je ne peux pas toucher au doc :-)
Merci emmanuel.remy, ça me rassure dans mon choix :-)

Par contre, depuis hier je n'arrive pas à faire fonctionner la feuille XSLT.

Dans le nouveau document, il y a toujours les mots indésirables : Soit c'est une erreur de raisonnement, soit c'est une erreur syntaxique.

Le document XML se presente de cette manière:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
<?xml version="1.0" encoding="UTF-8" ?>
<tree>
  <node>
    <terme>Terme 1</terme>
    <description>Def 1 .... </description>
   </node>  
 
   <node>
    <terme>terme 2</terme>
    <description>Def 2 .....</description>
   </node>   
</tree>

La feuille XSLT que j'essaie de faire fonctionner sans succès :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="xml" encoding="UTF-8" indent="yes" />
 
<xsl:template match="node">
 
<!-- Liste "Stop"-->
<xsl:variable name="mots">
<lab>Terme 2</lab>
<lab>Terme 4</lab>
<lab>Terme 100</lab>
</xsl:variable>
 
<xsl:for-each select = "current()[not (xsl:variable[@name='mots']/*)]">
<label><xsl:value-of select="terme"/></label>
<descr><xsl:value-of select="description"/></descr>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>

Ceci ne fonctionne pas non plus :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
<xsl:if test = "terme != $mots">
<label><xsl:value-of select="terme"/></label>
<descr><xsl:value-of select="description"/></descr>
</xsl:if>

ça fonctionne que quand je fait:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
<xsl:template match="node">
<xsl:variable name="mot1">Terme 2</xsl:variable>
<xsl:variable name="mot2">Terme 4</xsl:variable>
 
<xsl:if test = "(terme != $mot1) and (terme != $mot2)">
 <label><xsl:value-of select="terme"/></label>
 <descr><xsl:value-of select="description"/></descr>
</xsl:if>
</xsl:template>

Bien sûr ce n'est pas une solution souhaitable car si on a 100 termes à exclure, ça veut dire 100 variables à exclure !!

Je suis perdue dans tout ça. Si quelqu'un pourra m'éclairer, ça sera génial!!

Merci

**emmanuel.remy** · 15/04/2009, 14h02

Salut,

Pourquoi ne pas mettre tous les stop words dans un fichier XML à part (plus simple pour la maintenance) ? Ensuite tu peux les sélectionnés et les parcourir par un:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

document('stopwords.xml'))//lab"

Il te suffit de vérifier au moment de la transformation que le node traité n'est pas dans la liste des stop words.

ERE

**Marian83** · 15/04/2009, 15h02

Salut,

J'ai essayé les deux : avec une variable ou avec un fichier XML distinct mais à chaque fois c'est le même problème : il n'enlève que la première balise :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
 
<xsl:variable name="doc">
 <xsl:for-each select="document('stopWords.xml')/tree">
   <xsl:value-of select="*"/>
 </xsl:for-each>
</xsl:variable>
 
<xsl:template match="tree">
<Glossaire>
  <xsl:for-each select="node">
    <xsl:if test= "terme != $doc">
       <label><xsl:value-of select="terme"/></label>
       <descr><xsl:value-of select="description"/></descr>
    </xsl:if>
   </xsl:for-each>
</Glossaire>	
</xsl:template>

Si dans stopWords.xml, j'ai :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
<?xml version="1.0" encoding="UTF-8"?> 
 
<tree>
<label>Terme A</label>
<label>Terme B</label>
<label>Terme Z</label>
</tree>

Je n'ai en résultat que Terme A d'enlever !!

J'ai beau tourner le pb dans tous les sens, je n'arrive pas à détecter ce qui ne va pas !! Je désespère

**emmanuel.remy** · 16/04/2009, 00h03

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output method="xml" encoding="UTF-8" indent="yes" />
 
<xsl:variable name="sw" select="document('stopWords.xml')//label" />
 
<xsl:template match="tree">
<Glossaire>
  <xsl:for-each select="node">
    <xsl:if test= "not($sw[text()=current()/terme])">
       <label><xsl:value-of select="terme"/></label>
       <descr><xsl:value-of select="description"/></descr>
    </xsl:if>
   </xsl:for-each>
</Glossaire>	
</xsl:template>
</xsl:stylesheet>

avec les stopwords ainsi:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
<?xml version="1.0" encoding="UTF-8"?> 
<tree>
  <label>Terme A</label>
  <label>Terme B</label>
  <label>Terme Z</label>
</tree>

ERE

**Marian83** · 16/04/2009, 09h34

WoOoOW

Et dire que ça fait plus de 2 jours que je me bats avec des if et des current() et des variables ... :-) Et finalement, c'était un problème de condition :-)

En tout cas, tout ce que j'ai pu essayé et réessayé n'est pas perdu puisque ça me permet d'avancer, d'apprendre, etc.

Je te remercie énormément emmanuel.remy!

Au plaisir de rediscuter avec toi et qui sait, peut-être, un jour t'aider à résoudre un problème en XSLT

**GrandFather** · 22/04/2009, 11h56

Bonjour,

on peut même se passer du xsl:if

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
<xsl:for-each select="node[not(terme = $sw)]">
  <label><xsl:value-of select="terme"/></label>
  <descr><xsl:value-of select="description"/></descr>
</xsl:for-each>

**emmanuel.remy** · 22/04/2009, 13h17

Envoyé par GrandFather

Bonjour,

on peut même se passer du xsl:if

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
<xsl:for-each select="node[not(terme = $sw)]">
  <label><xsl:value-of select="terme"/></label>
  <descr><xsl:value-of select="description"/></descr>
</xsl:for-each>

Salut GrandFather,
Pour mon info, je ne comprends pas ton terme = $sw; on peut comparer un élément unique (ici terme) avec une collection d'éléments ($sw qui vaut un //label) ? Il les comparent entre eux ?

ERE

**GrandFather** · 22/04/2009, 15h19

Tout à fait, et c'est une des particularités parmi les plus puissantes et les plus méconnues de XPath.

Dans un test avec un opérateur de comparaison (=, !=, <, <=, >, >=), quand l'un des termes est une valeur scalaire et l'autre un nodeset, le résultat est vrai quand il existe au moins un noeud dans le nodeset pour lequel la comparaison revoit vrai. Selon cette définition, il est d'ailleurs intéressant de noter que a != b ne renverra pas forcément le même résultat que not(a = b).

Cela permet d'exprimer très facilement, en une seule expression XPath, des fonctions telles que min() et max(). Par exemple, pour trouver la valeur minimum parmi des éléments element frères, il suffira d'écrire ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

//element[not(../element &lt; .)]

La simplicité de l'expression ne doit cependant pas faire oublier que ce n'est pas optimal sur le plan des performances, sa complexité étant quadratique. Une fonction min() codée avec quelques instructions en XSLT sera elle de complexité linéaire.