Discussion :

[PhYx]

bonjour,
je cherche à donner un ordre précis aux colonnes d'un tableau croisé mais cet ordre suit une logique au niveau du sens des variables et non pas au niveau des valeurs ou de l'ordre alphabétique (le but est de d'intégrer le tableau dans un rapport), il faudrait donc que je le définisse à la main (je pense)

que me conseillez vous ? est ce possible avec un proc template ?
ou bien une option de order by que je ne connais pas ?

[PhYx]

je modifie un peu ma question car je viens de voir que la proc template ne fonctionnait pas avec les tableau croisés de freq

que me conseiller vous pour faire du reporting avec mes tableaux croisés ?
sachant que l etude est déja faite avec des procs freq, j'ai moyennement envie de la refaire avec report, d'autant plus que je ne maitrise pas du tout cette procédure.

[olivier.decourt]

Effectivement, rien à attendre de la proc Template dans l'immédiat.
Je te propose un contournement qui joue sur ORDER=DATA : l'ordre des colonnes et des lignes est l'ordre dans lequel SAS trouve les valeurs dans les données.
Il faut donc créer une variable à l'avance qui prend des valeurs dans l'ordre qui t'arrange, puis trier selon cette variable, et c'est fini.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 
DATA work.ventes ;
	SET sashelp.prdsale ;
	SELECT (country) ;
		WHEN("U.S.A.") order1 = 1 ;
		WHEN("CANADA") order1 = 2 ;
		OTHERWISE	   order1 = 3 ;
	END ;
	SELECT (product) ;
		WHEN("DESK")  order2 = 1 ;
		WHEN("CHAIR") order2 = 2 ;
		WHEN("BED")   order2 = 3 ;
		WHEN("SOFA")  order2 = 4 ;
		OTHERWISE     order2 = 5 ;
	END ;
RUN ;
PROC SORT DATA = work.ventes ;
	BY order2 order1 ;
RUN ;
PROC FREQ DATA = work.ventes ORDER = DATA ;
	TABLE product * country / FORMAT = NLNUM12.2 ;
	WEIGHT actual ;
RUN ;

Est-ce que ça te convient ?
Olivier