Discussion :

[clao260]

Bonjour (ou Bonsoir) à tous,

Je vous expose mon problème, J'ai besoin d'exporter le resultat de plusieurs requêtes vers excel. Mais ce dont j'ai encore plus besoin c'est que ces resultat soit dans des feuilles differente d'un meme classeur excel.

Donc aujourd'hui par les macro j'arrive tres facilement a exporter les resultats dans plusieurs fichiers excel mais pas dans un seul.

Merci de votre aide

[Invité]

Bonjour

Bienvenu sur le forum, tu as a ta disposition une FAQ, des Sources, et des tutoriaux, dont celui-là, qui te permettra je pense résoudra tes problèmes.

Starec

[clao260]

Merci pour ta reponse, mais ce ne fonctionne pas totalement. Pourtant je sens bien que je ne suis pas loin.
J'utilise le code trouver dans le tuto que tu m'as fournis

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
 
Function TransfertExcelAutomation()
 
    Dim xlApp As Excel.Application
    Dim xlSheet As Excel.Worksheet
    Dim xlBook As Excel.Workbook
    Dim I As Long, J As Long
    Dim t0 As Long, t1 As Long
 
    t0 = Timer
    Dim rec As Recordset
 
    Set rec = CurrentDb.OpenRecordset("TelFauxIDF", dbOpenSnapshot)
 
    'Initialisations
    Set xlApp = CreateObject("Excel.Application")
    Set xlBook = xlApp.Workbooks.Add
 
    'Ajouter une feuille de calcul
    Set xlSheet = xlBook.Worksheets.Add
    xlSheet.Name = "TelFauxIDF"
 
    ' le titre
    '  écriture dans la cellule de ligne 1 et de colonne 1
    'xlSheet.Cells(1, 1) = "Export d'une table Access"
 
 
    ' les entetes
    '  .Fields(Index).Name renvoie le nom du champ
    For J = 0 To rec.Fields.Count - 1
        xlSheet.Cells(1, J + 1) = rec.Fields(J).Name
        ' Nous appliquons des enrichissements de format aux cellules
        With xlSheet.Cells(1, J + 1)
            .Interior.ColorIndex = 15
            .Interior.Pattern = xlSolid
            .Borders(xlEdgeBottom).LineStyle = xlContinuous
            .Borders(xlEdgeBottom).Weight = xlThin
            .Borders(xlEdgeBottom).ColorIndex = xlAutomatic
            .HorizontalAlignment = xlCenter
        End With
    Next J
 
    ' recopie des données à partir de la ligne 3
    I = 2
    Do While Not rec.EOF
        For J = 0 To rec.Fields.Count - 1
            ' .Fields(Index).Type renvoie le type du champ
            '   si c'est un Texte (dbText) nous insérons "'" pour
            '   qu'il soit reconnu par Excel comme du Texte
            If rec.Fields(J).Type = dbText Then
                xlSheet.Cells(I, J + 1) = "'" & rec.Fields(J)
            Else
                xlSheet.Cells(I, J + 1) = rec.Fields(J)
            End If
        Next J
        I = I + 1
        rec.MoveNext
    Loop
 
    ' code de fermeture et libération des objets
    xlBook.SaveAs "C:\Temp\Resultat.xls"
    xlApp.Quit
    rec.Close
    Set rec = Nothing
    Set xlSheet = Nothing
    Set xlBook = Nothing
    Set xlApp = Nothing
 
    t1 = Timer
    Debug.Print I & " enregistrements", Format(t1 - t0, "0") & " secondes"
 
End Function

Voila ce que je fais j'ai créer une methode pour chaque requete, donc onglet que j'ai besoin de créer dans le fichier excel
Je pense que mon probleme viens de la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

xlBook.SaveAs "C:\Temp\Feuille.xls"

Comme j'ai plusieurs requetes à extraire, à chaque fois le fichier Resultat est remplacer par le nouveau puisque le code est SaveAs.

Merci de nouveau pour vos reponses

[Renardo]

Pourquoi extrait tu pas tes autres requetes a la suite de se code
ou alors si tu veux ajouter d'autre requete a la suite il faut juste que tu ouvre la feuille existante mais pas la recreer.

[helas]

Ceci qui est plus simple crée 2 onglets (Une et Deux) dans le même fichier XLS

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
Sub ExportExcel()
 DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel9, "reqUne", "E:\ExportExcel.xls", True, "Une"
 DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel9, "reqDeux", "E:\ExportExcel.xls", True, "Deux"
End Sub

[clao260]

Merci helas

C'etait si simple comme ca.

Par contre Renardo je ne perd pas de vue ta solution et pour ma culture personnel je vais essayer car elle me parait pas mal du tout

A bientot tous le monde