Discussion :

[Asdorve]

Bonjour,

Je viens à vous parce que je me pose une question:

j'ai une appli qui exige la création d'un nombre indéfini de tableaux, et donc je ne peux pas les déclarer.

J'aimerais pouvoir créer des tableau du genre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
MonTableaui(4)

Peut-on faire quelque chose de ce genre?

Si je ne suis pas assez clair, dites le moi!!

Merci d'avance.

[Theocourant]

Salut,

A ma connaissance, ce n'est pas possible par contre si tes tableaux de grandeur fixe, il suffit de passer par une dimension supplémentaire pour "gérer" un nombre de tableaux dynamique et après tu utilises la fonction ReDim Preserve pour modifier la dernière dimension.

Mais comme je te l'ai dis cela ne fonctionne qu'avec des tableaux de dimension fixe ou alors il faut faire un pré-traitement pour récupérer les dimensions maximales.

+

Théo

[Delbeke]

Si non, il existe la piste des collections de collections d'objet

[Asdorve]

Merci à tous les deux pour vos réponses.

Théo:
Malheureusement, la longueur n'est pas définie.

Si non, il existe la piste des collections de collections d'objet

Delbeke, peux-tu m'expliquer de quoi il s'agit?

[Delbeke]

Avec un peu d'astuce, on peut emuler un tableau avec une collection

Ce tableau, peut etre ajouté/retiré/selectionné dans une collection.

[Asdorve]

Dans msdn, il y a ce code, est-ce que ça correspond à ce que tu me dis?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
 
Sub ClassNamer()
   Dim MyClasses As New Collection   ' Crée un objet Collection.
   Dim Num   ' Compteur permettant d'individualiser les clés.
   Dim Msg As String   ' Variable devant contenir  la chaîne d'invite.
   Dim TheName, MyObject, NameList   ' Variants devant contenir les   'données.
   Do
      Dim Inst As New Class1   ' Crée une nouvelle instance de Class1.
      Num = Num + 1   ' Incrémente d'une unité la valeur de Num, puis
                     ' obtient un nom.
      Msg = "Veuillez affecter un nom à cet objet." & Chr(13) _
      & "Appuyez sur Annuler pour afficher les noms présents _
      & "dans la collection."
      TheName = InputBox(Msg, "Nommez les éléments de Collection")
      Inst.InstanceName = TheName   ' Place le nom dans l'instance de
                                    ' l'objet.
      ' Si l'utilisateur a saisi un nom, ajoute  celui-ci à la 
      ' collection.
      If Inst.InstanceName <> "" Then
         ' Ajoute l'objet nommé à la collection.
         MyClasses.Add item := Inst, key := CStr(Num)
      End If
      ' Efface la référence en cours en prévision de la suivante.
      Set Inst = Nothing
   Loop Until TheName = ""
   For Each MyObject In MyClasses   ' Crée une liste des noms.
      NameList = NameList & MyObject.InstanceName & Chr (13)
   Next MyObject
   ' Affiche la liste des noms dans une zone de message.
   MsgBox NameList, , "Noms des instances présentes dans la _
    & "collection MyClasses"
 
   For Num = 1 To MyClasses.Count   ' Supprime le nom de la collection.
      MyClasses.Remove 1            ' Puisque les collections sont                                           ' réindexées automatiquement,
                                    ' supprime le premier membre à
   Next                              ' chaque itération.
End Sub

[zazaraignée]

Je suggère alors deux classes d'objets dont l'une est une propriété de l'autre...

[Delbeke]

Vi, l'idée est la, j'essayerais de te faire un petit exemple demain, la j'ai pas trop le temps.

[Asdorve]

Vi, l'idée est la, j'essayerais de te faire un petit exemple demain, la j'ai pas trop le temps.

C'est sympathique ça!! merci par avance!

[zazaraignée]

Juste au cas, j'ai fait ça dans Together (Borland), pour illustrer le propos. Deux classes : Une classe Joueur (de billes) qui possède des Billes (l'autre classe).

[ProgElecT]

Je sais que les forumeurs qui sont intervenus son des bons de la programmation.

Il y a plusieurs années, j’ai eu un problème approchant, les collections n’existaient peut être pas, ou j’étais encor moins compétant qu’aujourd’hui .

Voilà comment j’avais solutionné mon problème, tableaux redimensionnables avec préservation des données pour un dimensionnement vers le haut.
Dans un module .bas

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Public Type MultipleTableau
 LeData() As Integer
End Type

Dans un Form

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
Private Sub Form_Load()
Dim NbrTableau As Integer
' la il faut avoir la possibilité de recuperer
' le besoin de quantité de tableaux
NbrTableau = 5 'valeur deduite par le prog
ReDim MonTableau(NbrTableau)
 
ReDim MonTableau(0).LeData(12)
ReDim MonTableau(1).LeData(100)
ReDim MonTableau(2).LeData(200)
ReDim MonTableau(3).LeData(300)
ReDim MonTableau(4).LeData(60)
 
'affectation de valeur aux tableaux indexés
MonTableau(0).LeData(0) = 8
MonTableau(0).LeData(1) = 18342
MonTableau(0).LeData(2) = 342
'...........
MonTableau(1).LeData(9) = 5
'...........
MonTableau(2).LeData(199) = 765
'...........
MonTableau(3).LeData(1) = 5
'...........
MonTableau(4).LeData(45) = 5
 
' le besoin a changé durant la session
'ATTENTION perte des tableaux d'index supperieur
ReDim Preserve MonTableau(2)
 
' le besoin a changé durant la session
ReDim Preserve MonTableau(0).LeData(20)
ReDim Preserve MonTableau(1).LeData(80)
ReDim Preserve MonTableau(2).LeData(50)
 
Dim T As Integer
'pour voir
For T = 0 To 3
 MsgBox MonTableau(0).LeData(T), vbInformation
Next T
 
'passage de la structure et des données vers un nouveau tableau
ReDim Preserve MonTableau(3)
MonTableau(3) = MonTableau(0)
MonTableau(3).LeData(3) = 2007 'affectation valeur à index 3 du tableau 3
For T = 0 To 3
 MsgBox MonTableau(3).LeData(T), vbInformation
Next T
 
End Sub

Usine à gaz, oui mais des fois ....

Je vous laisse analysez la différence vis-à-vis d’un tableau simple déclaré à deux dimensions, cette solution permet plus de souplesse.

Motif de l'edition

Un oublit dans le copier/coller
Dans le Form

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Option Explicit
Dim MonTableau() As MultipleTableau

[Delbeke]

Bon, chose promise, chose due
Créer une premiere classe nommée iTem

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Option Explicit
Public Value As Variant

Mettre la propriété value comme propriété par défaut de la classe

Créer une seconde classe nommée Tableau

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Private mCol As Collection
Private Sub Class_Initialize()
    Set mCol = New Collection
End Sub
Private Sub Class_Terminate()
    Set mCol = Nothing
End Sub
Public Property Get Item(vntIndexKey As Variant) As Item
  Set Item = mCol(vntIndexKey)
End Property
Public Property Get TUbound() As Long
  TUbound = mCol.Count
End Property
Public Sub TDim(Value As Integer)
  Dim iPnt As Integer
  Dim X As Item
  Do While mCol.Count > 0
    mCol.Remove 1
  Loop
  For iPnt = 1 To Value
    Set X = New Item
    X.Value = 0
    mCol.Add X
  Next
End Sub
Public Sub TDimPreserve(Value As Integer)
  Dim iPnt As Integer
  Dim X As Item
  If Value > mCol.Count Then
    For iPnt = mCol.Count To Value
      Set X = New Item
      X.Value = 0
      mCol.Add X
    Next
  Else
    For iPnt = mCol.Count To Value - 1
      mCol.Remove iPnt
    Next
  End If
End Sub

mettre la propriété Item comme la propriété par defaut de la classe

Enfin voici un exemple d'utilisation dans une form avec deux boutons de commande

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Dim Tabl As Tableau
Dim Tabls As New Collection
Private Sub Command1_Click()
  'generer un tableau de 25 élément et l'ajouter à la collection
  Dim lPnt As Long
  Set Tabl = New Tableau
  Tabl.TDim Fix(Rnd() * 100)
  For lPnt = 1 To Tabl.TUbound
    'Syntaxe developpée
      'Tabl.Item(lPnt).Value = Fix(Rnd() * 100)
    'en réglant les propriétés par defaut on peux simplifer en
      Tabl(lPnt) = Fix(Rnd() * 100)
  Next
  Tabls.Add Tabl
End Sub
 
Private Sub Command2_Click()
  Dim NumTableau As Long
  Dim Tabl As Tableau
  Dim lPnt As Long
  NumTableau = CLng(InputBox("Numero de tableau (de 1 à " & CStr(Tabls.Count) & ")"))
  Set Tabl = Tabls(NumTableau)
  For lPnt = 1 To Tabl.TUbound
    'syntaxe complete
      'Debug.Print lPnt, Tabl(lPnt).Value
    Debug.Print lPnt, Tabl(lPnt)
  Next
End Sub

Attention par manque de temps,je n'ai pas vérifier le code pour la fonction TDimPreserve

[Asdorve]

Merci beaucoup ami Delbeke (ainsi que tous ceux qui ont répondu). Je regarde attentivement ton code et je reviens vers vous pour des explications si besoin.

Merci encore

[sovo]

Aller juste comme ca une idee, qui vas un peut dans le meme sens que celui de ProgElect, c'est a dire en passant par les tableau. Mais dans mon cas par un tableau bidimensonnel. La premiere dimension represente l'index du "tableau" et la deuxieme "les donnees du tableau". Evidement va falloir faire un redim preserve pour conserver les anciennes donnees. Je crois c'est un peut plus rapide.

[OhMonBato]

Avec Redim Preserve tu ne peux redimensionner que le dernier indice du tableau (le deuxième donc en l'occurence)

[sovo]

Avec Redim Preserve tu ne peux redimensionner que le dernier indice du tableau (le deuxième donc en l'occurence)

Tu es sur ?? je n'ai pas fait VB depuis un bon bout de tempsmas je crois avoir fait un truc de ce genre. Je vais voir dans mes archives et je vous tiens au courant demain

[Phifi]

Tu es sur ??

Eh oui...

Si vous utilisez le mot clé Preserve, vous ne pouvez redimensionner que la dernière dimension du tableau. Vous ne pouvez en aucun cas modifier le nombre de dimensions. Par exemple, si votre tableau n'a qu'une dimension, vous pouvez la modifier puisqu'il s'agit de la dernière et seule dimension. Toutefois, si le tableau compte plusieurs dimensions, seule la taille de la dernière dimension est modifiable si vous souhaitez préserver le contenu du tableau. L'exemple suivant montre comment augmenter la taille de la dernière dimension d'un tableau dynamique sans effacer les données qu'il contient :

ReDim X(10, 10, 10)
. . .
ReDim Preserve X(10, 10, 15)

De même, le mot clé Preserve ne permet de redimensionner un tableau qu'en modifiant la limite supérieure ; toute modification de la limite inférieure provoque une erreur.

[sovo]

Bon apres verification dans mon projet et sur MSDN je me suis rendu compte que j'ai parler un peut trop vite.

Je retire mes propos.