Discussion :

[P96O1004]

Bonjour,

J'ai eu du mal à expliquer mon problème sur le titre. C'est aussi la raison pour laquelle je n'arrive pas à utiliser mon ami google .
En effet, je veux faire un macro pour déplacer vers la feuille juste avant.
Par exemple : je suis dans la feuille 5, je clique sur la feuille 9, je exécute le macro et je reviens à feuille 5 .

Comment le dit sur vba ?

Merci d'avance

[drakkar_agfa]

Bonjour,

Est-ce quelque chose comme ceci?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Worksheets("Feuil5").Activate

Sinon, tu devras expliquer un peu plus!

[casefayere]

Bonjour,

peut-être en déclarant ta feuille dans une variable "public" avant de changer

dans un module
public nomfeuil as string

dans ta procédure

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

nomfeuil = activesheets.name

en fin de procédure sur feuille 9

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sheets(nomfeuil).activate 'ou select

ca devrait marcher

[P96O1004]

Merci pour les réponses si rapides

Mais je veux que ce macro marche pour toutes les feuilles. Ca veut dire, si je suis à feuille 1, je vais à feuille 2, ensuite, je vais à feuille 3, je lance le macro, je reviens à feuille 2, je lance encore macro je reviens à feuille 1.

C'est pour naviguer entre 2 feuille dans un fichier de 60 feuilles.

Si un jour excel comprend ce qu'on pense, ça sera

[drakkar_agfa]

Il est possible d'utiliser cette technique (comme précédent dans exploreur) mais tu devras coder autant de variables (ou un tableau) contenant le nombre de feuilles que tu veux garder.

Et faire quelque chose du genre

Ancien 1 = Ancien 2
Ancien 2 = Ancien 3
Ancien 3 = Ancien 4
Ancien 4 = Actuel

...

Je viens de penser à quelque chose...

En utilisant une feuille vide qu'on pourrait nommer historique...
En utilisant aucune variable!

La colonne A de la feuille historique contient une valeur (nuérique) qui indique le nombre de feuilles visitées.
La colonne B ... Quand l'utilisateur change de feuille on incrément le compteur (A1), le nom de l'ancienne feuille s'inscrit à la suite (donc la ligne inscrit en A1)

Quand on exécute la macro, on retourne à la dernière feuille inscrite dans la colonne B (en utilisant le numéro du compteur), en effacant la dernière feuille et diminuant le compteur de 1.

[laetitia]

bonjour le fil le forum essai un truc comme cela dans ta macro

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub Inser()
On Error Resume Next 'pour la 1feuil
'ton code
ActiveSheet.Previous.Select
End Sub

[drakkar_agfa]

Ce code sélectionne la feuille précédente (en position) et non la feuille sélectionnée précédemment...

[laetitia]

re le fil le forum oui tu as raison drakkar_agfa ou une bidouille la dedans peut etre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
 
End Sub

[aalex_38]

Oui en reprenant l'idée de l'historique et des évenements,

La derniere feuille utilisée dans une feuille masquée avec dans Thisworkbook :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub Workbook_SheetActivate(ByVal Sh As Object)
If Sh.Name <> "DerniereFeuille" Then
    Worksheets("DerniereFeuille").Range("A1") = ActiveSheet.Name
End If
End Sub

Ensuite dans la macro, il suffit de reprendre la valeur dans la cellule A1.

[drakkar_agfa]

En gros, cette technique nous permet de revenir à la dernière...

Mais l'avant dernière n'est pas gérée avec cette méthode. En utilisant ma méthode proposée plus haut, il est possible de revenir sur plusieurs feuilles.

[aalex_38]

Oui la technique de l'historique est la plus complète.

Bon week end à tous.

Alex

[edelweisseric]

Bonsoir le forum
Bonsoir à vous tous

Une autre idée :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub Workbook_SheetActivate(ByVal Sh As Object)
nomfeuil = ActiveSheet.Name
End Sub
 
Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)
feuille_ancienne = nomfeuil
End Sub

et dans un module

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Option Explicit
 
Public nomfeuil As String
Public feuille_ancienne As String
 
Sub lance() 'ta macro
....
....
Worksheets(feuille_ancienne).Activate
End Sub

si j'ai bien compris

Eric

[Qwazerty]

Salut
Si on garde le principe de l'historique:

Dans un module on met ca

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Public ByReturn As Boolean
 
Sub Retour()
With Sheets("Histo")
    If .Range("A1") <> "" Then
        ByReturn = True
        Sheets(.Cells(Rows.Count, "A").End(xlUp).Value).Activate
        .Cells(Rows.Count, "A").End(xlUp).ClearContents
        ByReturn = False
    End If
End With
End Sub

Dans le ThisWorkBook du classeur on met ça (celui ci contient donc un onglet "Histo" qui pourra être caché)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub Workbook_Open()
Sheets("Histo").Cells.ClearContents
 
End Sub
 
Private Sub Workbook_SheetActivate(ByVal Sh As Object)
 
If Sh.Name <> "Histo" And Sh.Name <> Sheets("Histo").Cells(Rows.Count, "A").End(xlUp).Value And Not (ByReturn) Then
    Sheets("Histo").Cells(Rows.Count, "A").End(xlUp).Offset(1, 0).Value = Sh.Name
End If
 
End Sub

Voila, je pense n'avoir rien oublié, a toi d'adapter a ton besoin, pour ne pas faire d'imper surtout au niveau de la macro du module, qui pourrait être appelé depuis un bouton placé dans les menu par exemple (macro placer dans un xla au demarage de l'appli excel), dans ce cas il faudra verifier que notre fichier est compatible avec les retour en arriere, en controlant l'existance de l'onglet Histo par exemple.

A++
Qwaz

[laetitia]

bonjour le fil le forum autrement faire ultra simple dans l ex: je prends la cellule a1
Option Explicit

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)
[A1] = Sh.Name
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Sub macro1()
'ton code
Worksheets([A1].Text).Activate
End Sub

[Qwazerty]

Salut l'ami Leti
Ta solution est pas mal, mais je ne sais pas les besoins exacts a l'origine de la demande, car ta solution se limite a 1 retour en arrière possible.

Imaginons un passe feuil1, feuil3, feuil4, feuil3, feuil6

Ici quand on fera retour en arrière plusieurs fois on obtiendra

feuil6 -> feuil3 -> feuil6 -> feuil3 ->... ceci est dut au fait que lors du retour en arrière via la macro, le sheetdesactivate joue encore son rôle et inscrit dans feuil3[A1] "feuil6"

Mais bon tous dépend du besoin exact, mais visiblement il souhaite pouvoir revenir en arrière sur plusieurs feuilles

A++
Qwaz

[laetitia]

salut l ami Qwazerty le forum as tu une idee pour ne pas l ecrire sur la feuille l envoyer dans dans variable public en partant de thisworkbook la je bloque pas assez forte dans ces variables publiques. j ai regardais avec l instruction set je mangeais tous mes ongles affreux!!!!!!!!!
a+ leti

[Qwazerty]

Re demoiselle
Voila une solution avec une variable, mais attention avec les variable public, il m'est deja arriver de perdre le contenue d'une variable lors d'un bug sur une partie tout autre du fichier, les variable ont été "purgées" par excel, donc prudence.
Ton utilisation de Desactivesheet plutôt que Activesheet est plus logique.

Dans ThisWorkBook

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)
Dim Test
 
On Error Resume Next
Test = UBound(Tableau)
On Error GoTo 0
 
If Not IsEmpty(Test) Then
    If (Sh.Name <> Tableau(UBound(Tableau))) And Not (ByReturn) Then
        ReDim Preserve Tableau(UBound(Tableau) + 1)
        Tableau(UBound(Tableau)) = Sh.Name
    End If
Else
    ReDim Tableau(0)
    Tableau(0) = Sh.Name
End If

Dans le module

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Public ByReturn As Boolean
Public Tableau
 
Sub RetourTab()
Dim Test
 
On Error Resume Next
Test = UBound(Tableau)
On Error GoTo 0
 
If Not IsEmpty(Test) Then
    ByReturn = True
    Sheets(Tableau(UBound(Tableau))).Activate
    If UBound(Tableau) = 0 Then
        Erase Tableau
    Else
        ReDim Preserve Tableau(UBound(Tableau) - 1)
    End If
    ByReturn = False
End If
 
End Sub

A++
Qwaz

[laetitia]

re monsieur Qwazerty le forum que dire c est vraiment du grand art je suis impressionnee j ai encore beaucoup a apprendre si avec ce code P96O1004 n est satisfait alors la je fais un scandale!!! super
passe un bonne soiree Qwazerty
leti a+

[P96O1004]

Merci "LES PROS"

testing ...

Bonne semaine à vous tous

[Godzestla]

Joli code Qwaz....