Excel / Word / PDF avec Adobe Acrobat Pro et PDFCreator 1.7.3 (obsolète)

**Flodu31** · 02/11/2015, 17h02

Bonjour Kiki,

Merci pour tes didacticiels explicites, et désolé de remonter un si vieux post.. mais je n'ai pas trouvé plus proche de mon problème.
Je cherche donc à partir d'une macro excel VBA à :
- trouver un mot dans un fichier pdf
- et à ouvrir ce pdf à la page correspondante au mot recherché.

En appliquant ton bout de code, j'obtiens bien à iTrouvé -1 si le mot est trouvé et 0 le cas échéant.
En revanche, le fichier pdf s'ouvre toujours à la première page.
Saurais tu m'aiguiller?

Merci par avance,

Bien à toi

Envoyé par kiki29

Rechercher un mot dans un fichier PDF via Acrobat

Ajouter un bouton et l'affecter à la procédure SelFichier

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
Option Explicit
 
Sub SelFichier()
Dim Fichier As Variant
Dim sMot As String
 
    ChDir ThisWorkbook.Path
 
    ' Mot à rechercher
    sMot = "Investments"
 
    Fichier = Application.GetOpenFilename("Fichier PDF (*.pdf), *.pdf")
    If Fichier <> False Then AcrobatFindText Fichier, sMot
End Sub
 
Private Sub AcrobatFindText(ByVal sFichier As String, ByVal sRch As String)
Dim oApp As Object
Dim oAvDoc As Object
Dim iTrouvé As Integer
 
    Set oApp = CreateObject("AcroExch.App")
    oApp.Hide
 
    Set oAvDoc = CreateObject("AcroExch.AVDoc")
 
    If oAvDoc.Open(sFichier, "") Then
        If Len(sRch) > 0 Then
            '   Parametres FindText
            '       StringToSearchFor ,
            '       caseSensitive (1 Or 0),
            '       WholeWords(1 Or 0),
            '       ResetSearchToBeginOfDocument (1 Or 0)
 
            '   Rencoie -1 si Trouvé, 0 autrement
            iTrouvé = oAvDoc.FindText(sRch, True, False, True)
        Else
            oAvDoc.Close (1)
            Set oAvDoc = Nothing
            Set oApp = Nothing
            Exit Sub
        End If
    End If
 
    oApp.Show
    oAvDoc.BringToFront
 
    Set oAvDoc = Nothing
    Set oApp = Nothing
End Sub

Rechercher un mot dans un fichier PDF via Internet Explorer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
Option Explicit
 
Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
 
Sub SelFichier()
Dim FD As FileDialog, sStr As String
 
    Set FD = Application.FileDialog(msoFileDialogFilePicker)
    With FD
        .InitialFileName = ThisWorkbook.Path
        .AllowMultiSelect = False
        .Filters.Clear
        .Filters.Add "PDF", "*.pdf", 1
        .ButtonName = "Ouvrir fichier"
        .Title = "Sélectionner un fichier PDF"
    End With
 
    If FD.Show = True Then
        DoEvents
       ' Mot à rechercher
        sStr = "Investments"
        RchMot_PDF_IExplorer FD.SelectedItems(1), sStr
    End If
 
    Set FD = Nothing
End Sub
 
Private Sub RchMot_PDF_IExplorer(sFichier As String, sMot As String)
Dim IE As Object
 
    Set IE = CreateObject("InternetExplorer.Application")
 
    IE.Navigate sFichier
    IE.Visible = True
 
    ' Attente de la fin du chargement
    Do Until IE.ReadyState = 4
        DoEvents
    Loop
 
    SendKeys "^f", True
    Sleep 250
    SendKeys sMot, True
    Sleep 100
    SendKeys "{ENTER}"
 
    Set IE = Nothing
End Sub

**kiki29** · 03/11/2015, 02h11

Salut, désolé mais je ne rencontre aucun problème de ce genre ( ni autre d'ailleurs ) même avec ~~le Reader 11.0.13~~ Acrobat DC 15 sous W10.

Tu pourrais voir ici, une autre façon plus exhaustive de procéder.

il y a aussi cette Liste des contributions et téléchargements pour faciliter la navigation dans le bazar.

**Flodu31** · 03/11/2015, 17h29

Merci pour ton retour.
Je vais parcourir tout ça.
Après j'utilise Adobe Acrobat XI, cela peut-il avoir une influence quelconque ?
Peut-on forcer l'ouverture via Reader (j'ai les 2).

Thanks !

**kiki29** · 04/11/2015, 00h01

Salut, ici cela fonctionne avec Acrobat DC 15.6. Excuse moi ( j'avais oublié ) mais le code fait appel à Acrobat ( pas au Reader )
Dans le post 144, c'est le Reader qui est utilisé.

**davido84** · 04/11/2015, 13h38

Salut Philippe,
ci-joint une version compatible avec Adobe Acrobat Reader DC (version 15).
A+

**Flodu31** · 04/11/2015, 16h19

Hello,
Une question supplémentaire que je me pose.
Dans le code que tu présentes kiki, la partie où tu réalises le FindText, cela renvoie une valeur -1/0 si le nom est trouvé ou non.
En revanche, je ne parviens pas à voir quelle partie du code te renvoie le numéro de page associé.

Dans mon cas, on dirait que la recherche s'effectue, il trouve (ou pas) et continue jusqu'à retomber sur la page initiale.
Donc quand on fait oApp.Show et oAVDoc.BringToFront ça affiche la page 1 (soit indice 0).

Je me trompe dans l'analyse? ou le fonctionnement du code?

**Flodu31** · 04/11/2015, 16h43

J'ai trouvé une méthode qui passe par des objets Java, utilise pour ne chercher qu'un seul mot
http://www.myengineeringworld.net/20...rough-vba.html

Ca fonctionne pour le coup, mais je ne m'explique toujours pas pourquoi l'autre méthode ne marche pas.

Du coup, je profite de l'occasion pour poser une autre question:
- Est-il possible de repérer la position d'un mot dans la page? Du style, est ce que le mot est dans la moitié droite du document, ou dans la moitié gauche? Ou bien est ce totalement illusoire ^^

**kiki29** · 05/11/2015, 00h10

@David, salut et merci, cela ne manquera pas de servir.

@Flodu31, ne reproduisant pas ici le problème que tu recontres difficile de répondre,
Autrement via le post 112 Acrobat Exécution d'un code JavaScript

L'exemple n°3 repris de la doc Adobe doit le permettre. Ce script recherche un mot dans un PDF, l'encadre et crée un lien pour chaque occurrence trouvée de ce mot. Les coordonnées apparaissent dans cet ordre : [upper-left x, upper-left y, lower-right x, lower-right y]. A toi d'œuvrer.

l = addLink(p, [r[4], r[5], r[2], r[3]]);

**kiki29** · 21/11/2015, 00h07

LibreOffice permet de créer des formulaires PDF. Ici via sCalc.

En liaison avec Acrobat ( pas le Reader )
Lecture des champs d'un formulaire Pdf
Ecriture dans les champs d'un formulaire PDF
Ecriture dans les champs d'un formulaire PDF à partir d'une feuille Excel
Lecture de formulaires PDF

**kiki29** · 24/11/2015, 07h28

Plus à titre documentaire et de curiosité qu'autre chose, faire une recherche de fredclo sur free.fr
pour une solution de remplissage de formulaire PDF ... originale.

**Dje69r** · 07/12/2015, 11h18

Merci pour tous ces exemples...

J'ai cependant une petite question, j'affiche mon pdf ainsi que les barres d'outils. Or les commentaires sont grisés. Y a t il une commande pour permettre d'ajouter un commentaire directement dans une userform ? Ca fonctionne directement avec Reader, mais là tout est grisé...

Merci

**kiki29** · 08/12/2015, 02h08

Salut, ne pratiquant pas l'extispicine, reformule ta question : contexte, fichier, application, Boileau l'a déjà dit : Ce qui se conçoit bien s'énonce clairement.

**kiki29** · 03/01/2016, 00h04

Référence à cocher sous VBA/Outils/Références : AdobePDFMakerForOffice
Testé avec Excel 2007 / Acrobat PDFMaker 15.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
Option Explicit
 
Sub Essai()
Dim sNom As String
    sNom = ThisWorkbook.Path & "\" & "Essai_PDFMaker.pdf"
    SavePDF sNom
End Sub
 
Sub SavePDF(sNomFichier As String)
Dim i As Long
Dim appPDFMaker As AdobePDFMakerForOffice.PDFMaker
Dim appSettings As AdobePDFMakerForOffice.ISettings
 
    Application.ScreenUpdating = False
 
    For i = 1 To Application.COMAddIns.Count
        If InStr(UCase$(Application.COMAddIns(i).Description), "PDFMAKER") > 0 Then
            Set appPDFMaker = Application.COMAddIns(i).Object
            Exit For
        End If
    Next i
 
    appPDFMaker.GetCurrentConversionSettings appSettings
 
    With appSettings
        .AddBookmarks = True
        .AddLinks = True
        .AddTags = True
        .AdvancedTagging = True
        .ConvertAllPages = True
        .CreateFootnoteLinks = True
        .CreateXrefLinks = True
        .FitToOnePage = False
        .OutputPDFFileName = sNomFichier
        .PromptForSheetSelection = False
        .ShouldShowProgressDialog = False
        .ViewPDFFile = False
    End With
 
    appPDFMaker.CreatePDFEx appSettings, 0
 
    Application.ScreenUpdating = True
 
    Set appSettings = Nothing
    Set appPDFMaker = Nothing
 
End Sub

Propriétés ISettings ( toutes booléennes sauf indications ) :

AddBookmarks
AddLinks
AddTags
AdvancedTagging
AllowBleeds
AlwaysFlattenLayers
AttachSourceFile
ConversionRoute
ConvertAllPages
ConvertHiddenSlides
ConvertMultimedia
ConvertSpeakerNotes
CreateDocInfo
CreateFootnoteLinks
CreateLayers
CreateMetadata
CreateTextNodes
CreateThreads
CreateXrefLinks
FitToOnePage
InvokedFromFeat
IsAutomation
IsConversionSilent
JobOptions as String
LayoutBasedOnPrinterSettings
OpenLayerPane
OutputPDFFileName as String
PDFACompliance
PreserveSpotColor
PreserveTransparency
PrintActiveSheetOnly
PrintBleedMarks
PrintCropMarks
PromptForPDFFilename
PromptForSheetSelection
Reserved as Long
SaveAnimations
SaveSlideShowTransitions
SecuritySettings as Object
SendForReview
SendViaEmail
ShouldShowProgressDialog
ViewPDFFile

**Flodu31** · 22/01/2016, 10h59

Bonjour Kiki,

Je me replonge dans mes macros excel et notamment la recherche via PDF.
J'arrive désormais à chercher un mot dans un fichier PDF.
Maintenant, je souhaiterais ouvrir le fichier pdf, ouvrir le panneau recherche (idéalement le panneau recherche avancée) et le remplir directement avec le mot souhaité.
Sais-tu si cela est faisable ?

Merci par avance,

**kiki29** · 22/01/2016, 12h33

Salut, regarde : Recherche dans tous les PDFs d'un dossier via Acrobat Reader (via APIs) ou son adaptation à Acrobat Reader DC 15

**Flodu31** · 25/01/2016, 15h32

Merci,

En adaptant la macro dont tu parles à mon cas, ça marche super bien !
Bonne journée

**juelo** · 03/02/2016, 11h36

Bonjour,

Et merci pour ce sujet très riche !

Ma question :
Je souhaite Spliter un PDF contenant n documents avec 1 ou plusieurs pages par document, pour obtenir 1 fichier par document.
J'ai la possibilité d'ajouter une chaîne de caractère permettant de différencier 2 documents distincts.

Je développe en VB.NET et j'utilise pdfforge.

Pouvez vous me conseiller ?

Merci

**kiki29** · 03/02/2016, 16h58

Salut, un exemple ici via PDFCreator
sinon toujours en VBA pour les doublons il y a un exemple ici

Il te restera à les transposer en NET

**Alogtf** · 11/02/2016, 13h45

Envoyé par kiki29

@David, salut et merci, cela ne manquera pas de servir.

@Flodu31, ne reproduisant pas ici le problème que tu recontres difficile de répondre,
Autrement via le post 112 Acrobat Exécution d'un code JavaScript

L'exemple n°3 repris de la doc Adobe doit le permettre. Ce script recherche un mot dans un PDF, l'encadre et crée un lien pour chaque occurrence trouvée de ce mot. Les coordonnées apparaissent dans cet ordre : [upper-left x, upper-left y, lower-right x, lower-right y]. A toi d'œuvrer.

Salut kiki29,

Je fais des recherches sur les PDF ( sous Adobe Acrobat 11 Pro) pour localiser un mot dans une page puis le localiser dans l'espace de cette page,
Tu parles d'un exemple3 qui permet apparemment de faire cela. Peux tu m'en dire plus ?

Merci par avance

**kiki29** · 15/02/2016, 14h32

Salut, regarde plutôt les liens du post 175

Excel / Word / PDF avec Adobe Acrobat Pro et PDFCreator 1.7.3 (obsolète)

Contribuez

Discussions similaires

Partager

Partager