Discussion :

[tmamy]

Bonjour,

Quand je fais une requête sur date() ou datetime(), la date fais référence à 01JAN1960:04:58:53.
Savez-vous comment activer cette date pour qu'elle prenne la date du jour ?

Merci

[tmamy]

Suite à mes investigations, il semblerait que cela est dû au format. mais du coup le calcul avec d'autres dates devient erroné.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
data _null_ ;
date = input("&sysdate",date7.) ;
put date ddmmyy10. ;
put date DATETIME20.;
run ;

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
05/02/2009
  01JAN1960:04:58:53

[olivier.decourt]

Bonsoir.
J'ai surtout l'impression que tu t'es emmêlé les crayons entre les dates et les datetimes, parce que "01JAN1960:04:58:53"dt = 17 933 = 05/02/2009.
Donc tu as généré un nb de jours avec DATE(), et ensuite posé un format DATETIME. dessus, ce qui donne ce 1er janvier 1960 à 5 heures du mat.
Normalement, la fonction DATETIME() doit renvoyer une valeur correcte, dans Guide ou pas dans Guide, puisque c'est une session SAS normale qui exécute le code au final.
Une date SAS = nb de jours depuis le 01/01/1960
Un datetime = nb de secondes depuis le 01/01/1960 à minuit
Il y a des fonctions de conversion pour passer de l'un à l'autre.

Olivier

[tmamy]

Merci Olivier,

Comment savoir si dans la bdd on est sur datetime ou date ?
01JUL2008:00:00:00 est la valeur que j'apperçois dans ma table,
je voudrais retirer toutes les dates qui ont plus de six mois à partir de la date du jour. Comment faire, cela ne retourne pas les bons résultats. La requête manuelle est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
proc sql;
create table CMP_TARGET_OVER_SIX as
select c.company_key 
	   ,max(call_date) as last_call_date
from CMS_CH.CMS_RESPONSE c
group by company_key
having last_call_date < '01aug08'd
;

Je voudrais quelque chose de plus explicite comme :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
proc sql;
create table CMP_TARGET_OVER_SIX as
select c.company_key 
	   ,max(call_date) as last_call_date
from CMS_CH.CMS_RESPONSE c
group by company_key
having intnx('month',last_call_date,6) < today()
;

[olivier.decourt]

Si tu vois des heures, des minutes et des secondes, même alignées sur minuit pile, c'est un datetime. En fait, on les reconnaît au format (ou, en enlevant le format, à l'ampleur de la valeur : entre -20 000 et 20 000, c'est probablement une date, au-delà, c'est un datetime).
Pour ta requête, tu peux faire quelque chose comme :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
proc sql;
create table CMP_TARGET_OVER_SIX as
select c.company_key 
,max(DATEPART(call_date)) as last_call_date FORMAT=DDMMYY10.
from CMS_CH.CMS_RESPONSE c
group by company_key
having intnx('month',last_call_date,6) < today()
;

Avec la fonction DATEPART, on part d'un datetime (puisque visiblement CALL_DATE en est un, à ce que tu nous dis) et on extrait uniquement la date (en nb de jours depuis 1960) : on peut alors comparer avec TODAY() sans souci.
Bon courage.
Olivier

[tmamy]

Merci Olivier.

C'est tout simplement génial. Ca marche.

Merci encore.