Discussion :

[gbuxo]

Bonjour,
Je souhaiterais, depuis une procédure VBA Access, premièrement sélectionner une cellule (C1), puis Activer le menu "Données...Actualiser les données".
J'ai fais des recherches sur le Net, les Forums, mais rien.....
Je peux ouvrir un fichier, ecrire dans une cellule, effacer une cellule........
mais pas actionner un menu.
J'ai essayé avec CommandBar, mais rien......
Bien sur le fichier Excel est ouvert et actif.....
(Je suis en Access 97)
Merci d'avance
A+

[Jean-Philippe André]

bonjour
je te conseille de passer par le macro recorder
Outils>macro>nouvelle macro
tu récupères le code d'excel, tu pourras l'utiliser depuis access

[gbuxo]

Salut,
j'ai essayé l'enregistreur de macro...
Celà me fournit deux commandes :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 xlW.ActiveSheet.PivotTables("TCD1").PivotSelect "", xlDataAndLabel
 xlW.ActiveSheet.PivotTables("TCD1").RefreshTable

(xlW est ma variable classeur)
Malheureusement ce code provoque des erreurs dans le style "commandes non reconnues"
Pour exemples si j'applique

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

xlW.Sheets(onglet).Range("A1:C100").ClearContents

pour effacer une plage, celà fonctionne correctement.
A+

[Invité]

Bonjour

Dans ton code tu réalises l'opération sur la feuille active. Essaye de la faire en nommant la feuille.

[gbuxo]

Salut,
milles excuses pour les cotes, un copier/coller trop rapide.
Je donne le code complet, ce sera plus clair....

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Private Sub Commande105_Click()
Dim FichierExcel As String
FichierExcel = "C:\Projet\HistoTableaux.xls"
Call Exportation("DS4", FichierExcel, "Histo")
End Sub
 
 
Public Sub Exportation(requete As String, fichier As String, onglet As String)
 Dim xlA As Object, xlW As Object, t As DAO.Recordset
 Dim s As String, NumChamp As Long, ligne As Long
 
 Set xlA = CreateObject("excel.application")    'lance Excel
 xlA.Visible = True
 xlA.WorkBooks.Open (fichier)       'ouvre le fichier
 Set xlW = xlA.ActiveWorkBook
 xlW.Sheets(onglet).Range("A2:E100").ClearContents
 ligne = 1
 Set t = CurrentDb.OpenRecordset(requete)    'ouvre la requete
  Do Until t.EOF
   ligne = ligne + 1            'ligne suivante dans la feuille Excel
   For NumChamp = 0 To 4        'pour chaque colonne de la requete
    xlW.Sheets(onglet).cells(ligne, NumChamp + 1) = t(NumChamp) 'ecriture dans la cellule
   Next NumChamp
  t.MoveNext                    'enregistrement suivant
  Loop
 t.Close
 xlW.Sheets(onglet).ActiveSheet.PivotTables("TCD1").PivotSelect "", "xlDataAndLabel"
 xlW.Sheets(onglet).ActiveSheet.PivotTables("TCD1").RefreshTable
 xlW.Save
 xlA.Quit
 Set xlA = Nothing    ' puis libère la référence.
End Sub

Je pense que pour sélectionner le tableau, il faut que la feuille soit Active.
De plus je ne trouve aucune aide sur "ActiveSheet" ou "PivotSelect" que ce soit en VBA Access ou en VBA Excel...
Je bloque toujours au niveau de la ligne "PivotSelect" avec comme erreur :
"Arguments non reconnus"....en revanche l'exportation de la table (requete) se fait sans problème...
A+

[Invité]

Bonjour

ici :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
xlW.Sheets(onglet).ActiveSheet.PivotTables("TCD1").PivotSelect "", "xlDataAndLabel"
 xlW.Sheets(onglet).ActiveSheet.PivotTables("TCD1").RefreshTable

Enlève le ActiveSheet pour voir.

[gbuxo]

Bonjour,
J'ai retiré ActiveSheet, j'ai un message :
"Argument non valable".
Je pense que celà vient de "xlDataAndLabel", car lorsque je retire les guillemets, j'ai : "Variable non déclarée"
Vu la pauvreté de l'aide, je ne vois pas quelle valeur lui donner (ce doit être un Integer ou un Long...)
Merci
A+

[Invité]

Re

As-tu déclaré la réference Excel ?

Si ce n'est pas le cas, soit tu la déclares, soit tu crées une constante xlDataAndLabel à laquelle tu affectes sa valeur, tu la trouveras dans l'explorateur d'objet (F2) d'Excel.

Edit :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Public Const xlDataAndLabel As Long = 0

[gbuxo]

Grands merci pour ces conseils éclairés.....
Cela fonctionne d'une manière impécable.
A+

[Invité]

Tant mieux

Une petite explication s'impose.

Comme tu ne références pas Excel, Access ne peut trouver les constantes Excel, il faut donc les redéclarer à chaque fois.

Si tu avais référencé Excel, tu n'aurais pas eut le soucis.

L'avantage de ne pas référencé est que tu n'es plus embêté avec les versions d'Excel.