Discussion :

[ruzakruzak]

Bonjour.

J'ai un petit souci entre 2 versions d'un code, et malheureusement c'est celle qui me plaît le plus qui plante...

Voici la version qui marche:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 For Each cell In Sheets("Projects").Range("J2:J" & dernLigneP)
    If Left(cell.Value, 2) = "PM" Or Left(cell.Value, 2) = "Pm" Or Left(cell.Value, 2) = "pm" Then cell.EntireRow.Hidden = True
 Next cell

Et voici la version qui plante à la 1re ligne. iProjFinancialbudgetcode est une constante, et dernLigneP la dernière ligne de la feuille, déclarée en integer.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
    For Each cell In Sheets("Projects").Range(Cells(2, iProjFinancialbudgetcode), Cells(dernLigneP, iProjFinancialbudgetcode)).Cells ' Ca plante aussi sans le .Cells
        If Left(cell.Value, 2) = "PM" Or Left(cell.Value, 2) = "Pm" Or Left(cell.Value, 2) = "pm" Then cell.EntireRow.Hidden = True
    Next cell

Avez-vous une idée pour comprendre mon erreur SVP ?

[mordrhim]

tes constantes

elle sont initialisées, ou ? C'est des constantes de projet, de module ? elles sont publiques ? privées ?

pour faire un petit test met un

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    MsgBox ("iProjFinancialbudgetcode :" & iProjFinancialbudgetcode & ",dernLigneP : " & dernLigneP)

juste avant le for.

s'il ne donne pas iProjFinancialbudgetcode : X,dernLigneP : Y une de tes variables n'est pas bien initialisée

(chez moi la commande fonctionne bien, sauf si une des deux variable est nulle ou non initialisée, ce qui me donne une erreur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Erreur d'execution '1004': Erreur définie par l'application ou par l'objet

[illight]

t'a essayé tout betement de mettre ta variable en long plutot qu'en integer ?

A mon avis, c'est aussi ton .cells a la fin qui fait plantouiller. Ça te fait la meme erreur quand tu le met pas ?

[jfontaine]

Petite astuce sur un autre partie de ton code.
Afin d'éviter les or dansnun if pour contrôle de la saisie.
Il suffit de tester le texte en Majuscule (idem si tu prefère les minuscule)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
 
If Ucase(Left(cell.Value, 2)) = "PM" Then cell.EntireRow.Hidden = True

Pour ton problème, ton code fonctionne si l'on met directement des valeurs plutôt que les variables. Regardes du coté des variables

[ruzakruzak]

Merci pour vos feeedbacks.

Alors, ma constante et ma variable sont déclarées de la manière suivante:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Const iProjFinancialbudgetcode As Integer = 10
' et 
dernLigneP = Sheets("Projects").Range("A1").CurrentRegion.Rows.Count

La constante est déclarée dans le même module que le code ci-dessus, et dernLigneP est décvlarée comme Integer. A priori les Integer suffisent, le décompte se faisant sur des numéros de lignes et de colonnes, et non sur le nombre de cellules d'une plage, d'antant que je teste sur des jeux de données restreints (genre 100 lignes au max...).
Et si j'espionne les valeurs de iProjFinancialbudgetcode et dernLigneP, elles sont bien présentes et définies.

> Illight : même sans le .Cells à la fin, le plantage reste le même.

> Jfontaine : merci pour l'astuce, j'implémente de suite !

[wilfried_42]

bonjour à tous

As tu defini cell

dim cell as range

@ te lire

[ruzakruzak]

Oui, tout à fait.

[ruzakruzak]

Bon je creuse toujours mais sans succès.
Pour info, le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each cell In Sheets("Projects").Range(Cells(2, 38), Cells(23, 38))

plante aussi, bien que j'aie remplacé les variables par leurs valeurs littérales.

Y'a plus que cell qui puisse être source d'erreur, alors qu'il est déclaré en tant que Range.

Des idées ? Moi, ça commence à me ...

[Pierre Fauconnier]

Bonjour

C'est parce que tu ne précises pas que Cells(...) fait partie de ta feuille. Sans cette précision, les Cells(...) que tu définis appartiennent à la feuille active alors que ton code les attribue à la feuille "Projects"...

Avec le code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
For Each Cell In Worksheets("Projects").Range(Worksheets("Projects").Cells(2, iProjFinancialbudgetcode), Worksheets("Projects").Cells(DernLigneP, iProjFinancialbudgetcode))

cela fonctionnera. Mais c'est un peu lourd au niveau syntaxe.

Je te conseille donc d'utiliser un objet Worksheet.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
    Dim Feuille As Worksheet
    Set Feuille = Worksheets("Projects")
    For Each Cell In Feuille.Range(Feuille.Cells(2, iProjFinancialbudgetcode), Feuille.Cells(DernLigneP, iProjFinancialbudgetcode))

pour rendre ton code plus lisible.

Ok?

[wilfried_42]

re: bonjour à tous

Il ressort avec une erreur 1004, non pas avec une mauvaise plage choisie

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each cell In Sheets("Projects").Range(Cells(2, 38), Cells(23, 38))

je ne comprends pas trop ton code m'enfin essaye ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each cell In Sheets("Projects").Range(Cells(2, 38).Address & ":" & Cells(23, 38).address)

sinon, si dans tes 2 cellules tu vas chercher des adresses

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each cell In Sheets("Projects").Range(Cells(2, 38).value & ":" & Cells(23, 38).value)

dis nous

[Pierre Fauconnier]

Bonjour Wilfried

Il ressort avec une erreur 1004 parce que:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
worksheets("Projects").range(cells(...))

utilise une référence à la feuille "Projects"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

worksheets("Projects").range

ET une référence à la feuille active

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

...range(cells(...)

Ce n'est donc pas un problème de "mauvaise plage choisie", c'est que VBA sera dans l'impossibilité de déterminer l'objet Range lorsque la feuille Projects n'est pas la feuille active.
Donc, lorsque Projects est la feuille active, pas de problème. Mais dès que Projects n'est plus la feuille active, VBA se plante puisqu'il essaie de définir au sein d'une feuille des cellules qui ne lui appartiennent pas. C'est pour cela qu'il faut préciser que l'on travaille avec un objet Cells() de la feuille Projects.

Ton code fonctionne effectivement car tu utilises l'adresse d'une cellule de la feuille active. Mais c'est un peu "tordu", si tu me permets l'expression.

De plus, ton code ne fonctionnera plus lorsque la feuille active sera une feuille graphique et plus une feuille de calcul, puisqu'il fera référence à un objet Cells() d'une feuille qui n'en possède pas.

J'ai posté précédemment une solution qui fonctionne.
La seule façon de procéder est de rattacher l'objet Cells() à la feuille Projects, et la solution la plus élégante et la plus lisible est d'utiliser un objet WorkSheet.

Ok?

[AlainTech]

Pour préciser encore.

Il n'est pas nécessaire de dire à quelle feuille l'étendue (Range) va se référer puisqu'on va déterminer la feuille de chaque cellule.

Ce qui donne:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each Cell In Range(Worksheets("Projects").Cells(2, iProjFinancialbudgetcode), Worksheets("Projects").Cells(DernLigneP, iProjFinancialbudgetcode))

Ou mieux (salut, Pierre):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim Feuille As Worksheet
Set Feuille = Worksheets("Projects")
For Each Cell In Range(Feuille.Cells(2, iProjFinancialbudgetcode), Feuille.Cells(DernLigneP, iProjFinancialbudgetcode))

[Pierre Fauconnier]

Bonjour Alain, J'espère que tu vas bien...

Tu as raison, la précision avant le Range est superflue.

Bonnes vacances, si tu en prends...