Discussion :

[Aos]

Bonjour,

Alors la question est simple :
Y a-t-il plus rapide pour extraire un fichier texte complet dans un tableau que la fonction suivante sachant que celle-ci mets a peu pres 30 seconde pour extraire les 20.000 ligne de mon fichier (a peu pres 150 caractere par lignes).
Sachant que le type tableuaInfiniDeString = array of string;

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
function extraireFichier(leFichier : String):tableauInfiniDeString;
var
F : TextFile;
tableauTemporaire : tableauInfiniDeString;
i : integer;
chaine:string;
begin
i:=0;
AssignFile(F,leFichier);
reset(F);
setLength(tableauTemporaire,0);
while not(eof(F)) do
  begin
  setLength(tableauTemporaire,length(tableauTemporaire)+1);
  readln(F,chaine);
  tableauTemporaire[i]:=chaine;
  inc(i);
  application.ProcessMessages;
  end;
CloseFile(F);
extraireFichier:=tableauTemporaire;
end;

[Cl@udius]

Salut

As-tu essayé de travailler avec un TStringList et sa méthode LoadFromFile ?
Tu devrais avoir des résultats plus rapide.

@+

[ShaiLeTroll]

Quelques optimisations sont possibles, l'application.processmessages qui permet à l'application de traiter les messages, donc ralenti la lecture, les setlenght a répétition !

Le plus simple serait une TStringList et un LoadFromFile, maintenant tu préféres peut-être les Tableaux, je ponds une fonction et je reviens

EDIT : Griller par Claudius !

EDIT 2 :
Une TStringList est dix fois plus lente que la fonction suivante, fichier testé, 2 millions de ligne de 60 char,

extraireFichier : Trop long et Mémoire Insuffisante avant 100 000 lignes
FillArrayFromTextFile : 6533 ms
StringList.LoadFromFile : 62483 ms

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
function FillArrayFromTextFile(const FileName: string): Types.TStringDynArray;
var
  FLNC: TextFile;
  CountLn, I: Integer;
begin
   CountLn := 0;
   AssignFile(FLNC, FileName);
   Reset(FLNC);
   try
     while not Eof(FLNC) do
     begin
       Inc(CountLn);
       Readln(FLNC);
     end;
   finally
     CloseFile(FLNC);
   end;
 
   Reset(FLNC);
   try
     SetLength(Result, CountLn);
 
     for I := 0 to CountLn - 1 do
       Readln(FLNC, Result[I]);
   finally
     CloseFile(FLNC);
   end;
end;

[Aos]

Non j'ai jamais essayer avec un TStringList mais non je n'ai pas specialement de preference pour le tableau car le traitement effectuer apres est en TStringList.

Je teste

[Aos]

waaaaaaaaaaah c'est la folie!
J'ai juste "pour l'exemple" fait un SetLength(leTableau,50000); et donc enlever le SetLength() a repetition dans la boucle et la lecture de tout le fichier se fait quasi instantanément (une seconde ou 2).

Faut juste que je sache la longueur du fichier pour pouvoir mettre un Setlength avec une variable maintenant.
Avec une boucle while et un readln() et inc(i), ça devrait aller vite.
Sauf s'il existe une méthode pour connaitre directement le nom de ligne d'un fichier texte ?

[ShaiLeTroll]

Normal !

Tu as 50 000 items, il va faire une nouvelle allocation mémoire, mais 99% il n'a pas la place pour 50 001 item, donc il alloue 50 001 ailleurs, recopie les 50000 anciens et laisse le 50 001 eme pret pour une nouvelle valeur !

[Cl@udius]

Héhé pas mal la méthode de Shai:

1. Je compte le nb de lignes
2. Je dimensionne le tableau
3. Je remplis...

2M de lignes en 6.5s ! Intéressant.

[edit]
Les résultats sont-ils aussi intéressant avec un fichier disons 2 fois plus petit ? (Je n'ai pas de fichier sous la main)
[/edit]

@+ Claudius

[Aos]

Quel methode claudius ?

SHAI : j'ai rien compris a ton dernier post

Une petite precision le fichier change tout le temps, il est ramené avec un opedialog donc je ne maitrise pas le nombre de ligne. Il peut y en avoir 10, 100, 1000 ou 100.000

[Cl@udius]

Quel methode claudius ?

Celle de Shai: FillArrayFromTextFile.

Une petite precision le fichier change tout le temps, il est ramené avec un opedialog donc je ne maitrise pas le nombre de ligne. Il peut y en avoir 10, 100, 1000 ou 100.000

La méthode de Shai dimensionne le tableau en fonction du fichier !
Si tu regardes bien son code il parcourt 2 fois le fichier.

@+ Claudius

[Aos]

ah oui ok, j'avias pas vu qu'il avait edité son message
ouais ben j'avais codé a peu pres une méthode similaire. La meme en faite
sauf que je boucle pas jusqu'a countLn-1 mais jusqu'a pred(countLn).
Oui je sais c'est pareil

Merci a vous deux
Et voila une affaire simple mais resolu!