Discussion :

[TaleMaker]

Salut à tous,

Je cherche à lister tous les fichiers contenus dans un dossier et tous ces sous dossiers (un peu comme lors d'une recherche classique sous windows, mais pour plusieurs fichiers d'un coup). Je dois souvent récupérer des centaines de fichiers dans des répertoires et avec des extensions différents.

Pour l'instant mon code est le suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Chemin = Application.InputBox(Prompt:="Copier/Coller l'adresse du répertoire contenant les fichiers à renommer.")
        Range("G2") = Chemin
    Chemin = Chemin + "\*.*"
    Compteur = 1
    Fichier = Dir(Chemin)
 
    'List dir du dossier
    Do While (Len(Fichier) > 0)
        ReDim Preserve Tableau(Compteur)
        Tableau(Compteur - 1) = Fichier
        LigneCompteur = Compteur + 3
        ActiveSheet.Range("C" & LigneCompteur).Value = Tableau(Compteur - 1)
        Compteur = Compteur + 1
        Fichier = Dir()
    Loop

Mais je ne liste que le 1er niveau de dossier.

Merci d'avance,
Phil....

[pgz]

Bonjour.

Si tu ne connais pas le nombre de niveaux à l'intérieur du répertoire, il me semble intéressant d'utiliser une prcédure récursive.
Voici un exemple en utilisant la bibliothèque 'Windows Script Host Object Model", et en écrivant le chemin complet des fichers directement dans la feuille (ce n'est pas le plus rapide).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Private lRow As Long
Private myCell As Excel.Range
 
Public Sub subFilesList(ByVal sRepertoire As String)
Dim fso As IWshRuntimeLibrary.FileSystemObject
 
Set myCell = Application.ThisWorkbook.Sheets(1).Range("C4")
Set fso = New IWshRuntimeLibrary.FileSystemObject
lRow = 0
 
If Not fso.FolderExists(sRepertoire) Then
    MsgBox "Le répertoire " & sRepertoire & " n'existe pas."
Else
    Call subIterFolder(fso.GetFolder(sRepertoire))
End If
 
Set fso = Nothing
Set myCell = Nothing
 
End Sub
 
 
Private Sub subIterFolder(ByRef FolderToList As IWshRuntimeLibrary.Folder)
Dim fld As IWshRuntimeLibrary.Folder, fle As IWshRuntimeLibrary.File
 
For Each fle In FolderToList.Files
    myCell.Offset(lRow, 0).Value = fle.Path
    lRow = lRow + 1
Next fle
 
For Each fld In FolderToList.SubFolders
    Call subIterFolder(fld)
Next fld
 
End Sub

Et la ligne d'appel

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Call subFilesList("C:\Users\...")

En complétant convenablement l'argument.

Cordialement,

PGZ

[TaleMaker]

Merci pour la réponse, je suis en train d'adapter le code à mon programme. Cependant, une question me taraude : Quelle est la fonction de "IWshRuntimeLibrary" dans

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set fso = New IWshRuntimeLibrary.FileSystemObject

??

[pgz]

Merci pour la réponse, je suis en train d'adapter le code à mon programme. Cependant, une question me taraude : Quelle est la fonction de "IWshRuntimeLibrary" dans

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set fso = New IWshRuntimeLibrary.FileSystemObject

??

Ca précise que l'on parle de l'objet FileSystemObject de cette bibliothèque et pas d'une autre.

PGZ