Discussion :

[yos]

Salut tout le monde,
Ce code me permet de filtrer des source xhtml pour récupérer la partie qui m'intérèsse

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
<xsl:template match="//body//table[3]">
  <xsl:copy-of select="."/>
</xsl:template>

Problème, je dois effectuer un translate dans les valeurs d'attributs <img src="nom.txt"> en <img src="nom.jpg">
j'essay avec

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
<xsl:template match="//body//table[3]">
  <xsl:copy-of select="*[translate(@*, '.txt', '.jpg')]"/>
</xsl:template>

sans résultat
en plus je dois éliminer du résultat tout les <a href...>
quelque chose du genre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
<xsl:template match="//body//table[3]">
  <xsl:copy-of select="*[translate(@*, '.txt', '.jpg')][not(a)]"/>
</xsl:template>

merci pour votre aide

[GrandFather]

Bonjour,

pour réussir l'écriture de tes expressions XPath, il est important de bien comprendre la chose suivante : Les expressions entre crochets ne servent pas à faire des opérations sur des noeuds mais sont des prédicats. Les prédicats servent à filtrer des éléments parmi ceux sélectionnés dans l'expression XPath qui les précèdent. Le prédicat est évalué pour chaque noeud de la sélection, et si l'expression qui le compose renvoie true, le noeud est conservé, sinon il est filtré.

Exemples de requêtes XPath avec ou sans prédicats :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

//table

Sélectionne tous les éléments table de la source XML

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

//table[@class = 'liste']

Ne sélectionne que les éléments table qui ont un attribut class qui contient la valeur 'liste'

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

//table[starts-with(@class, 'l')]

Ne sélectionne que les éléments table qui ont un attribut class dont la valeur commence par un 'l' (starts-with renvoie un booléen)

Quand le prédicat ne contient qu'un chiffre k, alors l'expression XPath ne renvoie que le k-ième noeud de la sélection ; ce type particulier de prédicat est un raccourci pour le prédicat [position() = k], et peut être associé à un autre prédicat. Par exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

//table[@class='liste'][4]

Ne sélectionne que le quatrième élément parmi les éléments table ayant un attribut class avec une valeur égale à 'liste'

Attention à l'ordre des prédicats, il ne faut pas confondre avec :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

//table[4][@class='liste']

sélectionne la quatrième table de la source XML uniquement s'il a un attribut class avec la valeur 'liste'

[yos]

merci Grand-Father pour ta réponse
effectivement les crochets servent de prédicats
une erreur de ma part dans le

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

<xsl:copy-of select="*[translate(@*, '.txt', '.jpg')]"/>

mais comment faire pour le translate
merci pour ton aide

[GrandFather]

Le translate ne convient pas, cette fonction ne travaille qu'au niveau caractère, pas de la chaîne. Il vaut mieux utiliser substring-before(). Comme tu dois faire un traitement sur certaines balises avant de les recopier, le <xsl:copy-of> ne convient pas pour ton problème. Il faut créer un template "général" qui se charge de recopier tel quel les balises sans modifications, et des templates pour chaque cas particulier qui nécessite une transformation. Ca donne grosso modo ceci (à toi d'adapter à ton cas) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
 
	<xsl:template match="/">
		...
		<xsl:apply-templates select="//body//table[3]"/>
		...
	</xsl:template>
 
	<xsl:template match="*">
		<xsl:copy>
			<xsl:copy-of select="@*"/>
			<xsl:apply-templates/>
		</xsl:copy>
	</xsl:template>
 
	<xsl:template match="img">
		<img src="{concat(substring-before(@src, '.'), '.jpg')}">
			<xsl:apply-templates/>
		</img>
	</xsl:template>
 
	<xsl:template match="a"/>
 
 
</xsl:stylesheet>

[yos]

Merci Grand-father C ok