Discussion :

[jeanpierreco]

Bonjour,

Dans excel si je veux appliquer la macro ci dessous aux cellules A1:A12 cela me génère une erreur par contre si je mets note = range(A1") aucun problème comment faut il écrire la sélection de cellule pour que cela fonctionne sur la plage citée plus haut si je mets range ("cellA2:cellA12") cele ne fonctionne pas non plus.
merci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
 Sub evaluation()
 
 
Dim Note As Integer
 
Dim Mention As String
Note = Range("A2:A12") '----->>>>>> c'est là qu'il y a problème
If Note = 0 Then Mention = "Nul"
If Note >= 1 And Note < 6 Then Mention = "Moyen"
If Note >= 6 And Note < 11 Then Mention = "Passable"
If Note >= 11 And Note < 16 Then Mention = "Bien"
If Note >= 16 And Note < 20 Then Mention = "Très Bien"
If Note = 20 Then Mention = "Excellent"
Range("B2:B12") = Mention
End Sub

[lio62]

bonjour,

Essaye ca c'est la première fois que je réponds

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub essai()
 
 
For Each cell In Range("a2:a12")
If cell.Value = 0 Then
ActiveCell.Offset(0, 1) = "nul"
ElseIf cell.Value >= 6 Then
ActiveCell.Offset(0, 1) = "coucou"
 
 
End If
Next
End Sub

[lio62]

non ca ne marche pas désolé

[illight]

Bonjour,

Dans excel si je veux appliquer la macro ci dessous aux cellules A1:A12 cela me génère une erreur par contre si je mets note = range(A1") aucun problème comment faut il écrire la sélection de cellule pour que cela fonctionne sur la plage citée plus haut si je mets range ("cellA2:cellA12") cele ne fonctionne pas non plus.
merci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
 Sub evaluation()
 
 
Dim Note As Integer
 
Dim Mention As String
Note = Range("A2:A12") '----->>>>>> c'est là qu'il y a problème
If Note = 0 Then Mention = "Nul"
If Note >= 1 And Note < 6 Then Mention = "Moyen"
If Note >= 6 And Note < 11 Then Mention = "Passable"
If Note >= 11 And Note < 16 Then Mention = "Bien"
If Note >= 16 And Note < 20 Then Mention = "Très Bien"
If Note = 20 Then Mention = "Excellent"
Range("B2:B12") = Mention
End Sub

C'est normal que ça ne marche pas, "Note" tu le définis comme un entier, or ce n'est pas un entier mais une plage de cellules.

Tu peux par contre écrire un truc de ce genre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 Sub evaluation()
 
dim i as long
'Dim Note As Integer
'Dim Mention As String
'Note = Range("A2:A12") '----->>>>>> c'est là qu'il y a problème
for i = 2 to 12
If cells(i,1).value = 0 Then cells(i,2).value = "Nul"
If cells(i,1).value>= 1 And cells(i,1).value < 6 Then cells(i,2).value = "Moyen"
If cells(i,1).value>= 6 And cells(i,1).value< 11 Then cells(i,2).value = "Passable"
If cells(i,1).value>= 11 And cells(i,1).value< 16 Then cells(i,2).value = "Bien"
If cells(i,1).value>= 16 And cells(i,1).value< 20 Then cells(i,2).value = "Très Bien"
If cells(i,1).value= 20 Then cells(i,2).value = "Excellent"
next i
'Range("B2:B12") = Mention
End Sub

Il y a surement solution plus simple, mais pour un peu ressembler a ce que tu as écrit, c'est ça

[lio62]

j'ai trouvé ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
For Each Cell In Range("a2:a12")
If Cell.Value = 0 Then
Cell.Offset(0, 1) = "nul"
 
ElseIf cell.Value > 1 And cell.Value < 6 Then
cell.Offset(0, 1) = "mal"
 
ElseIf cell.Value >= 6 And cell.Value < 11 Then
cell.Offset(0, 1) = "tbl"
    'etc
End If
 
 
Next

ca marche mais c peut être pas le plus simple.

[AlainTech]

Evitez les If à répétition!

Nettement plus simple et plus propre:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub evaluation()
  Dim C As Range
  For Each C In Range("A2:A12")
    Select Case C.Value
    Case 0
      C.Offset(0, 1) = "Nul"
    Case Is < 6
      C.Offset(0, 1) = "Moyen"
    Case Is < 11
      C.Offset(0, 1) = "Passable"
    Case Is < 16
      C.Offset(0, 1) = "Bien"
    Case Is < 20
      C.Offset(0, 1) = "Très Bien"
    Case 20
      C.Offset(0, 1) = "Excellent"
    End Select
  Next C
End Sub

[illight]

Je peux juste une précision : Le OffSet c'est quoi ?

[AlainTech]

Ca doit pouvoir se traduire par "décalage"...



Dans le cas présent, on va écrire dans la cellule qui est décalée de 1 vers la droite par rapport à la cellule c.

[illight]

Ah ouais ok, merci pour la précision

Par contre, pour ce code, "Nettement plus simple", en terme de compréhension pour un débutant, je sais pas si c'est le cas, car un débutant commencera toujours pas des If

EN terme de propreté, oui c'est le cas

Mais si tu regarde dans les 2 cas, il y a presque autant de lignes

[AlainTech]

car un débutant commencera toujours par des If

D'où l'erreur de commencer à programmer sans avoir, au moins, pris la peine de parcourir les éléments du langage.
Si on exclut les fonctions mathématiques et de conversion, il n'y en a pas tellement.
Ca vaut franchement la peine de les lire au moins une fois pour savoir ce qui existe.

[megapacman]

perso , je verrai un truc du style:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
 
Sub evaluation()
 
 
Dim Note As Integer
Dim Mention As String
Dim i As Integer
 
For i = 2 To 12
 
Note = Cells(i, 1).Value
Debug.Print
 
'Note = Range("A2:A12") '----->>>>>> c'est là qu'il y a problème
If Note = 0 Then Mention = "Nul"
If Note >= 1 And Note < 6 Then Mention = "Moyen"
If Note >= 6 And Note < 11 Then Mention = "Passable"
If Note >= 11 And Note < 16 Then Mention = "Bien"
If Note >= 16 And Note < 20 Then Mention = "Très Bien"
If Note = 20 Then Mention = "Excellent"
Cells(i, 2).Value = Mention
Next i
 
End Sub

essaie ca ca fonctionne

[cafeine]

Hello,

si on veut s'amuser on peut utiliser Switch()

ce qui fait un code très compact mais pas forcément très rapide.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
dim toto as Range
For each toto in Range("A2:A12")
   toto.Offset(0,1) = switch(toto=0,"Nul",toto<6, "Passable", _
      toto<11,"moyen", toto<16,"bien", _
      toto<20,"très bien",toto=20,"excellent")
Next toto

[AlainTech]

Si on est parti pour le fun, on peut aussi faire ça:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub evaluation()
  Dim C As Range
  Dim aEval As Variant
  aEval = Array("Nul", "Moyen", "Moyen", "Moyen", "Moyen", "Moyen", "Passable", _
                "Passable", "Passable", "Passable", "Bien", "Bien", "Bien", "Bien", _
                "Bien", "Bien", "Très Bien", "Très Bien", "Très Bien", "Très Bien", _
                "Excellent")
  For Each C In Range("A2:A12")
    C.Offset(0, 1) = aEval(C.Value)
  Next C
End Sub

[jeanpierreco]

Bonjour,
j'ai une macro qui est comme ceci sous excel:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Dim essairéussi As range
Dim appréciation As String
set essairéussi = Range("A1": A10").value
Select Case essairéussi
    Case 0
        appréciation = "Nul"
    Case 1 To 5
       appréciation  = "Moyen"
    Case 6 To 10
        appréciation  = "Passable"
    Case 11 To 15
       appréciation  = "Bien"
    Case 16 To 19
      appréciation  = "Très Bien"
    Case Else
        appréciation  = "hors norme"
End Select
Range("B1:B10") = appréciation

La macro ne fonctionne pas elle génère une erreur 424 objet requis à la ligne
set essairéussi = Range("A1": A10").value
Comment libellé cette ligne pour que cela fonctionne
Merci

[Invité]

Salut

Je pense que c'est parceque tu demandes la valeur (value) d'un plage de cellule, à mon avis tu dois parcourir la plage avec une bloucle For ... Next, et dans ta boucle tu testes la propriété value de ta cellule en cours

Starec

[SfJ5Rpw8]

ensuite elle est censé faire quoi ta fonction ... tu as 10 valeurs à tester et un seul endroit pour la réponse..?

[cafeine]

Hello,

erreur de code sur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

set essairéussi = Range("A1": A10").value

essaie avec

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

set essairéussi = Range("A1:A10").value

perso, j'évite les caractères accentués dans les noms de variables ...