Discussion :

[Deciprog]

Bonjour,

Je voudrais savoir comment je pourrais colorer une ligne sur deux plus foncée d'un tableau généré par une proc tabulate.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
PROC TABULATE DATA = table ;
CLASS variables1 ;
VAR variables2 ;
TABLE … ;
RUN ;

J'ai pensé au paire et impaire avec une boucle et une variable type entier qui s'incrémente. Par exemple quand c'est paire j'affecte à la ligne une couleur grise et quand c'est impaire en gris foncé.

Mais je ne vois pas comment faire !

Merci beaucoup

[olivier.decourt]

Bonsoir.
Je ne pense pas qu'on puisse obtenir ça de la proc Tabulate, parce qu'on ne peut pas changer le style d'une ligne entière sous condition. Par contre, avec Report, ça se passe comme tu le proposes : avec un compteur, initialisé en début de tableau, et incrémenté à chaque ligne. Et un CALL DEFINE pour changer le style à chaque ligne paire (repérer par la fonction MODulo).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
ODS PDF FILE="c:\temp\test.pdf" ;
PROC REPORT DATA=sashelp.class NOWD ;
	COLUMNS age sex weight N ;
	DEFINE age / GROUP ;
	DEFINE sex / GROUP ;
	DEFINE weight / MEAN ;
	COMPUTE BEFORE ;
		numLigne = 0 ;
	ENDCOMP ;
	COMPUTE weight ;
		numLigne + 1 ;
		IF MOD(numLigne,2)=0 THEN CALL DEFINE(_ROW_, "STYLE", "STYLE=[BACKGROUND=GRAYB0]") ;
		ELSE					  CALL DEFINE(_ROW_, "STYLE", "STYLE=[BACKGROUND=WHITE]") ;
	ENDCOMP ;
RUN ;
ODS PDF CLOSE ;

Olivier

[Deciprog]

merci ça fonctionne (désolé de mettre résolut si tard)