Discussion :

[gueguenk]

Bonjour a tous

Mon probleme est simple
J'ai un logiciel développé en Vb sous access et je suis entrain de passer la bdd sous ms sql server 2005

J'ai donc créer des procédures stockés dont une qui me renvoi un certain nombre d'enregistrements d'une table.

J'essaye tant bien que mal d'exploiter les données de cette procédure.

Je voulai savoir s'il etait possible de travaillé sur une procedure stocké comme sur une table

Exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
Dim conx As New ADODB.Connection
conx.ConnectionString = machaine
conx.Open
 
Dim rec As New ADODB.Recordset
rec.CursorLocation = adUseClient
Dim rep As New ADODB.Recordset
rep.CursorLocation = adUseClient
 
Dim cmd As New ADODB.Command
cmd.CommandText = "BTenC"
cmd.CommandType = adCmdStoredProc
cmd.ActiveConnection = conx
rec.Open cmd
 
TxtSql = "select compteur from " & BTenC & ""
.........?????...............

J'aimerais exploiter les données que retourne l procedure comme une table

Merci

[LedZeppII]

Bonjour,

On ne peut pas faire de SELECT sur une procédure stockée, juste un EXEC.
Mais on peut obtenir un recordset ADO si la procédure stockée renvoie des enregistrements.

Exemple avec une procédure stockée sans paramètres

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Dim oConn As ADODB.Connection
Dim oRS As ADODB.Recordset
 
Set oConn = New ADODB.Connection
oConn.Open "Provider=SQLOLEDB;...."
 
Set oRS = New ADODB.Recordset
oRS.CursorLocation = adUseClient
Set oRS.ActiveConnection = oConn
'oRS.Open "dbo.sp_maprocedurestockee", , adOpenStatic, adLockOptimistic, adCmdStoredProc
oRS.Open "EXEC dbo.sp_maprocedurestockee", , adOpenStatic, adLockOptimistic, adCmdText
 
Do While Not oRS.EOF
   Debug.Print oRS.Fields(0), oRS.Fields(1)
   oRS.MoveNext
Loop
 
oRS.Close
Set oRS = Nothing
 
oConn.Close
Set oConn = Nothing

S'il y a des paramètres on peut les mettre dans la source du recordset, en respectant la syntaxe Transact-SQL.
Par exemple si ma procédure stockée a un premier paramètre numérique et un deuxième texte :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

oRS.Open "EXEC dbo.sp_maprocedurestockee 123, 'abCD'", , adOpenStatic, adLockOptimistic, adCmdText

Pour passer les paramètres on peut également passer par un objet Command.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Dim oConn As ADODB.Connection
Dim oCmd As ADODB.Command
Dim oRS As ADODB.Recordset
 
Set oConn = New ADODB.Connection
oConn.CursorLocation = adUseClient
oConn.Open "Provider=SQLOLEDB;...."
 
Set oCmd = New ADODB.Command
Set oCmd.ActiveConnection = oConn
oCmd.CommandType = adCmdStoredProc
oCmd.CommandText = "dbo.sp_maprocedurestockee"
' Récupérer la collection de paramètres
oCmd.Parameters.Refresh
' Fournir les paramètres
oCmd.Parameters(1).Value = 123
oCmd.Parameters(2).Value = "abCD"
 
Set oRS = oCmd.Execute()
 
Do While Not oRS.EOF
   Debug.Print oRS.Fields(0), oRS.Fields(1)
   oRS.MoveNext
Loop
 
oRS.Close
Set oRS = Nothing
Set oCmd = Nothing
oConn.Close
Set oConn = Nothing

Remarque :
On peut utiliser le nom des paramètres de la procédure stockée.
Si le premier paramètre s'appelle @PARAM1 et le deuxième @PARAM2 (pas très original )

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
oCmd.Parameters("@PARAM1").Value = 123
oCmd.Parameters("@PARAM2").Value = "abCD"

A+