Discussion :

[GBAGO]

Bonjour à tous,

C'est peut-être une question bête mais

J'ai une base données MsAccess qui contient plusieurs tables. Je veux supprimer toutes les données de toutes les tables de cette base de données en un seul clic. En dehors de " delete from nomtable", existe-t-elle une autre possibilité pour le faire tout en gardant les structures de ces tables?

Merci de votre réponse à cette question qui frise la bétise!

__________________________________________________________________
Demander n'est pas bête!

[DMboup]

Tu peux voir dans ce post comment récupérer toutes les tables de la base de données en cour.

Il te suffit ensuite d'adapter la boucle pour supprimer toutes les données de toutes les tables.

[Access_ible]

Bonjour.

Non spécialiste d'Access, voilà comment je procèderait :

Je créerait (soit par les assistants, soit par le code) une requête de suppression d'enregistrement pour chaque table à "vider".

Ensuite, les regrouper sous une macro reliée à un bouton de formulaire.

Ou bien tout écrire en code derrière un bouton de formulaire.
En code pour une table, ça donnerait :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
DoCmd.RunSQL "DELETE MATABLE.UNNOMDECHAMPDEMATABLE
FROM MATABLE;"

Une ligne par table à netoyer

Et voila !

[spaiku]

Bonsoir,

il y a mieux que la solution que tu envisages, c'est-à-dire plus évolutif. Le principe est le suivant : tu écris une boucle qui fait le tour de toutes les tables de ta base, et à chaque fois, tu supprimes les enregistrements. Mais attention, il existe des tables système auxquelles il vaut mieux ne pas toucher. Le mieux est donc de nommer tes tables en commençant par T_ (ex : T_Client, T_Commande, T_Produit, etc.) Dans une fonction, tu peux ensuite écrire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Dim Tbl as TableDef
For Each Tbl in CurrentDb
    If Left(Tbl.Name, 2) = "T_" Then
        Docmd.RunSQL "DELETE FROM " & Tdf.Name & ";"
    End If
Next Tbl

Dans ton premier post, tu demandes "en dehors de Delete From NomTable". Pourquoi ? Cette requête ne supprime pas la table, donc te permet de conserver la structure.

[Pierre Fauconnier]

Bonsoir

Il est vachement préférable "d'oublier" les tables systèmes, et s'appuyer (désolé, spailu) sur les noms des tables qui commencent pas "T" est à mon avis un peu léger.

Les tables systèmes commencent par "MSys"...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub Test()
    Dim MaTable As DAO.TableDef
    Dim sql As String
 
    For Each MaTable In CurrentDb.TableDefs
        If Left(MaTable.Name, 4) <> "MSys" Then
            sql = "delete from " & MaTable.Name
            DoCmd.RunSQL sql
        End If
    Next
End Sub

[francishop]

Bonsoir,

Dans bien des cas on risque de rencontrer quelque soucis avec l'intégrité référentielle.

Il semble préférable de créer une table pour assurer l'ordre de suppression.
D'abord les tables "côté plusieurs" avant les tables "côté un" apparentées.

La table --> zTbl_DeleTout--> deux champs :
__ Ordre --> Numérique
__ NomTable --> Texte

Dans un module :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Public Function SupDansTbl() As Boolean
On Error GoTo Erreur_SupDansTbl
    Dim db As DAO.Database
    Dim rst As DAO.Recordset
     Set db = CurrentDb()
     Set rst = db.OpenRecordset( _
     "zTbl_DeleTout", dbOpenSnapshot)
 
    Do Until rst.EOF
        db.Execute "DELETE * FROM " & rst!NomTable
        rst.MoveNext
    Loop
 
    rst.Close
    Set rst = Nothing
    SupDansTbl = True
ExitHere:
    Exit Function
 
Erreur_SupDansTbl:
    SupDansTbl = False
    MsgBox "Erreur " & Err & ": " & Err.Description, , _
     "SupDansTbl()"
    Resume ExitHere
    Resume
End Function

Cordialement.

[spaiku]

GBAGO : je pense que tu es en de bonnes mains...

Pierre : Merci pour la remarque, c'est vrai que se baser sur le début du nom des tables système est plus cohérent.

[GBAGO]

Je remercie les uns et les autres pour vos réponses!

Vos réponses aideront certainement ceux qui sont dans la même situation que moi.
Je suis toujours ravi que je poste ma demande sur notre excellent site d'entraide!