Discussion :

[jaystas]

Bonjour à tous

je suis à la recherche d'une explication quand à la manière de pouvoir indexer un un bloc de donnée.

je m'explique

je dois pouvoir sauvegarder une valeur analogique dans un db sur une action bien précise.

Mon problème c'est que je ne comprends pas bien l'indexage.

Comment définir un pointeur qui se déplacera dans mon db.

Si quelqu'un avait un réponse ou un exemple hors doc siemens cela m'arrangerait.

merci à vous

[Nono40]

La méthode que j'utilise le plus est avec les registres d'index AR1 (et AR2 en cas de besoin).

AR1 contient le un délalage en nombre de bit. Il permet alers d'indexer des bits, des mots, des octets, etc... La syntaxe est la suivante :

L <zone> [AR1,P#<base>] (pour tout ce qui est octet, mot, etc...)
U <zone> [AR1,P#<base>] (pour la lecture d'un bit )

Zone déifini ce que tu veux inxéder :
M : zone des bits M
MB : zone des octets M
MW : zone des mots M
MD : zone des double mots
MF : zone des flottants

DBX : bit du DB courant
DBB : octet du DB courant
DBW, DBD, DBF...
Remarque : L'utilisation avec AR1 n'étant pas inter-DB il fau se positionner avec AUF sur le DB à accéder.

DIX : bit du DB d'instance courant
DIB : otctet du DB d'instance courant
DIW,DID,DIF...

E : zone des entrées
EB : octet d'entrée
EW,ED

A : idem zone E

PEB : octet de périphérie
PEW,PED...

PAB : idem zone PE

<base> est un décalage constant, en général quand on adresse un tableau c'est le décalage du tableay par rapport au début de la zone. <base> est toujours sous la forme <octet>.<bit>

Exemple :
Dans le DB10 (nommé TEST) tu as les variables suivantes :
MOT1 : INT (Adresse relative 0.0)
MOT2 : INT (Adresse relative 2.0
MOT3 : INT (Adresse relative 4.0)
TABLEAU : ARRAY[0..99] OF INT (Adresse relative 6.0)

Maintenant imagine que MOT2 contient l'index dans TABLEAU de la valeur à écrire et MOT1 la valeur à écrire. En liste tu écrirais

// Lire l'index en nombre de mots
L #TEST.MOT2
// convertir l'index mot en index bit
// C'est un décalage à geiche de 4 position, une multiplication par 16 peut aussi convenir
SLW 4
// Charger le registre d'index
LAR1
// Lire la valeur à stocker
L #TEST.MOT1
// S'assurer de la position du DB par défaut
AUF #TEST
// Stocker la valeur, ici on donne le décalage par rapport au début du tableau
T DBW[AR1,P#6.0]

Autre exemple, voici le code d'une fonction qui retourne un bool VALEUR et prenant comme entrée une adresse de carte CARTE (int) et un numéro de bit BIT (bit)

// Charger l'adresse de la carte
L #CARTE
// Transformer en pointeur de bit
SLW 3
// Ajouter le décalage de bit
L #BIT
+I
// Charger le registre d'index
LAR1
// Lire le bit d'entrée
U E[AR1,P#0.0]
// Retourner la valeur
= VALEUR



Note que venant de PL7, je n'ai jamais compris comment un logiciel comme Step 7 ne permettait pas de faire des choses simples de façon simple. Dans le premier exemple en PL7 on écrirait une seule ligne %MW6[MOT2]:=MO1

[jaystas]

merci merci
je test et je te tiens au courant