Supprimer les macros par une macro

**fring** · 15/06/2008, 18h50

Supprimer tout : Modules, UserForms, procédures contenues dans ThisWorkbook et dans les feuilles (la procédure de suppression sera elle même supprimée)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub Supprimer_toutes_macros()
Dim VBC As Object
 
With ActiveWorkbook.VBProject
    For Each VBC In .VBComponents
        If VBC.Type = 100 Then
            With VBC.CodeModule
                .DeleteLines 1, .CountOfLines
                .CodePane.Window.Close
            End With
        Else
            .VBComponents.Remove VBC
        End If
    Next VBC
End With
 
End Sub

Supprimer toutes les procédures contenues dans une feuille

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub Supprimer_Code_Feuille()
Dim NomFeuille As String
 
NomFeuille = "Feuil1"
 
With ActiveWorkbook.VBProject.VBComponents _
(ActiveWorkbook.Sheets(NomFeuille).CodeName).CodeModule
    .DeleteLines 1, .CountOfLines
    .CodePane.Window.Close
End With
 
End Sub

Supprimer toutes les procédures contenues dans ThisWorkbook

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub Supprimer_Code_ThisWorbook()
 
With ActiveWorkbook.VBProject.VBComponents("ThisWorkbook").CodeModule
    .DeleteLines 1, .CountOfLines
    .CodePane.Window.Close
End With
 
End Sub

Supprimer un UserForm

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Supprimer_UserForm()
Dim USF As String
 
USF = "UserForm1"
 
ActiveWorkbook.VBProject.VBComponents.Remove _
    ActiveWorkbook.VBProject.VBComponents(USF)
 
End Sub

Supprimer un Module

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Supprimer_Module()
Dim NomMod As String
 
NomMod = "Module3"
 
ActiveWorkbook.VBProject.VBComponents.Remove _
    ActiveWorkbook.VBProject.VBComponents(NomMod)
 
End Sub

Supprimer une Macro bien précise dans un Module

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub Supprimer_Macro_Precise()
Dim Debut As Integer, Lignes As Integer
Dim NomMod As String, NomMacro As String
 
NomMod = "Module3"
NomMacro = "Macro1"
 
With ThisWorkbook.VBProject.VBComponents(NomMod).CodeModule
    Debut = .ProcStartLine(NomMacro, 0)
    Lignes = .ProcCountLines(NomMacro, 0)
    .DeleteLines Debut, Lignes
End With
 
End Sub

Supprimer tous les boutons dans toutes les feuilles

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub Supprimer_Boutons()
Dim Obj As OLEObject, X As Integer
 
For X = 1 To Sheets.Count
    For Each Obj In Worksheets(X).OLEObjects
        If TypeOf Obj.Object Is MSForms.CommandButton Then Obj.Delete
    Next Obj
Next X
 
End Sub

**androginius** · 29/07/2008, 22h40

Ben merci 100000 fois!!

Je me prenais le choux à essayer de faire pareil, et tout est là!!

SUPER

A +

**patricktoulon** · 06/09/2013, 16h12

bonjour fring
exemplaire preci tout y est ,c'est nickel

petite macro bien utile
peut etre en faire un complement afin de le rendre universel et de l'avoir a disponibilité dans n'importe quel fichier en activant le reference de ce complement

Au plaisir

**Vincent32** · 14/04/2016, 19h22

Merci pour ces informations.

Une petite question cependant si je veux supprimer toutes les macro contenues dans Feuil1 sauf une bien précise. Comment boucler sur les noms de macro ?

Merci de votre aide

Belle soirée à vous

**kiki29** · 14/04/2016, 21h55

Salut, tu as aussi ceci : Visual Basic Editor

**Vincent32** · 15/04/2016, 09h07

Merci Kiki pour ta réponse. Cependant les exemples du tuto n'étant pas suffisamment documentés pour un débutant (je suis parti de 0 seul (je ne suis programmeur ni informaticien) et je suis quasi autonome aujourd'hui) je maintien ma question : Comment boucler sur les noms de macro de la feuille 1 : je pensais faire un :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
for each sub In ThisWorkbook.VBProject.VBComponents("Feuil1").CodeModule
 
if nom sub <> "Private Sub Worksheet_Change(ByVal Target As Range)" then
sub.delete
end if
 
next sub

avec sub les différentes macro contenues dans la feuille 1 et sub.delete correspond je pense à :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
With ThisWorkbook.VBProject.VBComponents("Feuil1").CodeModule
                    .DeleteLines 1, .CountOfLines
                    .CodePane.Window.Close
                End With

Mais je suis trop imprécis et je ne comprends pas suffisamment le code pour être efficace et rendre la macro fonctionnelle.

Merci de votre aide

**kiki29** · 15/04/2016, 12h39

Salut, par exemple tu as : Comment lister le nom de toutes les procédures contenues dans un classeur ?. Avec le lien donné plus haut, tu as toutes les infos.
A titre documentaire : Pearson

**kiki29** · 16/04/2016, 14h11

Salut, tu as tourné autour, il te suffisait d'aller voir VBE , en y ajoutant une gestion d'erreurs basique, l'exemple y est quasiment tel quel.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Option Explicit
 
Sub Test()
Dim Wb As Workbook
    Set Wb = Workbooks("Classeur1.xls") 'ThisWorkbook
    SupprimerMacroPrecise Wb, "Feuil1", "Worksheet_Change"
End Sub
 
Private Sub SupprimerMacroPrecise(Wb As Workbook, Mdl As String, NomMacro As String)
Dim Debut As Long, Lignes As Long
    On Error GoTo erreurs
    With Wb.VBProject.VBComponents(Mdl).CodeModule
        Debut = .ProcStartLine(NomMacro, 0)
        Lignes = .ProcCountLines(NomMacro, 0)
        .DeleteLines Debut, Lignes
    End With
retour:
    Exit Sub
 
erreurs:
    If Err.Number = 35 Then
        MsgBox "Procédure inexistante"
    Else
        MsgBox Err.Number & vbCrLf & Err.Description
    End If
    GoTo retour
End Sub

**Vincent32** · 17/04/2016, 17h27

J'y suis arrivé (supprimer toutes les macros dont le nom de la sub contient "Sub Btn_" )

Donc j'ai testé chaque ligne et voilà le travail :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Dim Last as currency, Lig as currency
 
Last = ThisWorkbook.VBProject.VBComponents("Feuil1").CodeModule.CountOfLines
 
    For Lig = 1 To Last Step 1
        If ThisWorkbook.VBProject.VBComponents("Feuil1").CodeModule.Lines(Lig, 1) Like "Sub Btn_*" Then
            Last = Last - Lig
            ThisWorkbook.VBProject.VBComponents("Feuil1").CodeModule.DeleteLines Lig, Last
        End If
    Next Lig

Merci Kiki de ton aide qui m'a orienté dans la bonne direction.

**leblesois** · 29/01/2019, 19h46

Bonjour,

chez moi (excel 2016) cela ne fonctionne pas, j'ai un message :

"La méthode 'VBProject' de l'objet _Workbook' a échoué"

Je suppose qu'il faut effectivement coché quelque chose dans "Outils/Références", mais quoi ?

Merci d'avance

Envoyé par patricktoulon

bonjour fring
exemplaire preci tout y est ,c'est nickel

petite macro bien utile
peut etre en faire un complement afin de le rendre universel et de l'avoir a disponibilité dans n'importe quel fichier en activant le reference de ce complement

Au plaisir

**tototiti2008** · 01/02/2019, 20h58

Bonjour,

leblesois,
Les codes qui manipulent le code doivent avoir une option de sécurité cochée
Onglet Développeur - Groupe Code
Sécurité des macros
Cocher Accès approuvé au modèle d'objet du projet VBA
OK
Quitter puis relancer Excel

**leblesois** · 02/02/2019, 12h36

Super ! Cela fonctionne parfaitement.

Ou pourrais-je trouver sur ce site (ou sur un autre) ce genre d'information et également sur les fonctionnalités possibles après avoir coché telle ou telle case dans outils / Références ?

Merci !

Envoyé par tototiti2008

Bonjour,

leblesois,
Les codes qui manipulent le code doivent avoir une option de sécurité cochée
Onglet Développeur - Groupe Code
Sécurité des macros
Cocher Accès approuvé au modèle d'objet du projet VBA
OK
Quitter puis relancer Excel

**leblesois** · 02/02/2019, 12h48

C'est encore moi !

Existe-t-il un code VBA permettant de vérifier si cette case est cochée ?

Merci d'avance !

Envoyé par tototiti2008

Bonjour,

leblesois,
Les codes qui manipulent le code doivent avoir une option de sécurité cochée
Onglet Développeur - Groupe Code
Sécurité des macros
Cocher Accès approuvé au modèle d'objet du projet VBA
OK
Quitter puis relancer Excel

**tototiti2008** · 04/02/2019, 22h04

Ou pourrais-je trouver sur ce site (ou sur un autre) ce genre d'information et également sur les fonctionnalités possibles après avoir coché telle ou telle case dans outils / Références ?

Outils - Références te permet d'accéder à des objets supplémentaires offrant des fonctionnalités supplémentaires
Je ne connais pas de liste de toutes les références, celles-ci pouvant être dépendantes des programmes installés sur ton ordinateur
Certaines références (ou objets de contrôles supplémentaires) sont décrits dans des articles ici, et je ne prétend pas tout connaître

https://silkyroad.developpez.com/VBA/VisualBasicEditor/

Existe-t-il un code VBA permettant de vérifier si cette case est cochée ?

Je ne jurerais pas, mais ça m'étonnerais

Edit : sauf à essayer d'accéder à VBProject et faire une gestion d'erreurs, peut-être

**leblesois** · 08/02/2019, 12h23

Merci pour ta réponse !

petit correctif : Un grand merci pour ta réponse et le lien. Je viens de le lire, c génial ! J'ai appris plein de trucs grace à toi TOTOTITI

**Pascal loria** · 13/02/2020, 11h01

Merci pour ce post qui m'a beaucoup aider

**Patrice740** · 06/03/2020, 14h54

Envoyé par tototiti2008

Edit : sauf à essayer d'accéder à VBProject et faire une gestion d'erreurs, peut-être

C'est ce que fais habituellement, par Exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Sub TestAccesProjetVBA()
'
Dim Ok As Boolean
  On Error GoTo ErrorHandler
  Ok = Application.VBE.MainWindow.Visible
  On Error GoTo 0
 
Exit Sub
 
ErrorHandler:
'------------
Select Case Err.Description
  Case "L'accès par programme au projet Visual Basic n'est pas fiable" & vbLf
    Msg = "Erreur " & Err.Number & " : " & Err.Description & vbCr & vbCr
    Msg = Msg & "Pour autoriser l'accès au projet Visual Basic : " & vbCr
    Msg = Msg & "- Fichier puis Options ;" & vbCr
    Msg = Msg & "- Centre de gestion de la confidentialité ;" & vbCr
    Msg = Msg & "- Paramètres du centre de gestion de la confidentialité ;" & vbCr
    Msg = Msg & "- Paramètres des macros ;" & vbCr
    Msg = Msg & "- Cocher la case : " & vbCr & _
                "   « Accès approuvé au modèle d'objet du projet VBA » ;" & vbCr
    Msg = Msg & "- Valider ce choix par Ok (2 fois)." & vbCr & vbCr
    Msg = Msg & "- Fermer Excel et réouvrir " & ThisWorkbook.Name
    MsgBox Msg, vbCritical
    End
  Case Else
    MsgBox Err.Description, vbCritical
    End
End Select
 
End Sub

**Pierre Fauconnier** · 10/04/2020, 20h21

Salut.

Avec une bonne architecture, ça n'a pas de sens de devoir modifier du code par du code. Qui plus est, il ne peut fonctionner que sur un poste avec "la bonne case cochée"... Les plus futés comprendront pourquoi on ne peut pas cocher cette case par code (enfin j'espère). Dans les faits, c'est une ineptie.

Supprimer les macros par une macro

VBA

Discussions similaires

Partager

Partager