Discussion :

[alaingui]

Bonjor

tentant de convertir quelques lignes en ADO je n'arrive pas à passer un paramètre ?

voici mes lignes de codes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
 
Set DB = New ADODB.Connection
With DB
  .provider = "Microsoft.JET.OLEDB.4.0"
  .ConnectionString = chemin_base + nom_base
  .ConnectionTimeout = 6
  .CommandTimeout = 60
  .Open
End With
 
    Set rst = New ADODB.Recordset
    rst.CursorLocation = adUseClient
    rst.ActiveConnection = DB
 
    sql_rec = "req1"   'nom de la requete
 
    rst.Open sql_rec, , adOpenStatic, adLockReadOnly, adCmdTable

j'ai une erreur d'exécution sur le open car aucune données pour un ou plusieurs paramètres requis ....
Ma requete req1 neccessite un paramètre (cle) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
PARAMETERS cle Byte;
SELECT Table1.Nom, Table1.LSP FROM Table1
GROUP BY Table1.Nom, Table1.LSP HAVING (((Table1.LSP)=[cle]));

Comment faire pour le définir dans le code VBA?

merci d'avance

[wape]

Bonjour,

Essaye ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Set db = New ADODB.Connection
With db
  .Provider = "Microsoft.JET.OLEDB.4.0"
  .ConnectionString = chemin_base + nom_base
  .ConnectionTimeout = 6
  .CommandTimeout = 60
  .Open
End With
 
Set cmd = New ADODB.Command
 
With cmd
   .ActiveConnection = db
   .CommandText = "req1" '<-- "req1" = nom de la requête
   Set rst = .Execute(, 1) '<-- 1 = valeur du paramètre
End With
 
Do While Not rst.EOF
   MsgBox rst("nom").Value & " " & rst("LSP").Value
   rst.MoveNext
Loop
 
rst.Close
 
Set rst = Nothing
Set cmd = Nothing

wape

[alaingui]

merci cela fonctionne très bien

j'ai un autre soucis a cause d'une fonction dans Access mais je vais ouvrir un autre post