Discussion :

[nanot]

Bonjour,

J'ai un fichier qui comporte dans premier onglet "données" 2 colonnes. En colonne A, les numréférence et en colonne B, la catégorie concerné de la référence.

Je voudrais à partir de ce onglet "données", copier le numréférence ainsi que sa catégorie dans l'onglet approprié.

Merci d'avance pour vos réponses.

Vous trouverez en pièce jointe une ebauche du fichier Excel

[fring]

Bonjour,

Ci-dessous une proposition

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub test()
Dim i As Integer, j As Integer, x As Integer, Er As String
x = Sheets.Count
Er = ""
 
With Sheets("Données")
    For i = 2 To .Cells(Rows.Count, 1).End(xlUp).Row
        If .Cells(i, 3) <> "X" Then
            For j = 2 To x
                If .Cells(i, 2) = UCase(Sheets(j).Name) Then
                    .Range(.Cells(i, 1), .Cells(i, 2)).Copy Sheets(j).Cells(Rows.Count, 1).End(xlUp)(2)
                    .Cells(i, 3) = "X"
                    Exit For
                End If
            Next j
        End If
        If .Cells(i, 3) <> "X" Then Er = Er & Chr(10) & .Cells(i, 1) & "/" & .Cells(i, 2)
    Next i
End With
 
If Er <> "" Then
    MsgBox "les articles suivants n'ont pas été copié :" & Chr(10) & Er
Else
    MsgBox "tous les articles ont été copié"
End If
 
End Sub

Lorsqu'un article de la base de donnée est copié dans son onglet respectif, un "X" est ajouté dans la 3ème colonne ce qui permettra d'utiliser le code plusieurs fois en ne copiant qu'une seule fois chaque article.

Si un article ne correspond à aucun onglet, celui-ci ne sera donc pas copié et un message le signalera en fin de procédure.