Discussion :

[ouskel'n'or]

Maintenant que j'ai, grâce à Bigalo,

=ADRESSE(LIGNE(Q3) + EQUIV(GRANDE.VALEUR(Q3:Q445;1);Q3:Q445;0) - 1;14)

je voudrais en fait la valeur correspondant à l'adresse que j'obtiens ainsi (qui est une valeur placée dans une autre cellule)
Par avance, merci

[Mytå_Qc]

Salut ouskel'n'or et le forum

Tu veux récupérer la valeur de la cellule.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDIRECT(ADRESSE(LIGNE(Q3) + EQUIV(GRANDE.VALEUR(Q3:Q445;1);Q3:Q445;0) - 1;14) )

Mytå_Qc

[Bigalo]

Bonsoir,

Le dernier argument, "14", de la formule que je t'ai indiquée, et que tu as adaptée,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=ADRESSE(LIGNE(Q3) + EQUIV(GRANDE.VALEUR(Q3:Q445;1);Q3:Q445;0) - 1;14)

correspond à la colonne "N" (14ème lettre de l'alphabet, alors que GRANDE.VALEUR() se référait à la colonne "Q".

Dans ton adaptation, tu as commis une imprudence : ce "14" risque de déclencher de mauvaise surprises par la suite en cas d'insertion ou de suppression de colonne(s) : en effet, les données risquent alors de ne plus être en colonne 14, mais la formule continuera à s'y référer et renverra alors un résultat incorrect.

Il est vivement déconseillé d'employer directement une valeur numérique dans une formule : en cas d'erreur, elle est difficile à repérer, et certaines adaptations en principe automatiques dans un tableur ne fonctionnent plus, comme nous l'avons vu en cas d'insertion ou suppression de cellules.

C'est pourquoi il vaudrait mieux utiliser :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=ADRESSE(LIGNE(Q3) + EQUIV(GRANDE.VALEUR(Q3:Q445;1);Q3:Q445;0) - 1;COLONNE(N1))

En outre, cette formule est plus lisible, car les gens ne savent en général pas par cœur quelle est la quatorzième lettre de l'alphabet.

Il s'agit de la cellule en colonne N située sur la même ligne que la plus grande valeur de la plage Q3:Q445 (GRANDE.VALEUR(Q3:Q445;1)).

Je te propose 3 options :

Si la formule est dans la cellule A1 (à adapter) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDIRECT(A1)

Si tu veux éviter la formule intermédiaire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDIRECT(ADRESSE(LIGNE(Q3) + EQUIV(GRANDE.VALEUR(Q3:Q445;1);Q3:Q445;0) - 1;14))

Ou avec une autre approche :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDEX(DECALER(Q3:Q445;0;-3);EQUIV(GRANDE.VALEUR(Q3:Q445;1);Q3:Q445;0))

NB - DECALER(Q3:Q445;0;-3) fait référence à la plage située 3 colonnes avant Q3:Q445, sur les mêmes lignes.

Tu peux simplifier les 2 formules les plus longues en définissant un nom, "Réf" par exemple.

La dernière formule devient :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDEX(DECALER(Réf;0;-3);EQUIV(GRANDE.VALEUR(Réf;1);Réf;0))

Cordialement,

Michel Gaboly

Maintenant que j'ai, grâce à Bigalo,
je voudrais en fait la valeur correspondant à l'adresse que j'obtiens ainsi (qui est une valeur placée dans une autre cellule)
Par avance, merci

[ouskel'n'or]

Merci Mytå_Qc et une nouvelle fois merci, Bigalo pour tes explications, vous me sortez d'affaire.
Je ne travaille jamais avec Excel, seulement avec VBA. Mais je sens que je vais venir plus souvent
En fait je fais un test unique, pas de risque qu'une colonne soit supprimée. Je connaissais Decaler mais n'ai pas pensé à l'utiliser.
Tout ça va passer en VBA plus tard. Mais je voulais m'assurer de certains résultats avant de me lancer.
Encore merci, je crois que pour ce soir c'est terminé.
Bonne nuit

[Bigalo]

De rien, c'était un plaisir

N'hésite surtout pas à poser des questions sur Excel. Mieux on maîtrise le produit associé (Excel en l’occurrence), plus on est efficace avec VBA, car on peut exploiter directement les possibilités de l’application sans devoir écrire du code pour des choses disponibles.

En ce qui me concerne je suis directement concerné, car il m’arrive de manipuler Access, que je ne connais pas assez, par VBA à partir d’Excel.

Si je connaissais mieux Access, mon code serait plus efficace !

Cordialement,

Michel Gaboly

Merci Mytå_Qc et une nouvelle fois merci, Bigalo pour tes explications, vous me sortez d'affaire.
Je ne travaille jamais avec Excel, seulement avec VBA. Mais je sens que je vais venir plus souvent
En fait je fais un test unique, pas de risque qu'une colonne soit supprimée. Je connaissais Decaler mais n'ai pas pensé à l'utiliser.
Tout ça va passer en VBA plus tard. Mais je voulais m'assurer de certains résultats avant de me lancer.
Encore merci, je crois que pour ce soir c'est terminé.
Bonne nuit