Mettre une couleur à une lettre ou à un chiffre

**spico45** · 30/07/2008, 16h51

Bonjour tout le monde,

j'ai un créé un tbaleau de présence et je voudrais que quand je tape "maladie" ou "absence" etc la case se mette d'une couleur. Avec la mise en conditionnelle je ne peux gérer que 3 possibilités et moi j'en ai 5 pour le moment.
J'ai essayer d'enregistrer une macro etca me donner un code hors je ne sais pas le modifier.
Pouvez-vous m'aider Merci

voici le code que ca ma générer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub couleur()
'
' couleur Macro
' Macro enregistrée le 30/07/2008 par
'
 
'
    Selection.FormatConditions.Delete
    Selection.FormatConditions.Add Type:=xlCellValue, Operator:=xlEqual, _
        Formula1:="=""m"""
    Selection.FormatConditions.Interior.ColorIndex = 4
    Selection.FormatConditions.Add Type:=xlCellValue, Operator:=xlEqual, _
        Formula1:="=""abs"""
    Selection.FormatConditions.Interior.ColorIndex = 3
    Selection.FormatConditions.Add Type:=xlCellValue, Operator:=xlEqual, _
        Formula1:="=""at"""
    Selection.FormatConditions.Interior.ColorIndex = 34
End Sub

**Gorfael** · 30/07/2008, 18h43

Salut spico45 et le forum

J'ai essayer d'enregistrer une macro etca

C'est quoi une macro ecta ?

Sur ta feuille, tu mets ta souris sur le nom de l'onglet
Clic-droit => Menu contextuel>>Visualiser le code
tu colles la macro suivante

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub Worksheet_Change(ByVal Target As Range)
Dim Cel As Range
For Each Cel In Target
'pour chaque cellule de la plage modifiée
    Select Case LCase(Cel)
    'mettre en "case" la valeur de la cellule en minuscules
        Case "m"
            Cel.Interior.ColorIndex = 4
        Case "abs"
            Cel.Interior.ColorIndex = 3
        Case "at"
            Cel.Interior.ColorIndex = 34
        Case Else
        'si aucun des cas précédent
            Cel.Interior.ColorIndex = xlNone
            'couleur de fond en automatique
    End Select
Next Cel
End Sub

c'est une macro à lancement automatique
Target contient la/les cellule(s) ayant été modifiées.
Comme tu testes la valeur de la cellule, et que tu peux faire un copier/coller, tu es obligé de tester une cellule à la fois, d'où la boucle.

Ce n'est pas une MFC. tu changes la couleur du fond. donc, il faut prévoir une remise à blanc de ta cellule.
l'Inconvénient majeur d'une telle macro est que quelque soit la cellule qui passe en mode édition (quand tu entres dans le contenue de la cellule, en modifiant ou non, par double-clic ou modification dans la barre de formule ou F2), le fond repasse en blanc. Pour éviter ça, il suffit de définir la plage où doit travailler cette macro.
A+